core.logic में 'बाहरी शामिल' अनुकरण कैसे करें?

Question

मैंने अभी कोर.लॉगिक के साथ खेलना शुरू कर दिया है, और इस पर काम करने के लिए मैं कुछ सरल कार्यान्वित करने की कोशिश कर रहा हूं जो कि एक समस्या के समान है जिसे मैं वर्तमान में पेशेवर रूप से काम कर रहा हूं। हालांकि, समस्या का एक हिस्सा मुझे फंस गया है ...

मेरे उदाहरण के सरलीकरण के रूप में, यदि मेरे पास वस्तुओं की सूची है, और उनमें से कुछ केवल कुछ देशों में उपलब्ध हैं, और कुछ विशिष्ट में उपलब्ध नहीं हैं देशों। मैं आइटम की सूची निर्दिष्ट सक्षम होने के लिए चाहते हैं, और अपवाद हैं, कुछ की तरह:

(defrel items Name Color) 
(defrel restricted-to Country Name) 
(defrel not-allowed-in Country Name) 

(facts items [['Purse 'Blue] 
       ['Car 'Red] 
       ['Banana 'Yellow]]) 

(facts restricted-to [['US 'Car]]) 

(facts not-allowed-in [['UK 'Banana] 
         ['France 'Purse]]) 

संभव हो तो, मैं था बल्कि नहीं निर्दिष्ट अनुमति-इन सभी देशों के लिए, प्रतिबंधों के साथ वस्तुओं के सेट के रूप में अपेक्षाकृत छोटा है, और मैं किसी दिए गए देश के लिए किसी आइटम के लिए अनुमति/बहिष्कृत करने के लिए एक ही परिवर्तन करने में सक्षम होना चाहता हूं।

मैं एक नियम है कि एक देश के लिए की आइटम/रंग सूची प्रदान करती है, तो निम्न बाधाओं के साथ कैसे लिख सकते हैं:

• आइटम आइटम
• देश/मद चाहिए की सूची में होना चाहिए 'नहीं-अनुमति के रखने वाले' सूची में नहीं जा
• कोई एक:
  • में कोई भी देश नहीं है प्रतिबंधित करने कि आइटम
  • देश/आइटम जोड़ी restricted- में है के लिए सूची सूची

वहाँ किसी तरह यह करने के लिए है? क्या मैं पूरी तरह से गलत तरीके से चीजों के बारे में सोच रहा हूं?

Answer 1

आमतौर पर जब आप तर्क प्रोग्रामिंग में लक्ष्यों को अस्वीकार करना शुरू करते हैं, तो आपको गैर-रिलेशनल ऑपरेशंस (प्रोलॉग में कटौती, कोर.लॉगिक में कोंडा) तक पहुंचने की आवश्यकता होती है।

इस समाधान को केवल जमीन के तर्क के साथ बुलाया जाना चाहिए।

(defn get-items-colors-for-country [country] 
    (run* [q] 
    (fresh [item-name item-color not-country] 
     (== q [item-name item-color]) 
     (items item-name item-color) 
     (!= country not-country) 

     (conda 
     [(restricted-to country item-name) 
     (conda 
      [(not-allowed-in country item-name) 
      fail] 
      [succeed])] 
     [(restricted-to not-country item-name) 
     fail] 
     ;; No entry in restricted-to for item-name 
     [(not-allowed-in country item-name) 
     fail] 
     [succeed])))) 

(get-items-colors-for-country 'US) 
;=> ([Purse Blue] [Banana Yellow] [Car Red]) 

(get-items-colors-for-country 'UK) 
;=> ([Purse Blue]) 

(get-items-colors-for-country 'France) 
;=> ([Banana Yellow]) 

(get-items-colors-for-country 'Australia) 
;=> ([Purse Blue] [Banana Yellow]) 

Full solution

Answer 2

Conda कोड complexifies सकता है, NAFC उपयोग कर, आप और अधिक आसानी से लक्ष्यों को पुन: व्यवस्थित अगर आप चाहते हैं कर सकते हैं। यह अभी भी गैर-संबंधपरक है! :)

(ns somenamespace 
    (:refer-clojure :exclude [==]) 
    (:use [clojure.core.logic][clojure.core.logic.pldb])) 

(db-rel items Name Color) 
(db-rel restricted-to Country Name) 
(db-rel not-allowed-in Country Name) 

(def stackoverflow-db 
    (db [items 'Purse 'Blue] 
     [items 'Car 'Red] 
     [items 'Banana 'Yellow] 
     [restricted-to 'US 'Car] 
     [not-allowed-in 'UK 'Banana] 
     [not-allowed-in 'France 'Purse])) 


(defn get-items-colors-for-country [country] 
    (with-db stackoverflow-db 
    (run* [it co] 
     (items it co) 
     (nafc not-allowed-in country it) 
     (conde 
      [(restricted-to country it)] 
      [(nafC#(fresh [not-c] (restricted-to not-c %)) it)])))) 

(get-items-colors-for-country 'US) 
;=> ([Purse Blue] [Banana Yellow] [Car Red]) 

(get-items-colors-for-country 'UK) 
;=> ([Purse Blue]) 

(get-items-colors-for-country 'France) 
;=> ([Banana Yellow]) 

(get-items-colors-for-country 'Australia) 
;=> ([Purse Blue] [Banana Yellow]) 

अधिक उदाहरण के लिए: https://gist.github.com/ahoy-jon/cd0f025276234de464d5