क्या 0 पिछले सर्कल की डिग्री को स्थानांतरित करने के लिए कोई फ़ंक्शन है?

Question

मैं Inc() के समान डेल्फी XE2 में कहीं भी फ़ंक्शन ढूंढ रहा हूं जो मुझे वर्तमान डिग्री की डिग्री से कई डिग्री जोड़ने/घटाने की अनुमति देता है और परिणामस्वरूप नई डिग्री होती है। उदाहरण के लिए, यदि मेरे पास वर्तमान में एक सर्कल के चारों ओर 5 डिग्री पर एक बिंदु है, और मैं 10 घटाना चाहता हूं, मुझे -5 डिग्री नहीं मिलनी चाहिए, बल्कि 355 (360 - 5)। पिछले 360 को जोड़ने के समान - इसे 360 तक पहुंचने पर 0 पर वापस जाना चाहिए।

क्या पहले से ही डेल्फी में ऐसा कुछ है, इसलिए मुझे इसे फिर से लिखना नहीं है? शायद Math इकाई में?

Answer 1

uses 
    System.SysUtils,Math; 

Function WrapAngle(angle : Double) : Double; 
Const 
    modAngle : Double = 360.0; 
begin 
    Result := angle - modAngle*Floor(angle/modAngle); 
end; 

begin 
    WriteLn(FloatToStr(WrapAngle(-5))); 
    WriteLn(FloatToStr(WrapAngle(5-720))); 
    WriteLn(FloatToStr(WrapAngle(360))); 
    ReadLn;  
end. 

परिणाम का उत्पादन:

355 
5 
0 

अद्यतन:

रूप @Giel पाया, XE3 में वहाँ एक नया समारोह है DegNormalize() जो वें करता है ई नौकरी यहां तक ​​कि लगभग 25% तेज। चाल Floor() को Int() के साथ कॉल करने के बजाय प्रतिस्थापित करना है, और यदि परिणाम नकारात्मक है, तो परिणाम के लिए modAngle जोड़ें।

Answer 2

मैं किसी भी पता नहीं है, लेकिन मुझे किसी भी एक अधिक सामान्य समाधान का उपयोग पसंद करते हैं ...

Procedure IncOverFlow(var Value:Double;Difference:Double;Limit:Double=360); 
begin 
    Value := Value + Difference; 
    While Value < 0 do Value := Value + Limit; 
    While Value >= Limit do Value := Value -Limit; 
end; 

Answer 3

कोड मैं इस कार्य को करने के लिए उपयोग है:

function PosFrac(x: Double): Double; 
(* PosFrac(1.2)=0.2 and PosFrac(-1.2)=0.8. *) 
begin 
    Result := Frac(x); (* Frac(x)=x-Int(x) *) 
    if Result<0.0 then begin 
    Result := 1.0+Result; 
    end; 
end; 

function ModR(const x, y: Double): Double; 
(* ModR(1.2,1)=0.2 and ModR(-1.2,1)=0.8 *) 
var 
    absy: Double; 
begin 
    if y=0.0 then begin 
    Result := 0.0; 
    end else begin 
    absy := abs(y); 
    Result := PosFrac(x/absy)*absy; 
    end; 
end; 

function Mod360(const x: Double): Double; 
begin 
    Result := ModR(x, 360.0); 
end; 

यह कोड सभी कोणों को 0 से 360 में लाएगा।

Writeln(Round(Mod360(5-10))); 
Writeln(Round(Mod360(5-360))); 
Writeln(Round(Mod360(5-720))); 
Writeln(Round(Mod360(5+720))); 

आउटपुट: उदाहरण के लिए:

 
355 
5 
5 
5 

Answer 4

function WrapAngle(Value: Integer): Integer; 
begin 
    Result := Value mod 360; 
    if Result < 0 then 
    Inc(Result, 360); 
end; 

Answer 5

procedure WrapAngle(var Degs: Integer); 
begin 
    Degs := Degs mod 360; 
    if Degs < 0 then 
    Inc(Degs, 360); 
end;