जेनकींस पाइपलाइन ग्रोवी जेसन पार्सिंग

Question

मुझे ग्रोवी में यह JSON फ़ाइल बनाना है। मैंने कई चीजों को आजमाया है (JsonOutput.toJson()/JsonSlurper.parseText()) असफल।

{ 
    "attachments":[ 
     { 
     "fallback":"New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>", 
     "pretext":"New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>", 
     "color":"#D00000", 
     "fields":[ 
      { 
       "title":"Notes", 
       "value":"This is much easier than I thought it would be.", 
       "short":false 
      } 
     ] 
     } 
    ] 
} 

यह स्लेक के लिए जेनकींस बिल्ड संदेश पोस्ट करने के लिए है।

Answer 1

JSON एक ऐसा प्रारूप है जो मानव-पठनीय पाठ का उपयोग डेटा ऑब्जेक्ट्स को संचारित करने के लिए करता है जिसमें विशेषता-मूल्य जोड़े और सरणी डेटा प्रकार होते हैं। तो, सामान्य जेसन में एक स्वरूपित पाठ है।

ग्रोवी जेसन ऑब्जेक्ट में मानचित्र/सरणी का अनुक्रम है।

JsonSlurperClassic

//use JsonSlurperClassic because it produces HashMap that could be serialized by pipeline 
import groovy.json.JsonSlurperClassic 

node{ 
    def json = readFile(file:'message2.json') 
    def data = new JsonSlurperClassic().parseText(json) 
    echo "color: ${data.attachments[0].color}" 
} 

का उपयोग कर json पार्स करने json कोड से

node{ 
    def data = readJSON file:'message2.json' 
    echo "color: ${data.attachments[0].color}" 
} 

इमारत json पाइपलाइन का उपयोग कर पार्स करने और फाइल करने के लिए इसे लिखने

import groovy.json.JsonOutput 
node{ 
    //to create json declare a sequence of maps/arrays in groovy 
    //here is the data according to your sample 
    def data = [ 
     attachments:[ 
      [ 
       fallback: "New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>", 
       pretext : "New open task [Urgent]: <http://url_to_task|Test out Slack message attachments>", 
       color : "#D00000", 
       fields :[ 
        [ 
         title: "Notes", 
         value: "This is much easier than I thought it would be.", 
         short: false 
        ] 
       ] 
      ] 
     ] 
    ] 
    //two alternatives to write 

    //native pipeline step: 
    writeJSON(file: 'message1.json', json: data) 

    //but if writeJSON not supported by your version: 
    //convert maps/arrays to json formatted string 
    def json = JsonOutput.toJson(data) 
    //if you need pretty print (multiline) json 
    json = JsonOutput.prettyPrint(json) 

    //put string into the file: 
    writeFile(file:'message2.json', text: json) 

} 

Answer 2

इस सवाल को मिला, जबकि मैं कुछ करने की कोशिश कर रहा था (मुझे विश्वास था) करना आसान होना चाहिए, लेकिन दूसरे जवाब से संबोधित नहीं किया गया था। यदि आपके पास पहले से ही एक चर के अंदर एक स्ट्रिंग के रूप में लोड JSON है, तो आप इसे मूल वस्तु में कैसे परिवर्तित करते हैं? जाहिर है आप new JsonSlurperClassic().parseText(json) कर सकता है के रूप में अन्य जवाब पता चलता है, लेकिन वहाँ जेनकींस में एक देशी तरीका यह है है:

node() { 
    def myJson = '{"version":"1.0.0"}'; 
    def myObject = readJSON text: myJson; 
    echo myObject.version; 
} 

आशा इस कोई मदद करता है।

संपादित करें: जैसा कि "मूल" टिप्पणियों में बताया गया है, बिल्कुल सटीक नहीं है।