मैं वर्कशीट्स के सबसेट के माध्यम से कैसे लूप कर सकता हूं?

Question

मुझे पता है कि एक वर्कबुक की सभी वर्कशीट्स लूप करने के लिए, और कैसे एक बार बाहर निकलने के लिए मुझे एक 'अंत झंडा' कार्यपत्रक तक पहुँचने:

For Each ThisWorkSheet In Worksheets 
    If ThisWorkSheet.Name = "FlagEnd" Then Exit For 
    MsgBox "This worksheet name is: " & ThisWorkSheet.Name 
Next 

हालांकि मैं नहीं मिल सकता है पाश एक 'प्रारंभ पर शुरू करने के लिए फ्लैग 'वर्कशीट (या स्टार्ट-फ्लैग वर्कशीट के ठीक बाद वर्कशीट पर भी बेहतर है। उदाहरण के लिए ध्वजांकित स्टार्ट/एंड वर्कशीट अन्य वर्कशीट्स के समूह के बीच में हैं, इसलिए शुरुआत या अंत ट्रैवर्सिंग काम करने योग्य नहीं है।

'फ्लैगस्टार्ट' शीट से पहले सैकड़ों वर्कशीट हो सकती हैं, इसलिए मुझे वास्तव में दाएं शीट पर शुरू करने की आवश्यकता है।

की कोशिश की:

Set ThisWorkSheet = Sheets("FlagNew") 

और

For Each Sheets("FlagNew") In Worksheets 

विचार?

समाधान: माथीस बहुत करीब था, लेकिन डेंडरारी कस्टम एंडिंग इंडेक्स के साथ छोटा कदम था। मैंने वास्तव में अपने अंतिम समाधान का पता लगाया, लेकिन क्रेडिट देना चाहता था। यहां मेरा अंतिम समाधान था:

Private Sub CommandButtonLoopThruFlaggedSheets_Click() 
    ' determine current bounds 
    Dim StartIndex, EndIndex, LoopIndex As Integer 
    StartIndex = Sheets("FlagNew").Index + 1 
    EndIndex = Sheets("FlagEnd").Index - 1 

    For LoopIndex = StartIndex To EndIndex 
     MsgBox "this worksheet is: " & Sheets(LoopIndex).Name 
     ' code here 
    Next LoopIndex 
End Sub 

Answer 1

यदि यह विशेष रूप से परिवर्तनीय कार्यपुस्तिका नहीं है (यानी वर्कशीट्स को हर समय जोड़ा और हटाया नहीं जा रहा है), तो आप वर्कशीट्स के नाम छिपे हुए शीट पर और नाम से उनके माध्यम से लूप पर स्टोर कर सकते हैं।

हालांकि, यह लग रहा है जैसे वे कार्यपुस्तिका में लगातार जमा हो जाती है तो, मैथियास 'समाधान पर निर्माण, आप एक समारोह इस्तेमाल कर सकते हैं आरंभ और अंत कार्यपत्रकों के सूचकांक और फिर पाश के माध्यम से वापस जाने के लिए:

Public Function GetStartIndex() As Integer 
    On Error Resume Next 
    GetStartIndex = ThisWorkbook.Worksheets("MyStartingWorksheet").Index + 1 
End Function 

Public Function GetEndIndex() As Integer 
    On Error Resume Next 
    GetEndIndex = ThisWorkbook.Worksheets("MyEndingWorksheet").Index - 1 
End Function 

Sub LoopThrough() 

    Dim wks As Worksheet 
    Dim i As Integer 
    Dim iStart As Integer 
    Dim iEnd As Integer 

    iStart = GetStartIndex() 
    iEnd = GetEndIndex() 

    If iStart > 0 And iEnd > 0 And iEnd > iStart Then 
     For i = iStart To iEnd 
      Set wks = ThisWorkbook.Worksheets(i) 
      MsgBox wks.Name 
     Next i 
    End If 

End Sub 

Answer 2

कैसे?

For Each ThisWorkSheet In Worksheets 
    If ThisWorkSheet.Name = "FlagStart" Then output = true 
    If ThisWorkSheet.Name = "FlagEnd" Then Exit For 
    If output = true Then MsgBox "This worksheet name is: " & ThisWorkSheet.Name 
Next 

यह कोड काफी सही नहीं हो सकता है। मैं इसे एसओ संपादक में लिख रहा हूं वीबीए नहीं, लेकिन आपको विचार मिलता है।

Answer 3

मेरा मानना ​​है कि यदि आप "foreach" का उपयोग करते हैं तो आपके पास प्रारंभिक शीट पर कोई नियंत्रण नहीं होगा। उस मामले के लिए, मुझे यह भी यकीन नहीं है कि आप उस क्रम की गारंटी दे रहे हैं जिसमें पुनरावृत्ति होगी।
मुझे लगता है कि आपको क्या करना चाहिए सबसे पहले, उस शीट की अनुक्रमणिका प्राप्त करें जिसमें आप रुचि रखते हैं (नाम से शीट प्राप्त करें, और इसकी अनुक्रमणिका प्राप्त करें), और उसके बाद शुरू होने वाली चादरों के इंडेक्स पर, लूप के लिए पुनरावृत्त करें फ्लैग शीट सूचकांक।
:

Sub Iterate() 

Dim book As Workbook 
Dim flagIndex As Integer 
Dim flagSheet As Worksheet 

Set book = ActiveWorkbook 
Set flagSheet = book.Worksheets("Sheet3") 
flagIndex = flagSheet.Index 

Dim sheetIndex As Integer 
Dim currentSheet As Worksheet 

For sheetIndex = flagIndex To book.Worksheets.Count 
    Set currentSheet = book.Worksheets(sheetIndex) 
Next 

End Sub 

Answer 4

[संपादित करें मैं एक त्वरित उदाहरण के माध्यम से काट दिया] शीट तुम पर पुनरावृति एक आम नाम प्रारूप है? अगर यह एक चादर आप का संदर्भ लेना चाहते है

पूर्व)

Sheets(0).name > "Reports" 
Sheets(1).name > "Start Here" 
Sheets(2).name > "emp.0001" 
Sheets(3).name > "emp.0002" 
Sheets(4).name > "emp.0003" 
Sheets(5).name > "emp.0004" 
Sheets(6).name > "End Here" 

यदि हां, तो अपनी प्रत्येक पाश के लिए, बस एक Left(ThisWorkSheet.name, 4) = "emp" कर सत्यापित करने के लिए।

Answer 5

Public Sub ITERATE_WORKSHEETS() 
    On Error Resume Next  
    Dim x As Long 
     For x = 0 To 100 
       MsgBox Worksheets(x).Name 
     Next x 
    On Error GoTo 0 
    MsgBox "all done" 
End Sub 

Answer 6

एक्सेल वीबीए 2013 में यदि आपके पास वर्कशीट्स हैं जो आप "ब्लैंकफर्स्ट" और "ब्लैंकलास्ट" टैब के बीच अपडेट करना चाहते हैं।

परीक्षण के लिए नीचे दिए गए कोड का उपयोग करके अपने टैब नाम वापस लाएंगे और फिर MsgBox wks.Name भाग के स्थान पर अपने मैनिपुलेटिंग कोड को प्रतिस्थापित करें।

Sub Macro2() 

    On Error Resume Next 
    GetStartIndex = ThisWorkbook.Worksheets("Blankfirst").Index + 1 

    On Error Resume Next 
    GetEndIndex = ThisWorkbook.Worksheets("Blanklast").Index - 1 

    Dim wks As Worksheet 
    Dim i As Integer 
    Dim iStart As Integer 
    Dim iEnd As Integer 

    iStart = GetStartIndex 
    iEnd = GetEndIndex 


    If iStart > 0 And iEnd > 0 And iEnd > iStart Then 
     For i = iStart To iEnd 
      Set wks = ThisWorkbook.Worksheets(i) 
      MsgBox wks.Name 
     Next i 
    End If 

End Sub