मैं सीपीएस फ़ंक्शन के साथ आरईपीएल का उपयोग कैसे कर सकता हूं?

Question

मुझे wreq पैकेज का सामना करना पड़ा है। मैं लाइन द्वारा निरंतरता रेखा का मूल्यांकन करना चाहता हूं, लेकिन मुझे इसके लिए कोई रास्ता नहीं मिल रहा है।

import Network.Wreq.Session as S 
withSession $ \sess -> do 
    res <- S.getWith opts sess "http://stackoverflow.com/questions" 
    -- print res 
    -- .. other things 

उपरोक्त स्निपेट में मैं ghci में print res का मूल्यांकन कैसे कर सकता हूं? दूसरे शब्दों में, क्या मुझे ghci में Session टाइप मिल सकता है?

Answer 1

अद्भुत सवाल।

मुझे कोई भी तरीका नहीं है जो जीएचसीआई आरईपीएल में फिर से प्रवेश कर सकता है, ताकि हम इसका उपयोग सीपीएस कार्यों में कर सकें। शायद दूसरे कुछ सुझाव दे सकते हैं।

हालांकि, मैं एक हैक का सुझाव दे सकता हूं। असल में, कोई भी इस मामले में आईओ मोनैड पर आधारित होने पर सीपीएस को अंदर लाने के लिए समवर्तीता का फायदा उठा सकता है।

यहाँ हैक है:

data CPSControl b = CPSControl (MVar()) (MVar b) 

startDebugCps :: ((a -> IO()) -> IO b) -> IO (a, CPSControl b) 
startDebugCps cps = do 
    cpsVal <- newEmptyMVar 
    retVal <- newEmptyMVar 
    stop <- newEmptyMVar 
    _ <- forkIO $ do 
     x <- cps $ \c -> putMVar cpsVal c >> takeMVar stop 
     putMVar retVal x 
    s <- takeMVar cpsVal 
    return (s, CPSControl stop retVal) 

stopDebugCps :: CPSControl b -> IO b 
stopDebugCps (CPSControl stop retVal) = do 
    putMVar stop() 
    takeMVar retVal 

testCps :: (String -> IO()) -> IO String 
testCps act = do 
    putStrLn "testCps: begin" 
    act "here's some string!" 
    putStrLn "testCps: end" 
    return "some return value" 

एक त्वरित परीक्षण:

> (x, ctrl) <- startDebugCps testCps 
testCps: begin 
> x 
"here's some string!" 
> stopDebugCps ctrl 
testCps: end 
"some return value"