TStringList के addObject विधि

Question

मैं पता है कि इस विधि कॉल करता हैं:

stringList.addObject(String,Object); 

मैं भी पता है कि इस संपत्ति करता हैं:

stringList.Objects[i] 

यह कुंजी, मान युग्म की तरह लग रहा है, जबकि जोड़ने। लेकिन एक लूप में पुनर्प्राप्त करते समय क्या प्राप्त किया जाता है?

मैं आइटम भी देखता हूं [i] कॉल।

मैं टीस्ट्रिंगलिस्ट ऑपरेशंस और टीएलआईस्ट ऑपरेशंस से उलझन में हूं।

Answer 1

AddObject विधि आपको आइटम संपत्ति में संग्रहीत स्ट्रिंग से जुड़े एक टॉब्जेक्ट पता (सूचक) को स्टोर करने देता है। Objects संपत्ति संग्रहीत वस्तुओं तक पहुंच के लिए है।

इस सरल नमूना को जांचें जो प्रत्येक स्ट्रिंग से जुड़े एक पूर्णांक मान को संग्रहीत करने के लिए AddObject का उपयोग करता है।

var 
List : TStringList; 
I : integer; 
begin 
    try 
    List:=TStringList.Create; 
    try 
     List.AddObject('Item 1', TObject(332)); 
     List.AddObject('Item 2', TObject(345)); 
     List.AddObject('Item 3', TObject(644)); 
     List.AddObject('Item 4', TObject(894)); 

     for I := 0 to List.Count-1 do 
     Writeln(Format('The item %d contains the string "%s" and the integer value %d',[I, List[I], Integer(List.Objects[i])])); 
    finally 
     List.Free; 
    end; 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
    Readln; 
end. 

Answer 2

TStringList तारों की एक सूची से अधिक है।

यह नाम मूल्य जोड़े के लिए इस्तेमाल किया जा सकता:

stringlist.Values['apple'] := 'one'; 
stringlist.Values['banana'] := 'two'; 

लेकिन यह भी किसी भी वस्तु (या किसी भी सूचक) के साथ तार संबद्ध करने के लिए इस्तेमाल किया जा सकता।

stringlist.AddObject('apple', TFruit.Create); 
stringlist.AddObject('banana', TFruit.Create); 


i := stringlist.IndexOf('apple'); 
if i >= 0 then 
    myfruit := stringlist.Objects[i] as TFruit; 

टीएलिस्ट एक सूची है जो पॉइंटर्स स्टोर करती है। वे तारों से जुड़े नहीं हैं।

Answer 3

यह आइटमों की एक जोड़ी जोड़ता है: TStringList.Strings सूची में एक प्रविष्टि, और TStringList.Objects सूची में TObject से मेल खाता है।

यह आपको उदाहरण के लिए, स्ट्रिंग्स की एक सूची संग्रहीत करने की अनुमति देता है जो आइटम के लिए नाम प्रदान करते हैं, और एक ऑब्जेक्ट जो मेल खाने वाला आइटम है।

type 
    TPerson=class 
    FFirstName, FLastName: string; 
    FDOB: TDateTime; 
    FID: Integer; 
    private 
    function GetDOBAsString: string; 
    function GetFullName: string; 
    published 
    property FirstName: string read FFirstName write FFirstName; 
    property LastName: string read FLastName write FLastName; 
    property DOB: TDateTime read FDOB write FDOB; 
    property DOBString: string read GetDOBAsString; 
    property FullName: string read GetFullName; 
    property ID: Integer read FID write FID; 
    end; 

implementation 

{TPerson} 
function TPerson.GetDOBAsString: string; 
begin 
    Result := 'Unknown'; 
    if FDOB <> 0 then 
    Result := DateToStr(FDOB); 
end; 

function TPerson.GetFullName: string; 
begin 
    Result := FFirstName + ' ' + FLastName; // Or FLastName + ', ' + FFirstName 
end; 

var 
    PersonList: TStringList; 
    Person: TPerson; 
    i: Integer; 
begin 
    PersonList := TStringList.Create; 
    try 
    for i := 0 to 9 do 
    begin 
     Person := TPerson.Create; 
     Person.FirstName := 'John'; 
     Person.LastName := Format('Smith-%d', [i]); // Obviously, 'Smith-1' isn't a common last name. 
     Person.DOB := Date() - RandRange(1500, 3000); // Make up a date of birth 
     Person.ID := i; 
     PersonList.AddObject(Person.LastName, Person); 
    end; 

    // Find 'Smith-06' 
    i := PersonList.IndexOf('Smith-06'); 
    if i > -1 then 
    begin 
     Person := TPerson(PersonList[i]); 
     ShowMessage(Format('Full Name: %s, ID: %d, DOB: %s', 
         [Person.FullName, Person.ID, Person.DOBString])); 
    end; 
    finally 
    for i := 0 to PersonList.Count - 1 do 
     PersonList.Objects[i].Free; 
    PersonList.Free; 
    end; 

यह स्पष्ट रूप से एक प्रदूषित उदाहरण है, क्योंकि ऐसा कुछ नहीं है जिसे आप वास्तव में उपयोगी पाते हैं। यह अवधारणा को प्रदर्शित करता है, यद्यपि।

एक और आसान उपयोग स्ट्रिंग के साथ एक पूर्णांक मूल्य को संग्रहीत करने के लिए है (उदाहरण के लिए, TComboBox या TListBox में आइटमों की एक सूची दिखा रहा है और डेटाबेस क्वेरी में उपयोग के लिए संबंधित आईडी)। इस मामले में, आपको केवल Objects सरणी में पूर्णांक टाइप करना होगा (या कुछ और जो आकारऑफ (सूचक) है)।

// Assuming LBox is a TListBox on a form: 
while not QryItems.Eof do 
begin 
    LBox.Items.AddObject(QryItem.Fields[0].AsString, TObject(QryItem.Fields[1[.AsInteger)); 
    QryItems.Next; 
end; 

// User makes selection from LBox 
i := LBox.ItemIndex; 
if i > -1 then 
begin 
    ID := Integer(LBox.Items.Objects[i]); 
    QryDetails.ParamByName('ItemID').AsInteger := ID; 
    // Open query and get info. 
end; 

एक वास्तविक TObject के अलावा अन्य चीजों के भंडारण के मामले में, आप सामग्री को मुक्त करने की जरूरत नहीं है। चूंकि वे वास्तविक वस्तुएं नहीं हैं, इसलिए TStringList को छोड़कर मुक्त करने के लिए कुछ भी नहीं है।