Emacs org-mode में किसी फ़ंक्शन को उप-स्ट्रीम में कैसे प्रतिबंधित करें?

Question

मैं ऑर्ग-मोड और ऑर्ग-संलग्न का उपयोग कर रहा हूं जिसका अर्थ है कि एक संगठन फ़ाइल से जुड़े कई अनुलग्नक निर्देशिकाएं हो सकती हैं।

worg पर मुझे मैट लुंडी से एक फ़ंक्शन मिला जो सभी संलग्नक को पूरी फ़ाइल से संबंधित देखने और उन्हें ido के साथ ब्राउज़ करने की अनुमति देता है।

मैं इस फ़ंक्शन को एक उप-धारा में प्रतिबंधित करना चाहता हूं जो इसे मेरे उपयोग के मामले के लिए और अधिक उपयोगी बना देगा।

चूंकि मैं emacs के लिए नया नहीं हूं लेकिन लगभग पूरी तरह से निरक्षर elisp मैं यहां पूछ रहा हूँ।

(defun my-ido-find-org-attach() 
    "Find files in org-attachment directory" 
    (interactive) 
    (let* ((enable-recursive-minibuffers t) 
     (files (find-lisp-find-files org-attach-directory ".")) 
     (file-assoc-list 
      (mapcar (lambda (x) 
        (cons (file-name-nondirectory x) 
          x)) 
        files)) 
     (filename-list 
      (remove-duplicates (mapcar #'car file-assoc-list) 
          :test #'string=)) 
     (filename (ido-completing-read "Org attachments: " filename-list nil t)) 
     (longname (cdr (assoc filename file-assoc-list)))) 
    (ido-set-current-directory 
    (if (file-directory-p longname) 
     longname 
     (file-name-directory longname))) 
    (setq ido-exit 'refresh 
      ido-text-init ido-text 
      ido-rotate-temp t) 
    (exit-minibuffer))) 

Answer 1

शायद मैं कुछ याद कर रहा हूँ, लेकिन org-narrow-to-subtree पहले बुला आप क्या चाहते हैं क्या करना चाहिए (widen बाद में फोन है कि वापस लौटने के लिए):

यह कार्य है।

Answer 2

मैंने सोचा कि यह बहुत उपयोगी होगा, इसलिए आपके प्रश्न से प्रेरित, मैंने एक संस्करण लिखा है जो आप चाहते हैं कि कुछ और घंटियां और सीटी। इसे आमंत्रित करने के लिए आपको सी-सी ओ टाइप करना होगा। नोट: यह सामान्य org-attach कुंजी उपसर्ग पर नहीं है क्योंकि उस फ़ंक्शन को बिना किसी कुंजीमैप के लिखा गया है, इसलिए कार्यक्षमता को मुख्य उपसर्ग पर जोड़ना मुश्किल है।

(autoload 'org-attach-dir "org-attach") 
(autoload 'find-lisp-find-files "find-lisp") 
(defcustom ido-locate-org-attach-all-files nil 
    "Non-nil means `ido-locate-org-attach' returns all files. 
Otherwise the default behavior only returns files attached to the 
current entry." 
    :group 'ido 
    :type 'boolean) 

(defun ido-locate-org-attach (&optional find-all) 
    "Find files in org-attachment directory for current entry. 
When called with a prefix argument, include all files in 
`org-attach-directory'. With a double `C-u' prefix arg the value 
of `ido-locate-org-attach-all-files' will be toggled for the 
session. If you want to save it permanently for future session 
then customize the variable `ido-locate-org-attach-all-files'." 
    (interactive "P") 
    (when (org-attach-dir nil) 
    (when (equal find-all '(16)) 
     (setq ido-locate-org-attach-all-files 
     (not ido-locate-org-attach-all-files))) 
    (let* ((enable-recursive-minibuffers t) 
     (dir (if (org-xor ido-locate-org-attach-all-files 
       (equal find-all '(4))) 
      org-attach-directory 
      (org-attach-dir nil))) 
     (files (find-lisp-find-files dir ".")) 
     (file-assoc-list 
     (mapcar (lambda (x) 
       (cons (file-name-nondirectory x) 
       x)) 
      files)) 
     (filename-list 
     (remove-duplicates (mapcar #'car file-assoc-list) 
        :test #'string=)) 
     (filename (ido-completing-read "Org attachments: " filename-list nil t)) 
     (longname (cdr (assoc filename file-assoc-list)))) 
     (ido-set-current-directory 
     (if (file-directory-p longname) 
     longname 
    (file-name-directory longname))) 
     (setq ido-exit 'refresh 
     ido-text-init ido-text 
     ido-rotate-temp t) 
     (exit-minibuffer)))) 

;; Run ido-locate-org-attach when using org-open-at-point (C-c C-o) in 
;; the current entry (except if you're on the header line itself it 
;; will use the default behavior to open/close the entry. 
(add-hook 'org-open-at-point-functions 'ido-locate-org-attach) 

;; C-c o   will locate files for the current entry 
;; C-u C-c o  will locate files for the whole file 
;; C-u C-u C-c o will toggle the default current entry/whole file 
(define-key org-mode-map "\C-co" 'ido-locate-org-attach) 

मैं org-attach.el का आधिकारिक हिस्सा बनने के लिए इसे प्रस्तुत करने में देखता हूं।

एक अलग रूप में के रूप में, '(4) और '(16) जादू संख्या इसका मतलब यह उपसर्ग आर्ग हैं एक बार सी-यू और उपसर्ग आर्ग दो बार सी-यू सी यू कुंजी अनुक्रम कि आदेश सहभागी लागू करने से पहले।