स्ट्रिंग। स्प्लिट अजीब काम करता है जब अंतिम मान खाली होता है

Question

मैं अपनी स्ट्रिंग को सरणी में विभाजित करना चाहता हूं लेकिन आखिरी "मान" खाली होने पर यह खराब काम करता है। कृपया मेरा उदाहरण देखें। क्या यह बग या फीचर है? क्या वर्कअराउंड के बिना इस फ़ंक्शन का उपयोग करने का कोई तरीका है?

var 
    arr: TArray<string>; 

    arr:='a;b;c'.Split([';']); //length of array = 3, it's OK 
    arr:='a;b;c;'.Split([';']); //length of array = 3, but I expect 4 
    arr:='a;b;;c'.Split([';']); //length of array = 4 since empty value is inside 
    arr:=('a;b;c;'+' ').Split([';']); //length of array = 4 (primitive workaround with space) 

Answer 1

यह व्यवहार बदला नहीं जा सकता है। यह स्प्लिट फ़ंक्शन कैसे काम करता है इसे अनुकूलित करने का कोई तरीका नहीं है। मुझे संदेह है कि आपको अपना खुद का विभाजन कार्यान्वयन प्रदान करने की आवश्यकता होगी। माइकल एरिकसन मददगार रूप से एक टिप्पणी में बताते हैं कि System.StrUtils.SplitString आपकी इच्छानुसार व्यवहार करता है।

डिजाइन मुझे खराब लगता है। उदाहरण

Length('a;'.Split([';'])) = 1 

और अभी तक

Length(';a'.Split([';'])) = 2 

इस विषमता के लिए गरीब डिजाइन का एक स्पष्ट संकेत है। यह आश्चर्यजनक है कि परीक्षण ने इसकी पहचान नहीं की थी।

तथ्य यह है कि डिज़ाइन इतना स्पष्ट रूप से संदेह है कि यह एक बग रिपोर्ट सबमिट करने योग्य हो सकता है। मैं उम्मीद करता हूं कि यह किसी भी बदलाव से मौजूदा कोड को प्रभावित करेगा क्योंकि इससे इनकार किया जा सकता है। लेकिन आप कभी नहीं जान पाते।

मेरे सिफारिशें:

1. अपने स्वयं के विभाजन कार्यान्वयन के रूप में आप की आवश्यकता करता है कि का उपयोग करें।
2. एक बग रिपोर्ट सबमिट करें।

---

जबकि System.StrUtils.SplitString आप क्या चाहते हैं करता है, इसके प्रदर्शन को महान नहीं है। इससे कोई फर्क नहीं पड़ता। इस मामले में आपको इसका इस्तेमाल करना चाहिए।

{$APPTYPE CONSOLE} 

uses 
    System.SysUtils, System.Diagnostics, System.StrUtils; 

function MySplit(const s: string; Separator: char): TArray<string>; 
var 
    i, ItemIndex: Integer; 
    len: Integer; 
    SeparatorCount: Integer; 
    Start: Integer; 
begin 
    len := Length(s); 
    if len=0 then begin 
    Result := nil; 
    exit; 
    end; 

    SeparatorCount := 0; 
    for i := 1 to len do begin 
    if s[i]=Separator then begin 
     inc(SeparatorCount); 
    end; 
    end; 

    SetLength(Result, SeparatorCount+1); 
    ItemIndex := 0; 
    Start := 1; 
    for i := 1 to len do begin 
    if s[i]=Separator then begin 
     Result[ItemIndex] := Copy(s, Start, i-Start); 
     inc(ItemIndex); 
     Start := i+1; 
    end; 
    end; 
    Result[ItemIndex] := Copy(s, Start, len-Start+1); 
end; 

const 
    InputString = 'asdkjhasd,we1324,wqweqw,qweqlkjh,asdqwe,qweqwe,asdasdqw'; 

var 
    i: Integer; 
    Stopwatch: TStopwatch; 

const 
    Count = 3000000; 

begin 
    Stopwatch := TStopwatch.StartNew; 
    for i := 1 to Count do begin 
    InputString.Split([',']); 
    end; 
    Writeln('string.Split: ', Stopwatch.ElapsedMilliseconds); 

    Stopwatch := TStopwatch.StartNew; 
    for i := 1 to Count do begin 
    System.StrUtils.SplitString(InputString, ','); 
    end; 
    Writeln('StrUtils.SplitString: ', Stopwatch.ElapsedMilliseconds); 

    Stopwatch := TStopwatch.StartNew; 
    for i := 1 to Count do begin 
    MySplit(InputString, ','); 
    end; 
    Writeln('MySplit: ', Stopwatch.ElapsedMilliseconds); 
end. 

एक 32 बिट रिहाई के उत्पादन में मेरी E5530 पर XE7 साथ निर्माण होता है:

 
string.Split: 2798 
StrUtils.SplitString: 7167 
MySplit: 1428 

Answer 2

निम्नलिखित बहुत स्वीकार किए जाते हैं जवाब देने के लिए समान है, लेकिन फिर भी, यदि प्रदर्शन मामलों, तो मैं इस की पेशकश i) यह एक सहायक विधि है और ii) यह विभाजकों की एक सरणी स्वीकार करता है।

विधि इन कारणों से डेविड की तुलना में लगभग 30% अधिक है, लेकिन वैसे भी उपयोगी हो सकता है।

program ImprovedSplit; 

{$APPTYPE CONSOLE} 

uses 
    System.SysUtils; 

type 
    TStringHelperEx = record helper for string 
    public 
    function SplitEx(const Separator: array of Char): TArray<string>; 
    end; 

var 
    TestString : string; 
    StringArray : TArray<String>; 


{ TStringHelperEx } 

function TStringHelperEx.SplitEx(const Separator: array of Char): TArray<string>; 
var 
    Str : string; 
    Buf, Token : PChar; 
    i, cnt : integer; 
    sep : Char; 
begin 
    cnt := 0; 
    Str := Self; 
    Buf := @Str[1]; 
    SetLength(Result, 0); 

    if Assigned(Buf) then begin 

    for sep in Separator do begin 
     for i := 0 to Length(Self) do begin 
     if Buf[i] = sep then begin 
      Buf[i] := #0; 
      inc(cnt); 
     end; 
     end; 
    end; 

    SetLength(Result, cnt + 1); 

    Token := Buf; 
    for i := 0 to cnt do begin 
     Result[i] := StrPas(Token); 
     Token := Token + Length(Token) + 1; 
    end; 

    end; 
end; 

begin 
    try 
    TestString := ''; 
    StringArray := TestString.SplitEx([';']); 
    Assert(Length(StringArray) = 0, 'Failed test for Empty String'); 

    TestString := 'a'; 
    StringArray := TestString.SplitEx([';']); 
    Assert(Length(StringArray) = 1, 'Failed test for Single String'); 

    TestString := ';'; 
    StringArray := TestString.SplitEx([';']); 
    Assert(Length(StringArray) = 2, 'Failed test for Single Separator'); 

    TestString := 'a;'; 
    StringArray := TestString.SplitEx([';']); 
    Assert(Length(StringArray) = 2, 'Failed test for Single String + Single End-Separator'); 

    TestString := ';a'; 
    StringArray := TestString.SplitEx([';']); 
    Assert(Length(StringArray) = 2, 'Failed test for Single String + Single Start-Separator'); 

    TestString := 'a;b;c'; 
    StringArray := TestString.SplitEx([';']); 
    Assert(Length(StringArray) = 3, 'Failed test for Simple Case'); 

    TestString := ';a;b;c;'; 
    StringArray := TestString.SplitEx([';']); 
    Assert(Length(StringArray) = 5, 'Failed test for Start and End Separator'); 

    TestString := '0;1;2;3;4;5;6;7;8;9;0;1;2;3;4;5;6;7;8;9;0;1;2;3;4;5;6;7;8;9;0;1;2;3;4;5;6;7;8;9'; 
    StringArray := TestString.SplitEx([';', ',']); 
    Assert(Length(StringArray) = 40, 'Failed test for Larger Array'); 

    TestString := '0;1;2;3;4;5;6;7;8;9;0;1;2;3;4;5;6;7;8;9;0,1,2,3,4,5,6,7,8,9,0;1;2;3;4;5;6;7;8;9'; 
    StringArray := TestString.SplitEx([';', ',']); 
    Assert(Length(StringArray) = 40, 'Failed test for Array of Separators'); 

    Writeln('No Errors'); 

    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 

    Writeln('Press ENTER to continue'); 
    Readln(TestString); 

end.