आईडीएचटीपी बस प्रतिक्रिया कोड प्राप्त करें

Question

मैं कुछ वेबसाइट जांच करने के लिए idhttp (इंडी) का उपयोग कर रहा हूं। मैं बस इतना करना चाहता हूं कि मेरा अनुरोध भेजने के बाद सर्वर से प्रतिक्रिया कोड की जांच करें, मैं वास्तव में सर्वर से HTML आउटपुट प्राप्त नहीं करना चाहता क्योंकि मैं केवल 200 ओके कोड के लिए निगरानी कर रहा हूं, कोई भी अन्य कोड का अर्थ है कि कुछ रूपों का मुद्दा है।

मैंने idhttp सहायता दस्तावेज़ों को देखा है और एकमात्र तरीका जिसे मैं संभवतः देख सकता हूं, यह कोड को MemoryStream पर असाइन करना होगा और फिर इसे सीधे साफ़ करें, हालांकि यह बहुत कुशल नहीं है और स्मृति का उपयोग करता है इसकी आवश्यकता नहीं है। क्या किसी साइट को कॉल करने और प्रतिक्रिया प्राप्त करने का कोई तरीका है लेकिन HTML को वापस भेज दिया गया है जो अधिक कुशल है और स्मृति को बर्बाद नहीं करता है?

वर्तमान में कोड इस तरह कुछ दिखाई देगा। हालांकि यह सिर्फ नमूना कोड है जिसे मैंने अभी तक परीक्षण नहीं किया है, मैं बस यह समझाने के लिए इसका उपयोग कर रहा हूं कि मैं क्या करने की कोशिश कर रहा हूं।

Procedure Button1Click(Sender: TObject); 

var 
http : TIdHttp; 
s : TStream; 
url : string; 
code : integer; 

begin 

    s := TStream.Create(); 
    http := Tidhttp.create(); 
    url := 'http://www.WEBSITE.com'; 

    try 

    http.get(url,s); 
    code := http.ResponseCode; 
    ShowMessage(IntToStr(code)); 

    finally 

    s.Free(); 
    http.Free(); 

end; 

Answer 1

TIdHTTP.Head() सबसे अच्छा विकल्प है। हालांकि, एक विकल्प के रूप में, नवीनतम संस्करण में आप TIdHTTP.Get() को शून्य गंतव्य TStream, या TIdEventStream के साथ किसी भी ईवेंट हैंडलर के साथ कॉल कर सकते हैं, और यह अभी भी सर्वर के डेटा को पढ़ेगा लेकिन इसे कहीं भी स्टोर नहीं करेगा।

किसी भी तरह से, यह भी ध्यान रखें कि यदि सर्वर एक विफलता वापस भेजता है ResponseCode, TIdHTTP एक अपवाद उठाएगा (जब तक आप AIgnoreReplies पैरामीटर का उपयोग विशिष्ट प्रतिक्रिया कोड मूल्य निर्दिष्ट करने के लिए करते हैं), तो आपको इसके लिए जिम्मेदार होना चाहिए साथ ही, उदाहरण के लिए:

procedure Button1Click(Sender: TObject); 
var 
    http : TIdHttp; 
    url : string; 
    code : integer; 
begin 
    url := 'http://www.WEBSITE.com'; 
    http := TIdHTTP.Create(nil); 
    try 
    try 
     http.Head(url); 
     code := http.ResponseCode; 
    except 
     on E: EIdHTTPProtocolException do 
     code := http.ResponseCode; // or: code := E.ErrorCode; 
    end; 
    ShowMessage(IntToStr(code)); 
    finally 
    http.Free(); 
    end; 
end; 

procedure Button2Click(Sender: TObject); 
var 
    http : TIdHttp; 
    url : string; 
    code : integer; 
begin 
    url := 'http://www.WEBSITE.com'; 
    http := TIdHTTP.Create(nil); 
    try 
    try 
     http.Get(url, nil); 
     code := http.ResponseCode; 
    except 
     on E: EIdHTTPProtocolException do 
     code := http.ResponseCode; // or: code := E.ErrorCode; 
    end; 
    ShowMessage(IntToStr(code)); 
    finally 
    http.Free(); 
    end; 
end; 

Answer 2

http.head() बजाय http.get() साथ प्रयास करें।