मैं XSLT में स्पेसिंग व्हाइटस्पेस को प्रतिस्थापित किए बिना स्थान को कैसे ट्रिम कर सकता हूं?

Question

फ़ंक्शन normalize-space एक स्थान से व्हाइटस्पेस के अनुक्रमों को प्रतिस्थापित करता है और प्रदान की गई स्ट्रिंग को ट्रिम करता है। मैं व्हाइटस्पेस के प्रतिस्थापन के बिना केवल स्ट्रिंग को कैसे ट्रिम कर सकता हूं? orcl:left-trim जैसे स्वामित्व समाधान हैं, लेकिन मैं एक गैर-स्वामित्व वाले व्यक्ति की तलाश में हूं।

उदाहरण:

<xsl:value-of select="trim(/Car/Description)"/> 

कर देना चाहिए

<car> 
    <description> To get more information look at:  www.example.com </description> 
</car> 

में

"To get more information look at:  www.example.com" 

Answer 1

केवल xslt 1 का उपयोग कर एक समाधान।0 टेम्पलेट्स:

<xsl:variable name="whitespace" select="'&#09;&#10;&#13; '" /> 

<!-- Strips trailing whitespace characters from 'string' --> 
<xsl:template name="string-rtrim"> 
    <xsl:param name="string" /> 
    <xsl:param name="trim" select="$whitespace" /> 

    <xsl:variable name="length" select="string-length($string)" /> 

    <xsl:if test="$length &gt; 0"> 
     <xsl:choose> 
      <xsl:when test="contains($trim, substring($string, $length, 1))"> 
       <xsl:call-template name="string-rtrim"> 
        <xsl:with-param name="string" select="substring($string, 1, $length - 1)" /> 
        <xsl:with-param name="trim" select="$trim" /> 
       </xsl:call-template> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:value-of select="$string" /> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:if> 
</xsl:template> 

<!-- Strips leading whitespace characters from 'string' --> 
<xsl:template name="string-ltrim"> 
    <xsl:param name="string" /> 
    <xsl:param name="trim" select="$whitespace" /> 

    <xsl:if test="string-length($string) &gt; 0"> 
     <xsl:choose> 
      <xsl:when test="contains($trim, substring($string, 1, 1))"> 
       <xsl:call-template name="string-ltrim"> 
        <xsl:with-param name="string" select="substring($string, 2)" /> 
        <xsl:with-param name="trim" select="$trim" /> 
       </xsl:call-template> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:value-of select="$string" /> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:if> 
</xsl:template> 

<!-- Strips leading and trailing whitespace characters from 'string' --> 
<xsl:template name="string-trim"> 
    <xsl:param name="string" /> 
    <xsl:param name="trim" select="$whitespace" /> 
    <xsl:call-template name="string-rtrim"> 
     <xsl:with-param name="string"> 
      <xsl:call-template name="string-ltrim"> 
       <xsl:with-param name="string" select="$string" /> 
       <xsl:with-param name="trim" select="$trim" /> 
      </xsl:call-template> 
     </xsl:with-param> 
     <xsl:with-param name="trim" select="$trim" /> 
    </xsl:call-template> 
</xsl:template> 

टेस्ट कोड:

<ltrim> 
    <xsl:call-template name="string-ltrim"> 
     <xsl:with-param name="string" select="' &#10; test '" /> 
    </xsl:call-template> 
</ltrim> 
<rtrim> 
    <xsl:call-template name="string-rtrim"> 
     <xsl:with-param name="string" select="' &#10; test &#10; '" /> 
    </xsl:call-template> 
</rtrim> 
<trim> 
    <xsl:call-template name="string-trim"> 
     <xsl:with-param name="string" select="' &#10; test &#10; '" /> 
    </xsl:call-template> 
</trim> 

आउटपुट:

<test> 
    <ltrim>test </ltrim> 
    <rtrim> 
    test</rtrim> 
    <trim>test</trim> 
</test> 

Answer 2

XSLT कार्यात्मक प्रोग्रामिंग के लिए FXSL (खुला स्रोत पुस्तकालय का उपयोग करना, XSL में पूरी तरह से लिखा टी) एक बस लिखते:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:import href="trim.xsl"/> 

    <xsl:output method="text"/> 
    <xsl:template match="/*/description"> 
    '<xsl:call-template name="trim"> 
     <xsl:with-param name="pStr" select="."/> 
    </xsl:call-template>' 
    </xsl:template> 
</xsl:stylesheet> 

जब इस बदलाव प्रदान की XML दस्तावेज़ पर भी लागू होता है:

<car> 
    <description> To get more information look at:  www.example.com </description> 
</car> 

चाहता था, सही परिणाम का उत्पादन किया है:

'To get more information look at:  www.example.com' 

---

trim टेम्पलेट कैसे काम करता है?

यह बाएं अग्रणी व्हाइटस्पेस को ट्रिम करता है, फिर यह परिणामी स्ट्रिंग को उलट देता है और इसके अग्रणी व्हाइटस्पेस को ट्रिम करता है, फिर अंततः परिणामी स्ट्रिंग को उलट देता है।

---

II। XPath 2.0 समाधान:

उपयोग: - 2.0 -

replace(replace(/*/description, '^\s*(.+?)\s*$', '$1'), '^ .*$', '') 

यहाँ एक XSLT है आधारित सत्यापन:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="/"> 
    "<xsl:sequence 
     select="replace(replace(/*/description, '^\s*(.+?)\s*$', '$1'), '^ .*$', '')"/>" 
</xsl:template> 
</xsl:stylesheet> 

जब इस बदलाव प्रदान की XML दस्तावेज़ पर लागू किया जाता है (ऊपर), XPath अभिव्यक्ति का मूल्यांकन किया जाता है और इस मूल्यांकन का परिणाम आउटपुट में कॉपी किया जाता है:

"To get more information look at:  www.example.com" 

Answer 3

आप बीच में कोई खाली स्थान नहीं है, तो आप बस का उपयोग कर सकते हैं:

translate(/Car/Description,' ','') 

Answer 4

सामान्यीकृत-स्थान (वास्तविक सेटिंग) - यह ऐसा करेगा।

Answer 5

एक XSLT1 साथ बहुत ही कम समाधान:

<xsl:template name="trim"> 
      <xsl:param name="str"/> 

      <xsl:choose> 
       <xsl:when test="string-length($str) &gt; 0 and substring($str, 1, 1) = ' '"> 
        <xsl:call-template name="trim"><xsl:with-param name="str"><xsl:value-of select="substring($str, 2)"/></xsl:with-param></xsl:call-template></xsl:when> 
       <xsl:when test="string-length($str) &gt; 0 and substring($str, string-length($str)) = ' '"> 
        <xsl:call-template name="trim"><xsl:with-param name="str"><xsl:value-of select="substring($str, 1, string-length($str)-1)"/></xsl:with-param></xsl:call-template></xsl:when> 
       <xsl:otherwise><xsl:value-of select="$str"/></xsl:otherwise> 
      </xsl:choose> 
     </xsl:template>