मैं एक वेब यूआरएल कैसे पार्स करूं?

Question

मुझे एक यूआरएल को विभिन्न सेगमेंट में तोड़ने में सक्षम होना चाहिए। उदाहरण के लिए इस मार्ग लें:

Protocol: HTTP 
Username: login 
Password: password 
Host: somehost.somedomain.com 
Port: 8080 
Path Info: /some_path/something_else.html 
Query String: param1=val&param2=val 

मैं डेल्फी में ऐसा कैसे कर सकते हैं:

http://login:password@somehost.somedomain.com:8080/some_path/something_else.html?param1=val&param2=val#nose 
\__/ \___/ \______/ \_____________________/ \__/\____________________________/ \___________________/ \__/ 
|  |  |    |    |    |      |    | 
Scheme Username Password  Host   Port    Path     Query   Fragment 

यह इस प्रकार का विश्लेषण करना चाहिए? क्या कुछ तैयार है जो इसे मेरे लिए विभाजित कर सकता है? यदि नहीं, तो मैं सभी अलग-अलग संभावित प्रारूपों को पार्स करने के बारे में कैसे जा सकता हूं? यह माना जा रहा है कि यह एक अलग प्रोटोकॉल भी हो सकता है, जैसे कि HTTPS या RTSP।

Answer 1

इंडी, जो उस उद्देश्य के लिए एक TIdURI वर्ग है, जैसे के साथ XE2 जहाजों:

uses 
    ..., IdURI; 

var 
    URI: TIdURI; 

URI := TIdURI.Create('http://login:password@somehost.somedomain.com:8080/some_path/something_else.html?param1=val&param2=val'); 
try 
    // Protocol = URI.Protocol 
    // Username = URI.Username 
    // Password = URI.Password 
    // Host = URI.Host 
    // Port = URI.Port 
    // Path = URI.Path 
    // Query = URI.Params 
finally 
    URI.Free; 
end; 

Answer 2

आप InternetCrackUrl विधि का उपयोग कर सकते हैं।

इस सरल

{$APPTYPE CONSOLE} 

uses 
    Windows, 
    SysUtils, 
    WinInet; 

procedure ParseURL(const lpszUrl: string); 
var 
    lpszScheme  : array[0..INTERNET_MAX_SCHEME_LENGTH - 1] of Char; 
    lpszHostName : array[0..INTERNET_MAX_HOST_NAME_LENGTH - 1] of Char; 
    lpszUserName : array[0..INTERNET_MAX_USER_NAME_LENGTH - 1] of Char; 
    lpszPassword : array[0..INTERNET_MAX_PASSWORD_LENGTH - 1] of Char; 
    lpszUrlPath  : array[0..INTERNET_MAX_PATH_LENGTH - 1] of Char; 
    lpszExtraInfo : array[0..1024 - 1] of Char; 
    lpUrlComponents : TURLComponents; 
begin 
    ZeroMemory(@lpszScheme, SizeOf(lpszScheme)); 
    ZeroMemory(@lpszHostName, SizeOf(lpszHostName)); 
    ZeroMemory(@lpszUserName, SizeOf(lpszUserName)); 
    ZeroMemory(@lpszPassword, SizeOf(lpszPassword)); 
    ZeroMemory(@lpszUrlPath, SizeOf(lpszUrlPath)); 
    ZeroMemory(@lpszExtraInfo, SizeOf(lpszExtraInfo)); 
    ZeroMemory(@lpUrlComponents, SizeOf(TURLComponents)); 

    lpUrlComponents.dwStructSize  := SizeOf(TURLComponents); 
    lpUrlComponents.lpszScheme  := lpszScheme; 
    lpUrlComponents.dwSchemeLength := SizeOf(lpszScheme); 
    lpUrlComponents.lpszHostName  := lpszHostName; 
    lpUrlComponents.dwHostNameLength := SizeOf(lpszHostName); 
    lpUrlComponents.lpszUserName  := lpszUserName; 
    lpUrlComponents.dwUserNameLength := SizeOf(lpszUserName); 
    lpUrlComponents.lpszPassword  := lpszPassword; 
    lpUrlComponents.dwPasswordLength := SizeOf(lpszPassword); 
    lpUrlComponents.lpszUrlPath  := lpszUrlPath; 
    lpUrlComponents.dwUrlPathLength := SizeOf(lpszUrlPath); 
    lpUrlComponents.lpszExtraInfo  := lpszExtraInfo; 
    lpUrlComponents.dwExtraInfoLength := SizeOf(lpszExtraInfo); 

    InternetCrackUrl(PChar(lpszUrl), Length(lpszUrl), ICU_DECODE or ICU_ESCAPE, lpUrlComponents); 

    Writeln(Format('Protocol : %s',[lpszScheme])); 
    Writeln(Format('Host  : %s',[lpszHostName])); 
    Writeln(Format('User  : %s',[lpszUserName])); 
    Writeln(Format('Password : %s',[lpszPassword])); 
    Writeln(Format('Path  : %s',[lpszUrlPath])); 
    Writeln(Format('ExtraInfo: %s',[lpszExtraInfo])); 
end; 

begin 
    try 
    ParseURL('http://login:password@somehost.somedomain.com/some_path/something_else.html?param1=val&param2=val'); 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
    readln; 
end. 

यह वापस आ जाएगी प्रयास करें

Protocol : http 
Host  : somehost.somedomain.com 
User  : login 
Password : password 
Path  : /some_path/something_else.html 
ExtraInfo: ?param1=val&param2=val