"बड़े फोंट" के साथ संवाद संगत बनाएं।

Question

आपको लगता है कि मानक फ़ॉन्ट्स (9 6 डीपीआई) और "बड़ी फोंट" सेटिंग (120 डीपीआई) दोनों के साथ एक विंडोज संवाद संगत बनाने के लिए सर्वोत्तम प्रथाएं हैं ताकि ऑब्जेक्ट ओवरलैप न हो जाएं या कट ऑफ हो जाएं?

बीटीडब्लू: बस अगर यह प्रासंगिक है, तो मुझे डेल्फी संवाद के लिए ऐसा करने में दिलचस्पी है।

अग्रिम धन्यवाद!

Answer 1

"Considerations When Dynamically Resizing Forms and Controls" के तहत, D2007 सहायता फ़ाइल में एक बहुत अच्छा लेख है (ध्यान दें कि यूआरएल मदद फ़ाइल के लिए है, न कि वेब पेज भी)।

उसी नाम के तहत एक ही विषय, D2010 help file (ऊपर जैसा यूआरएल के बारे में समान चेतावनी), या docwiki पर पाया जा सकता है।

यह TForm.Scaled और TForm.ScaleBy की जांच करने के लिए भी सार्थक (कम से कम थोड़ा सा) है।

Answer 2

सामान्य रूप से इस उद्देश्य के लिए लेआउट प्रबंधकों का उपयोग करना चाहिए। यही वह है जिसे वे डिजाइन कर रहे हैं।

डेल्फी (लंबे समय तक इसके साथ काम नहीं किया) में ऐसे प्रबंधक नहीं हैं लेकिन तब से अलग-अलग डीपीआई को संभालने में सक्षम हैं। आपको यह सुनिश्चित करने के लिए घटकों के ऑटोसाइज प्रोपरी का उपयोग करना होगा कि उनके पास प्रदर्शित टेक्स्ट के लिए सही आकार है। घटकों के ओवरलैपिंग को रोकने के लिए उन्हें संरेखण और एंकर गुणों का उपयोग करके फ़ॉर्म पर व्यवस्थित करें। आखिरकार आपको उचित लेआउट प्राप्त करने के लिए कंटेनरों में घटक समूह करना होगा।

Answer 3

• कभी भी नियंत्रण और इसके वर्णन लेबल को एक तरफ न रखें, हमेशा लेबल को इसके ऊपर रखें।

लेकिन इसके अलावा? शायद:

• लेबल के दाएं और नीचे पर्याप्त जगह छोड़ दें ताकि बड़े फोंट का उपयोग होने पर वे अन्य नियंत्रणों के साथ ओवरलैप न हों।

मैंने कभी भी उस परिदृश्य में TLabeledEdit का उपयोग करने का प्रयास नहीं किया है, हो सकता है कि वे स्वचालित रूप से ऐसा करें?

Answer 4

कथित व्यावसायिक समाधान (डेवलपर एक्सप्रेस वीसीएल लेआउट प्रबंधक) हैं। लेकिन मुझे उनमें से किसी पर भरोसा नहीं है। मुझे संदेह है कि वर्तमान यूआई घटक सेट (वीसीएल) में एम्बरकाडेरो को इसे गंभीर कमजोरी के रूप में संबोधित करना चाहिए।

मुझे लगता है कि तीसरे पक्ष के घटक सेट अभी आपका सबसे तेज़ समाधान हो सकता है। यह वाणिज्यिक है लेकिन भारी महंगा नहीं है।

http://www.devexpress.com/products/VCL/ExLayoutControl/

Answer 5

यह कैसे मैं खिड़की के फ़ॉन्ट आकार सेटिंग की परवाह किए बिना डेल्फी VCL के पिक्सल के साथ सौदा करने की कोशिश है।

unit App.Screen; 

interface 

uses Controls; 

type 
    TAppScreen = class(TObject) 
    private 
    FDefaultPixelsPerInch: integer; 
    FPixelsPerInch: integer; 
    function GetPixelsPerInch: integer; 
    procedure SetPixelsPerInch(const Value: integer); 
    public 
    procedure AfterConstruction; override; 
    function DefaultPixelsPerInch: integer; 
    function InAcceptableRange(const aPPI: integer): boolean; 
    procedure ScaleControl(const aControl: TWinControl); 
    property PixelsPerInch: integer read GetPixelsPerInch write SetPixelsPerInch; 
    end; 

    TAppScreenHelper = class helper for TAppScreen 
    private 
    class var FInstance: TAppScreen; 
    class function GetInstance: TAppScreen; static; 
    public 
    class procedure Setup; 
    class procedure TearDown; 
    class property Instance: TAppScreen read GetInstance; 
    end; 

implementation 

uses 
    TypInfo, Windows, SysUtils, Forms, Graphics; 

type 
    TScreenEx = class(TScreen) 
    published 
    property PixelsPerInch; 
    end; 

    TScreenHelper = class helper for TScreen 
    public 
    procedure SetPixelsPerInch(Value: integer); 
    end; 

procedure TScreenHelper.SetPixelsPerInch(Value: integer); 
begin 
    PInteger(Integer(Self) + (Integer(GetPropInfo(TScreenEx, 'PixelsPerInch').GetProc) and $00FFFFFF))^ := Value; 
end; 

procedure TAppScreen.AfterConstruction; 
begin 
    inherited; 
    FDefaultPixelsPerInch := Screen.PixelsPerInch; 
    FPixelsPerInch := FDefaultPixelsPerInch; 
end; 

function TAppScreen.DefaultPixelsPerInch: integer; 
begin 
    Result := FDefaultPixelsPerInch; 
end; 

function TAppScreen.GetPixelsPerInch: integer; 
begin 
    Result := FPixelsPerInch; 
end; 

function TAppScreen.InAcceptableRange(const aPPI: integer): boolean; 
begin 
    if DefaultPixelsPerInch > aPPI then 
    Result := DefaultPixelsPerInch * 0.55 < aPPI 
    else if DefaultPixelsPerInch < aPPI then 
    Result := DefaultPixelsPerInch * 1.55 > aPPI 
    else 
    Result := True; 
end; 

procedure TAppScreen.ScaleControl(const aControl: TWinControl); 
begin 
    aControl.ScaleBy(PixelsPerInch, DefaultPixelsPerInch); 
end; 

procedure TAppScreen.SetPixelsPerInch(const Value: integer); 
begin 
    FPixelsPerInch := Value; 
    Screen.SetPixelsPerInch(FPixelsPerInch); 
end; 

class function TAppScreenHelper.GetInstance: TAppScreen; 
begin 
    if FInstance = nil then 
    FInstance := TAppScreen.Create; 
    Result := FInstance; 
end; 

class procedure TAppScreenHelper.Setup; 
begin 
    TAppScreen.Instance; 
end; 

class procedure TAppScreenHelper.TearDown; 
begin 
    FInstance.Free; 
    FInstance := nil; 
end; 

initialization 
    TAppScreen.Setup; 
finalization 
    TAppScreen.TearDown; 
end. 

अलग पिक्सल मूल्य के प्रभाव का परीक्षण करने के निम्नलिखित का प्रयास करें:

TAppScreen.Instance.PixelsPerInch := 120; 
TAppScreen.Instance.PixelsPerInch := 96; 
TAppScreen.Instance.PixelsPerInch := 150; 

आप से पहले PixelsPerInch बदलना चाहिए डेल्फी के VCL संवाद सहित TForm के वारिस का दृष्टांत।