मैं क्रोमियम के साथ पोस्ट और हेडर डेटा कैसे भेजूं?

Question

मैं कुछ कोड को TWebBrowser से क्रोमियम में कनवर्ट करने का प्रयास कर रहा हूं लेकिन मुझे HTTP अनुरोध के साथ पोस्ट और हेडर डेटा भेजने का तरीका पता लग रहा है।

नीचे TWebBrowser कार्यक्षमता है जिसे मैं कार्यान्वित करने की कोशिश कर रहा हूं।

var 
VHeader, PostData: OleVariant; 


PostData := VarArrayCreate([0, Length(XMLString) - 1], varByte) ;  
HeaderData := 'Content-Type: application/x-www-form-urlencoded'+ '\n'; 

WebBrowser1.Navigate(StrUrl,EmptyParam,EmptyParam,PostData,VHeader); 

मैं क्रोमियम के साथ समकक्ष कैसे करूं?

Answer 1

डेल्फी क्रोमियम एंबेडेड के लिए अनुपलब्ध दस्तावेज के कारण, मैं सीईएफ के सी ++ संस्करण के लिए वेब अनुरोध भेजने के लिए आवश्यक आवश्यकताओं का उल्लेख करूंगा। इसलिए, आपको क्रोमियम में अनुरोध भेजने के लिए LoadRequest विधि का उपयोग करने की आवश्यकता है। इसका उपयोग करने के लिए, आपको और CefPostData ऑब्जेक्ट हेडर और डेटा विनिर्देश के लिए CefRequest अनुरोध ऑब्जेक्ट क्लास के ऑब्जेक्ट इंस्टेंस की आवश्यकता है।

uses 
    ceflib; 

function CreateField(const AValue: AnsiString): ICefPostDataElement; 
begin 
    Result := TCefPostDataElementRef.New; 
    Result.SetToBytes(Length(AValue), PAnsiChar(AValue)); 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Header: ICefStringMultimap; 
    Data: ICefPostData; 
    Request: ICefRequest; 
begin 
    Header := TCefStringMultimapOwn.Create; 
    Header.Append('Content-Type', 'application/x-www-form-urlencoded'); 

    Data := TCefPostDataRef.New; 
    Data.AddElement(CreateField('Data.id=27')); 
    Data.AddElement(CreateField('&Data.title=title')); 
    Data.AddElement(CreateField('&Data.body=body')); 

    Request := TCefRequestRef.New; 
    Request.Flags := WUR_FLAG_NONE; 
    Request.Assign('http://example.com/', 'POST', Data, Header); 

    Chromium1.Browser.MainFrame.LoadRequest(Request); 
end; 

ही उपरोक्त कोड का एक और संस्करण करना चाहिए:

this thread से हेनरी Gourvest के उदाहरण (डेल्फी CEF आवरण के लेखक) पर विस्तार, आप डेल्फी में निम्नलिखित छद्म कोड की तरह कुछ कोशिश कर सकते हैं :

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Header: ICefStringMultimap; 
    Data: ICefPostData; 
    Request: ICefRequest; 
begin 
    Request := TCefRequestRef.New; 
    Request.Url := 'http://example.com/'; 
    Request.Method := 'POST'; 
    Request.Flags := WUR_FLAG_NONE; 

    Header := TCefStringMultimapOwn.Create; 
    Header.Append('Content-Type', 'application/x-www-form-urlencoded'); 
    Request.SetHeaderMap(Header); 

    Data := TCefPostDataRef.New; 
    Data.AddElement(CreateField('Data.id=27')); 
    Data.AddElement(CreateField('&Data.title=title')); 
    Data.AddElement(CreateField('&Data.body=body')); 
    Request.PostData := Data; 

    Chromium1.Browser.MainFrame.LoadRequest(Request); 
end;