गोटो इस समय अनपेक्षित था बैच विंडोज 7 स्टार्टर

Question

इस कोड को पोकीमॉन लड़ाई गेमप्ले का एक सरल संस्करण के समान बनाया गया है। मैंने केवल हमलों में कोड किया है। मैं पूरी तरह से परीक्षण कर रहा हूं, और पाया कि जब भी उपयोगकर्ता ने अपने हमले की पुष्टि की तो एक त्रुटि संदेश (गोटो अप्रत्याशित था)। चेतावनी !! कोड 96 लाइन लंबी है। अंत में, मैं समस्या अनुभाग डाल दूंगा, ताकि आप इस पहले विशाल खंड को छोड़ सकें।

@echo off 
Set H1=20 
Set A1=8 
Set D1=6 
Set S1=5 
Set H2=14 
Set A2=5 
Set D2=4 
Set S2=8 
:Begin 
CLS 
Echo Bulbasur 
Echo %H2%/14  /\  
Echo   (__) ___ 
Echo   l __lo.ol 
Echo   l_\ l_\" 
Echo.   
Echo  _ 
Echo */\ 
Echo \\l ) 
Echo \\__l Charmander 
Echo    %H1%/20 
Echo -Attack -Capture 
Echo -Item -Run 
Set /p Move=Action? 
If %move%==Attack goto Attack 
If %move%==Catpure goto capture 
If %move%==Item goto Item 
If %move%==Run Goto Run 
Echo I'm sorry, Charmander can't do that. 
Pause 
goto Begin 
:Attack 
ClS 
Echo Attacks 
Echo 1)Tackle 
Echo 2)Growl 
Echo 3)Ember 
Echo 4)Scratch 
Set /p attack=Which one? 
If %attack%==Tackle goto Tackle 
If %attack%==1 goto Tackle 
If %attack%==Growl Goto Growl 
If %attack%==2 goto Growl 
If %attack%==Ember goto Ember 
If %attack%==3 goto Ember 
If %attack%==Scratch goto Scratch 
If %attack%==4 goto Scratch 
If %attack%==Cancel goto Begin 
Echo I didn't get that 
Goto Attack 
:Tackle 
CLS 
Echo Tackle Hits The opponent where it hurts. EVERYWHERE. 
Echo Do you want to? 
set /p accept=Yes/No? 
If %acccept%==Yes goto Combat 
If %acccept%==No goto Begin 
Echo I didn't get that. 
goto Tackle 
:Growl 
CLS 
Echo Growl lowers the opponents attack. 
Echo Do you want to? 
set /p accept=Yes/No? 
If %acccept%==Yes goto Status 
If %acccept%==No goto Begin 
Echo I didn't get that. 
goto Growl 
:Scratch 
CLS 
Echo Scratch hits the foe with a claw. 
Echo Do you want to? 
set /p accept=Yes/No? 
If %acccept%==Yes goto Combat 
If %acccept%==No goto Begin 
Echo I didn't get that. 
goto Scratch 
:Ember 
CLS 
Echo Ember hits the opponent with a small fire. 
Echo Do you want to? 
set /p accept=Yes/No? 
If %acccept%==Yes goto Combat 
If %acccept%==No goto Begin 
Echo I didn't get that. 
goto Ember 
:Combat 
CLS 
If NOT %attack%==Growl If NOT %attack%==2 set /a H2=%H2%-(%A1%^2/%D2%) 
set /a H1=%H1%-(%A2%^2/%D1%) 
goto Begin 
:Status 
CLS 
Set /a A1=%A1%-1 
goto Combat 

समस्या क्षेत्र:

:Tackle 
CLS 
Echo Tackle Hits The opponent where it hurts. EVERYWHERE. 
Echo Do you want to? 
set /p accept=Yes/No? 
If %acccept%==Yes goto Combat 
If %acccept%==No goto Begin 
Echo I didn't get that. 
goto Tackle 

कोड यहाँ ठीक हो जाता है, लेकिन एक बार मैं यहाँ हूँ, यह गोटो आदेशों की उम्मीद नहीं है। कोई भी इस गोमांस को ठीक कर सकता है? (नोट: टैकल सिर्फ एक उदाहरण है। हमलों में से कोई भी काम नहीं करता है।) संपादित करें: यदि उपयोगकर्ता "हां", "नहीं", अस्पष्टता या कुछ भी नहीं डालता है, तो यह अभी भी एक ही त्रुटि संदेश प्रदान करता है (इस समय गोटो अप्रत्याशित था)

Answer 1

उपयोगकर्ता कुछ भी नहीं दर्ज करता है, अपने If लाइनों शायद कुछ इस तरह का मूल्यांकन:

… 
If ==Yes goto Combat 
If ==No goto Begin 
… 

जो वाक्य रचना सही नहीं है।

… 
set accept=default 
set /p accept=Yes/No? 
if … 

इस तरह, उपयोगकर्ता केवल एंटर दबाता है, accept चर default मूल्य बनी रहेगी, और बाद में if में समाप्त नहीं होगा: मैं कुछ डिफ़ॉल्ट मान के साथ set /p आदेश से पहले accept initialising सुझाव है त्रुटि।

Answer 2

आपकी समस्या है इस लाइन है कि:

set /p accept=Yes/No? 

एक ही चर नाम का उपयोग नहीं करता इन लोगों कि:

If %acccept%==Yes goto Combat 
If %acccept%==No goto Begin 

चर से ऊपर "सीसीसी" है, लेकिन पहले एक बस "सीसी "

संपादित

हाय, उपयोग r1205760; मुझे खर्च करने में कुछ समय मिला, इसलिए मैं आपका प्रोग्राम लेता हूं और इसे थोड़ा सा छोटा बना देता हूं। यह मेरा संस्करण है:

@echo off 

Setlocal EnableDelayedExpansion 
Set Actions=Attack Capture Item Run 
Set Attacks=Tackle Growl Ember Scratch Cancel 
Set i=0 
For %%a in (%Attacks%) do set /A i+=1 & set Attack[!i!]=%%a 

Set H1=20 
Set A1=8 
Set D1=6 
Set S1=5 
Set H2=14 
Set A2=5 
Set D2=4 
Set S2=8 

:Begin 
:Cancel 
CLS 
Echo Bulbasur 
Echo %H2%/14  /\  
Echo   (__) ___ 
Echo   l __lo.ol 
Echo   l_\ l_\" 
Echo.   
Echo  _ 
Echo */\ 
Echo \\l ) 
Echo \\__l Charmander 
Echo    %H1%/20 
Echo -Attack -Capture 
Echo -Item -Run 
Set /p Move=Action? 
For %%a in (%Actions%) do if /I %move%==%%a goto %move% 
Echo I'm sorry, Charmander can't do that. 
Pause 
goto Begin 

:Attack 
Cls 
Echo Attacks 
For %%a in (1 2 3 4) do echo %%a)!Attack[%%a]! 
Set /p attack=Which one? 
for %%a in (1 2 3 4) do if %attack%==%%a set attack=!Attack[%%a]! 
for %%a in (%Attacks%) do if /I %attack%==%%a goto %attack% 
Echo I didn't get that 
Pause 
Goto Attack 

:Tackle 
call :Confirm Tackle Hits The opponent where it hurts. EVERYWHERE. 
If %accept%==Yes goto Combat 
goto Begin 

:Growl 
call :Confirm Growl lowers the opponents attack. 
If %accept%==Yes goto Status 
goto Begin 

:Ember 
call :Confirm Ember hits the opponent with a small fire. 
If %accept%==Yes goto Combat 
goto Begin 

:Scratch 
call :Confirm Scratch hits the foe with a claw. 
If %accept%==Yes goto Combat 
goto Begin 

:Status 
Set /A A1-=1 
:Combat 
If /I NOT %attack%==Growl set /A H2=H2-(A1^2/D2) 
set /A H1=H1-(A2^2/D1) 
goto Begin 

:Confirm 
Cls 
Echo %* 
Echo Do you want to? 
set /p accept=Yes/No? 
For %%a in (Yes No) do if /I %accept%==%%a exit /B 
Echo I didn't get that. 
Pause 
goto Confirm 

Answer 3

आप उद्धरण में डाल दिया है:

if "%accept%"=="yes" goto combat 
if "%accept%"=="no" goto begin 

या बल्कि आप इसे केस संवेदी बनाना चाहते न हो तो:

if /i "%accept%"=="yes" goto combat 
if /i "%accept%"=="no" goto begin 

Answer 4

मुझे माफ करना,
यह डाउनवॉट्स के लिए सिर्फ एक सवाल है।
जो लोग पूछते हैं कि यह सुनिश्चित नहीं है कि समस्या उस भाग में होनी चाहिए।

उदा।

set a= 
if %a%==1 echo yes 

मैं सिर्फ इस लाइन पोस्ट करते हैं:

if %a%==1 echo yes 

तो यह सबके लिए पता होगा समस्या है क्या?

---

, चर के लिए याद रखें की तरह% एबीसी%, इसके साथ इसका इस्तेमाल करने ", [या {तो त्रुटि संदेश को रोकने के लिए के रूप में।

---

बेहतर है जैसे

set /p abc= 

और उपयोगकर्ता कुछ भी इनपुट नहीं करता है।
फिर अगली पंक्ति होनी चाहिए:

if %abc%==1 echo Hi 

लेकिन यह बन गया:

if ==1 echo Hi 

, के रूप में "% एबीसी%" == ""
लेकिन साथ "", यह

if ""=="1" echo Hi 

बन जाएगा और "" असमान के लिए "1" ।
समझें?

---

संपादित करें ---

आप विंडोज 7 (या अन्य संस्करण) का उपयोग कर रहे हैं, तो आप भी इस कोशिश कर सकते हैं:

choice /c YN /n /m "Confirm? [Y^|N] 

^ सिर्फ "पाइप" भागने है (|)।

आशा है कि यह आपके लिए उपयोगी होगा!