किसी ऑब्जेक्ट की कोई निश्चित संपत्ति होने पर सत्यापित कैसे करें?

Question

मैं या तो अपेक्षित संपत्ति का मूल्य या निर्दिष्ट डिफ़ॉल्ट का उपयोग करना चाहता हूं। ग्रोवी में इसे कैसे प्राप्त किया जाए? उदाहरण को

आइए नज़र:

def printName(object) { 
    //if object has initialized property 'name' - print 'name', otherwise print ToString 
    if (object<some code here>name && object.name) { 
     print object.name 
    } else { 
     print object 
    } 
} 

Answer 1

आप hasProperty उपयोग कर सकते हैं। उदाहरण:

if (object.hasProperty('name') && object.name) { 
    println object.name 
} else { 
    println object 
} 

आप संपत्ति के नाम के लिए एक चर का उपयोग कर रहे हैं, तो आप इस का उपयोग कर सकते हैं:

String propName = 'name' 
if (object.hasProperty(propName) && object."$propName") { 
    ... 
} 

Answer 2

मानते हुए अपने object एक ग्रूवी वर्ग, तुम इतनी तरह वस्तु metaClass में hasProperty का उपयोग कर सकते है:

def printName(o) { 
    if(o.metaClass.hasProperty(o, 'name') && o.name) { 
    println "Printing Name : $o.name" 
    } 
    else { 
    println o 
    } 
} 

तो, तो दिए गए दो वर्गों:

class Named { 
    String name 
    int age 

    String toString() { "toString Named:$name/$age" } 
} 

class Unnamed { 
    int age 

    String toString() { "toString Unnamed:$age" } 
} 

आप उदाहरण बना सकते हैं o उन्हें, और परीक्षण च:

def a = new Named(name: 'tim', age: 21) 
def b = new Unnamed(age: 32) 

printName(a) 
printName(b) 

कौन सा चाहिए उत्पादन:

Printing Name : tim 
toString Unnamed:32 

Answer 3

मैं बस एक वस्तु कुछ संपत्ति है कि बात पर जोर देना चाहते हैं, मैं तो बस का परीक्षण निम्नलिखित:

assertNotNull(myObject.hasProperty('myProperty').name) 

तो myObjectmyProperty नहीं है अभिकथन एक नल पॉइंटर एक्सेप्शन साथ विफल हो जाएगा:

java.lang.NullPointerException: Cannot get property 'name' on null object 

Answer 4

आप मेटा प्रोग्रामिंग के माध्यम से अपने खुद के विधि लिख सकते हैं:

class Foo { 
    def name = "Mozart" 
} 

def f = new Foo() 

Object.metaClass.getPropertyOrElse = { prop, defaultVal -> 
    delegate.hasProperty(prop) ? delegate."${prop}" : defaultVal 
} 

assert "Mozart" == f.getPropertyOrElse("name", "") 
assert "Salzburg" == f.getPropertyOrElse("city", "Salzburg")