क्यूएमएल: डिजाइन धारणा से qml पृष्ठों के बीच नेविगेशन

Question

हमें एक QtQuick प्रोजेक्ट विकसित करने की आवश्यकता है, जहां हमारे पास लगभग 100 स्क्रीन हैं।

मैंने नेविगेशन के लिए डेमो प्रोजेक्ट बनाने की कोशिश की थी जिसमें बटन क्लिक पर तीन स्क्रीन हैं। मैंने पृष्ठों के बीच नेविगेशन में 'राज्यों' की अवधारणाओं का उपयोग किया था। शुरुआत में मैंने 'लोडर' का उपयोग करके भी कोशिश की लेकिन लोडर पिछले पृष्ठ को बनाए रखने में सक्षम नहीं था, यह नेविगेशन के दौरान पूरे पृष्ठ को फिर से लोड कर रहा था।

नीचे main.qml

// import QtQuick 1.0 // to target S60 5th Edition or Maemo 5 
import QtQuick 1.1 

Rectangle { 
    id:main_rectangle 
    width: 360 
    height: 640 

    Page1{ 
     id:page1 
    } 

    Page2{ 
     id:page2 
    } 

    Page3{ 
     id:page3 
    } 

    states: [ 
     State { 

      name: "page2" 

      PropertyChanges { target: page3; visible:false; } 
      PropertyChanges { target: page1; visible:false; } 
      PropertyChanges { target: page2; visible:true; } 
     }, 
     State { 
      name: "page1" 
      PropertyChanges { target: page3; visible:false; } 
      PropertyChanges { target: page2; visible:false; } 
      PropertyChanges { target: page1; visible:true; } 
     }, 

     State { 
      name: "page3" 
      PropertyChanges { target: page1; visible:false; } 
      PropertyChanges { target: page2; visible:false; } 
      PropertyChanges { target: page3; visible:true; } 
     } 

    ] 

} 

के कोड स्निपेट इस तीन स्क्रीन के साथ छोटे POC के साथ अच्छी तरह से चलाता है इसके संभव 100 स्क्रीन के लिए राज्यों को परिभाषित करने के लिए नहीं है, लेकिन।

डिजाइनिंग पहलू से हमने सी ++ नियंत्रक बनाने के लिए निष्कर्ष निकाला है, हम राज्यों को नियंत्रित करते हैं, विभिन्न पृष्ठों की दृश्यता।

सी ++ में 'राज्य' तर्क को कार्यान्वित करने के सुझावों की आवश्यकता है।

Answer 1

मैं क्यूटी त्वरित घटक से स्टैकव्यू का उपयोग करने का सुझाव देता हूं। Here इसका प्रलेखन है।

Answer 2

यहां कॉन्फ़िगर करने योग्य पृष्ठ सूची (एक मॉडल की तरह) + एक पुनरावर्तक + लोडर आइटम का उपयोग करके सादे क्यूएमएल में सबसे आसान समाधान है, स्टार्टअप (आलसी instanciation) पर सब कुछ लोड नहीं करने के लिए और इसे छिपाने के बाद एक पृष्ठ को नष्ट नहीं करने के लिए अगर हम इसे वापस आते हैं तो इसे फिर से लोड करना होगा):

import QtQuick 1.1 

Rectangle { 
    id: main_rectangle; 
    width: 360; 
    height: 640; 

    // Put the name of the QML files containing your pages (without the '.qml') 
    property variant pagesList : [ 
     "Page1", 
     "Page2", 
     "Page3", 
     "Page4", 
     "Page5" 
    ]; 

    // Set this property to another file name to change page 
    property string currentPage : "Page1"; 

    Repeater { 
     model: pagesList; 
     delegate: Loader { 
      active: false; 
      asynchronous: true; 
      anchors.fill: parent; 
      visible: (currentPage === modelData); 
      source: "%1.qml".arg(modelData) 
      onVisibleChanged:  { loadIfNotLoaded(); } 
      Component.onCompleted: { loadIfNotLoaded(); } 

      function loadIfNotLoaded() { 
       // to load the file at first show 
       if (visible && !active) { 
        active = true; 
       } 
      } 
     } 
    } 
} 

आशा है कि इससे मदद मिलती है!