वीबीए से एक अलग सीएसवी फ़ाइल कैसे बनाएं?

Question

मुझे कुछ परिणाम .csv फ़ाइल के रूप में आउटपुट करने की आवश्यकता है, जो बाद में किसी अन्य प्रक्रिया द्वारा पार्स किया जाता है। इन परिणामों को उत्पन्न करने के लिए, मेरे पास एक बड़ी कार्यपुस्तिका है जिसमें सभी मैक्रोज़ और फ़ंक्शंस हैं जिन्हें मुझे चाहिए।

1. क्या VBA से अलग .csv फ़ाइल "बनाना" संभव है?
2. क्या यह "कच्चे पाठ" दृष्टिकोण में लिखने के बजाय VBA सुविधाओं का उपयोग करना संभव है?

VBA से CSV में आप :)

Answer 1

कुछ इस तरह तुम क्या चाहते है?

Option Explicit 
Sub WriteFile() 

    Dim ColNum As Integer 
    Dim Line As String 
    Dim LineValues() As Variant 
    Dim OutputFileNum As Integer 
    Dim PathName As String 
    Dim RowNum As Integer 
    Dim SheetValues() As Variant 

    PathName = Application.ActiveWorkbook.Path 
    OutputFileNum = FreeFile 

    Open PathName & "\Test.csv" For Output Lock Write As #OutputFileNum 

    Print #OutputFileNum, "Field1" & "," & "Field2" 

    SheetValues = Sheets("Sheet1").Range("A1:H9").Value 
    ReDim LineValues(1 To 8) 

    For RowNum = 1 To 9 
    For ColNum = 1 To 8 
     LineValues(ColNum) = SheetValues(RowNum, ColNum) 
    Next 
    Line = Join(LineValues, ",") 
    Print #OutputFileNum, Line 
    Next 

    Close OutputFileNum 

End Sub 

भूल आप किसी भी एक अल्पविराम युक्त मैदान के चारों ओर उद्धरण डाल करने की आवश्यकता होगी है।

Answer 2

आप किसी मैक्रो वर्तमान कार्यपुस्तिका को बचाने के लिए चाहते लिख सकते हैं (खोला फ़ाइल उत्कृष्टता) धन्यवाद:

ActiveWorkbook.SaveAs Filename:="C:\Book1.csv", _ 
    FileFormat:=xlCSVMSDOS, CreateBackup:=False 

Answer 3

टोनी का जवाब आम तौर पर काम करता है लेकिन उस मामले को संभाल नहीं करता है जहां आपके टेक्स्ट में अल्पविराम या उद्धरण शामिल हैं। आप वर्कबुक.SaveAs विधि का उपयोग करना पसंद कर सकते हैं।

यहां एक उदाहरण है यदि आप शीट 1 की सामग्री को अलग सीएसवी फ़ाइल के रूप में सहेजना चाहते हैं।

Sub create_csv() 
    Dim FileName As String 
    Dim PathName As String 
    Dim ws As Worksheet 

    Set ws = ActiveWorkbook.Sheets("Sheet1") 
    FileName = "filename.csv" 
    PathName = Application.ActiveWorkbook.Path 
    ws.Copy 
    ActiveWorkbook.SaveAs FileName:=PathName & "\" & FileName, _ 
     FileFormat:=xlCSV, CreateBackup:=False 
End Sub 

कल्पना कीजिए कि आपके पत्रक 1 शामिल हैं:

lorem ipsum

विद्या, मी "उम" IPS

उत्पादन csv फ़ाइल हो जाएगा:

लोरेम, ipsum

"विद्या, मी", "ips" "उम" ""