समग्र प्रक्रिया अधिक समग्र लॉकिंग ओवरहेड के साथ बहुत धीमी हो जाएगी लेकिन यदि आप केवल लेनदेन लॉग आकार की परवाह करते हैं तो आप निम्न कोशिश कर सकते हैं।
- एक निरर्थक पूर्णांक गैर पहचान कॉलम जोड़ें (मेटाडाटा केवल परिवर्तन)।
- बैचों में अद्वितीय अनुक्रमिक पूर्णांक के साथ इसे अद्यतन करने के लिए कोड लिखें। यह प्रत्येक व्यक्तिगत लेनदेन के आकार को कम करेगा और लॉग आकार को नीचे रखेगा (सरल वसूली मॉडल मानते हुए)। नीचे मेरा कोड 100 के बैचों में यह उम्मीद करता है कि आपके पास एक मौजूदा पीके है, जिसे आप बार-बार स्कैन करने के बजाय छोड़ने के लिए लीवरेज कर सकते हैं जो अंत में तेजी से लंबा लगेगा।
- कॉलम को
NOT NULL
के रूप में चिह्नित करने के लिए ALTER TABLE ... ALTER COLUMN
का उपयोग करें। इस बदलाव को सत्यापित करने के लिए पूरी तालिका को लॉक और स्कैन करने की आवश्यकता होगी लेकिन अधिक लॉगिंग की आवश्यकता नहीं है। कॉलम को पहचान कॉलम बनाने के लिए
- कॉलम बनाने के लिए
ALTER TABLE ... SWITCH
का उपयोग करें। यह केवल मेटाडाटा ही बदलता है।
उदाहरण नीचे दिए गए कोड
/*Set up test table with just one column*/
CREATE TABLE table_1 (original_column INT)
INSERT INTO table_1
SELECT DISTINCT
number
FROM master..spt_values
/*Step 1 */
ALTER TABLE table_1 ADD id INT NULL
/*Step 2 */
DECLARE @Counter INT = 0 ,
@PrevCounter INT = -1
WHILE @PrevCounter <> @Counter
BEGIN
SET @PrevCounter = @Counter;
WITH T AS (SELECT TOP 100
* ,
ROW_NUMBER() OVER (ORDER BY @@SPID)
+ @Counter AS new_id
FROM table_1
WHERE id IS NULL
)
UPDATE T
SET id = new_id
SET @Counter = @Counter + @@ROWCOUNT
END
BEGIN TRY;
BEGIN TRANSACTION ;
/*Step 3 */
ALTER TABLE table_1 ALTER COLUMN id INT NOT NULL
/*Step 4 */
DECLARE @TableScript NVARCHAR(MAX) = '
CREATE TABLE dbo.Destination(
original_column INT,
id INT IDENTITY(' + CAST(@Counter + 1 AS VARCHAR) + ',1)
)
ALTER TABLE dbo.table_1 SWITCH TO dbo.Destination;
'
EXEC(@TableScript)
DROP TABLE table_1 ;
EXECUTE sp_rename N'dbo.Destination', N'table_1', 'OBJECT' ;
COMMIT TRANSACTION ;
END TRY
BEGIN CATCH
IF XACT_STATE() <> 0
ROLLBACK TRANSACTION ;
PRINT ERROR_MESSAGE() ;
END CATCH ;
स्रोत
2011-08-23 16:14:18
क्या यह MySQL, SQL सर्वर, पोस्टग्रेस, ओरेकल है? – JNK
अक्षम लॉग, कॉलम जोड़ें, लॉग सक्षम करें। –
क्या यह एक उत्तर नहीं होना चाहिए बल्कि सिर्फ एक टिप्पणी नहीं? –