डेल्फी: किसी फ़ंक्शन को कॉल करें जिसका नाम स्ट्रिंग

Question

में संग्रहीत किया गया है क्या यह फ़ंक्शन को कॉल करना संभव है जिसका नाम डेल्फी में स्ट्रिंग में संग्रहीत है?

Answer 1

कृपया आप जो हासिल करने की कोशिश कर रहे हैं, उसके बारे में अधिक जानकारी दें।

मैं जानता हूँ कि जहाँ तक:

• ऐसा एक यादृच्छिक समारोह कॉल करने के लिए संभव नहीं है।
• कक्षा और ऑब्जेक्ट फ़ंक्शंस (MyObject.Function) के लिए यह आरटीटीआई के साथ किया जा सकता है, लेकिन यह बहुत काम है।
• यदि आपको केवल एक विशेष प्रकार के कार्यों को कॉल करने की आवश्यकता है (कहें, फ़ंक्शन (पूर्णांक, पूर्णांक): स्ट्रिंग), यह बहुत आसान है।

पिछले एक के लिए, एक समारोह प्रकार की घोषणा है, तो एक समारोह सूचक हो और इस तरह यह डाली:

type 
    TMyFuncType = function(a: integer; b: integer): string of object; 

    TMyClass = class 
    published 
    function Func1(a: integer; b: integer): string; 
    function Func2(a: integer; b: integer): string; 
    function Func3(a: integer; b: integer): string; 
    public 
    function Call(MethodName: string; a, b: integer): string; 
    end; 

function TMyClass.Call(MethodName: string; a, b: integer): string; 
var m: TMethod; 
begin 
    m.Code := Self.MethodAddress(MethodName); //find method code 
    m.Data := pointer(Self); //store pointer to object instance 
    Result := TMyFuncType(m)(a, b); 
end; 

{...} 

//use it like this 
var MyClass: TMyClass; 
begin 
    MyClass := TMyClass.Create; 
    MyClass.Call('Func1', 3, 5); 
    MyClass.Call('Func2', 6, 4); 
    MyClass.Destroy; 
end. 

Answer 2

यदि आप पूछ रहे हैं कि जावास्क्रिप्ट eval() कुछ ऐसा है जो डेल्फी में संभव है, तो डेल्फी देशी कोड में संकलित होने के बाद से यह आसानी से प्राप्त नहीं किया जा सकता है।

आप केवल कुछ तार आप हमेशा कर सकते हैं समर्थन करने के लिए की जरूरत है कई if या एक case ... कुछ की तरह:

if myString = 'myFunction' then 
    myFunction(); 

Answer 3

आप प्रकाशित गुणों के साथ एक या अधिक वर्गों क्राफ्टिंग द्वारा कुछ इस तरह कर सकते हैं कि उनके पढ़ने और लिखने की कार्यक्षमता को लागू करने के लिए कार्यों का उपयोग करें। गुणों को फिर आरटीटीआई प्रतिबिंब और संदर्भित करके खोजा जा सकता है, जिससे अंतर्निहित कार्यों को बुलाया जा सकता है।

वैकल्पिक रूप से, आप किसी तालिका में फ़ंक्शन पॉइंटर्स स्टोर कर सकते हैं, या यहां तक ​​कि TStringList की ऑब्जेक्ट प्रॉपर्टी भी संग्रहीत कर सकते हैं और स्ट्रिंग नाम से उन्हें प्रभावी रूप से इंडेक्स कर सकते हैं।

डेल्फी में नाम से फ़ंक्शन की सीधे कॉलिंग संभव नहीं है।

Answer 4

मैं कोई भी एक dispatch table सुझाव दिया है हैरान हूँ। यह वही है जो इसके लिए है।

program RPS; 

uses 
    SysUtils, 
    Generics.Collections; 

type 
    TDispatchTable = class(TDictionary<string, TProc>); 

procedure Rock; 
begin 
end; 

procedure Paper; 
begin 
end; 

procedure Scissors; 
begin 
end; 

var 
    DispatchTable: TDispatchTable; 

begin 
    DispatchTable := TDispatchTable.Create; 
    try 
    DispatchTable.Add('Rock', Rock); 
    DispatchTable.Add('Paper', Paper); 
    DispatchTable.Add('Scissors', Scissors); 

    DispatchTable['Rock'].Invoke; // or DispatchTable['Rock'](); 
    finally 
    DispatchTable.Free; 
    end; 
end. 

मैंने जो कार्यान्वयन लिखा वह जेनरिक का उपयोग करता है, इसलिए यह केवल डेल्फी 200+ के साथ काम करेगा। पुराने संस्करणों के लिए यह शायद TStringList और command pattern

Answer 5

आपने अपना डेल्फी संस्करण निर्दिष्ट नहीं किया है, हालांकि यदि आपके पास डेल्फी 2010 (+) है तो आप इसे बढ़ाए गए आरटीटीआई का उपयोग करके कर सकते हैं, मैं नहीं हूं विशेषज्ञ उन पर है, लेकिन मैं आप के लिए इस नमूने की कोशिश की:

TProcClass = class 
    public 
     procedure SayHi; 
     function GetSum(X,Y:Integer): Integer; 
    end; 

uses 
    Rtti; 

{ TProcClass } 

procedure TProcClass.SayHi; 
begin 
    ShowMessage('Hi'); 
end; 

function TProcClass.GetSum(X, Y: Integer): Integer; 
begin 
    ShowMessage(IntToStr(X + Y)); 
end; 

procedure ExecMethod(MethodName:string; const Args: array of TValue); 
var 
R : TRttiContext; 
T : TRttiType; 
M : TRttiMethod; 
begin 
    T := R.GetType(TProcClass); 
    for M in t.GetMethods do 
    if (m.Parent = t) and (m.Name = MethodName)then 
     M.Invoke(TProcClass.Create,Args) 
end; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    ExecMethod('SayHi',[]); 
    ExecMethod('GetSum',[10,20]); 
end; 

अच्छी बातें, यदि आप पैरामीटर के साथ प्रक्रिया या कार्य हो इसे और अधिक काम के बिना काम करेंगे।

Answer 6

डेल्फी 2010 के साथ आप पैरामीटर के साथ विधि का आह्वान करने के लिए JSON और SuperObject का उपयोग कर सकते हैं।

http://code.google.com/p/superobject/source/browse/#svn/trunk

आप की जरूरत है, वहाँ भी json के लिए एक्सएमएल को बदलने के लिए एक XML पार्सर है।

TForm1 = class(TForm) 
    Button1: TButton; 
    procedure Button1Click(Sender: TObject); 
    private 
    { Private declarations } 
    public 
    { Public declarations } 
    procedure TestMethod(const value: string); 
    end; 

var 
    Form1: TForm1; 

implementation 
uses superobject; 

{$R *.dfm} 

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    SOInvoke(Self, 'TestMethod', SO('{value: "hello"}')); 
end; 

procedure TForm1.TestMethod(const value: string); 
begin 
    Caption := value; 
end; 

Answer 7

प्रत्येक कार्य को एक क्रिया में रखें। तो फिर तुम नाम से कार्रवाई पा सकते हैं और निष्पादित यह

function ExecuteActionByName(const S: String); 
var 
    I: Integer; 
begin 
    for I := 0 to MainForm.ComponentCount-1 do 
    if (MainForm.Components[I] is TAction) 
    and SameText(TAction(MainForm.Components[I]).Name,S) then 
    begin 
     TAction(MainForm.Components[I]).Execute; 
     Break; 
    end; 
end; 

Answer 8

ठीक है, मैं बहुत देर पार्टी के लिए कर रहा हूँ, लेकिन आप निश्चित रूप से इस कोड के साथ नाम से दिनचर्या कॉल कर सकते हैं (कुछ सीमाएं सोचा हैं)

type 
    TExec = procedure of Object; 
    // rest of section... 

procedure TMainForm.ExecuteMethod(MethodName : String); 
var 
    Exec : TExec; 
    Routine : TMethod; 
begin 
    Routine.Data := Pointer(Form1); 
    Routine.Code := Form1.MethodAddress(MethodName); 
    if Not Assigned(Routine.Code) then 
     Exit; 

    Exec   := TExec(Routine); 
    Exec; 
end; 

शायद ज़रुरत पड़े कोई (बहुत दुर्लभ परिस्थितियों को छोड़कर) डेल्फी 7/2010