मैं F90 में to_upper() या to_lower() फ़ंक्शन कैसे लिख सकता हूं?

Question

कोई एक (इंटेल) F90 फ़ंक्शन कैसे लिखता है जो स्ट्रिंग को लोअरकेस (या वैकल्पिक रूप से, अपरकेस) में परिवर्तित करता है? मैं फ़ंक्शन में एक वर्ण सरणी पास करना चाहता हूं और इसे एक वर्ण सरणी वापस भेजना चाहता हूं, उदा।

program main 
    implicit none 

    character*32 :: origStr = "Hello, World!" 
    character*32 :: newStr 

    newStr = to_lower(origStr) 
    write (*,*) newStr 

end program main 

जैसे कि यह प्रोग्राम hello, world! आउटपुट करता है।

मैं to_lower() सबराउटिन RosettaCode पर पाया गया है, लेकिन मैं इसे फ़ंक्शन के रूप में लिखने का तरीका नहीं समझ सकता।

अग्रिम धन्यवाद!

पीएस - बोनस अंक यदि आप इसे अखंड लंबाई की एक स्ट्रिंग के साथ कर सकते हैं!

Answer 1

इस कोड के मूल लेखक के रूप में, मुझे खुशी है कि यह कुछ मदद की है। मुझे आश्चर्य हुआ कि इन कार्यों को फोरट्रान में क्यों नहीं बनाया गया था। मेरा अनुमान है कि वे केवल अक्षरों के बजाय प्रतिबंधित समूह के लिए काम करते हैं, यानी अंग्रेजी में उपयोग किए जाने वाले। यदि आपके पास लगभग किसी अन्य यूरोपीय भाषा में टेक्स्ट है तो आपके पास उच्चारण के साथ अक्षर होंगे, और फिर उन्हें ऊपरी या निचले मामले में परिवर्तित करना बहुत कठिन होगा। उदाहरण के लिए फ्रेंच में ई-कब्र ऊपरी मामले में बदल जाता है आमतौर पर केवल सादा ई के रूप में दिखाया जाता है (कब्र उच्चारण खो जाता है), लेकिन ई-तीव्र में यह नहीं होता है। फोरट्रान के डिजाइनरों ने हमेशा ऐसी सुविधाएं प्रदान करने की कोशिश की है जो भाषाओं की एक विस्तृत श्रृंखला के अनुरूप हैं, और बहु ​​भाषा के तरीके में ऊपरी/निचले मामले रूपांतरण करना बिल्कुल आसान नहीं है। कम से कम यह मेरा अनुमान है कि आपको इसे स्वयं क्यों करना है।

Answer 2

वाह - भले ही मैं इसे पोस्ट करने के तुरंत बाद एक घंटे से अधिक खोज करता, मुझे here ("विविध फोरट्रान संकेत और टिप्स" के तहत एक उत्तर मिला)।

कोड मैं का इस्तेमाल किया (to_upper के लिए) इस प्रकार है:

function to_upper(strIn) result(strOut) 
! Adapted from http://www.star.le.ac.uk/~cgp/fortran.html (25 May 2012) 
! Original author: Clive Page 

    implicit none 

    character(len=*), intent(in) :: strIn 
    character(len=len(strIn)) :: strOut 
    integer :: i,j 

    do i = 1, len(strIn) 
      j = iachar(strIn(i:i)) 
      if (j>= iachar("a") .and. j<=iachar("z")) then 
       strOut(i:i) = achar(iachar(strIn(i:i))-32) 
      else 
       strOut(i:i) = strIn(i:i) 
      end if 
    end do 

end function to_upper 

आशा इस किसी मदद करता है!

Answer 3

यहाँ एक है कि ASCII प्रतिनिधित्व

Pure Function to_upper (str) Result (string) 

! ============================== 
! Changes a string to upper case 
! ============================== 

    Implicit None 
    Character(*), Intent(In) :: str 
    Character(LEN(str))  :: string 

    Integer :: ic, i 

    Character(26), Parameter :: cap = 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 
    Character(26), Parameter :: low = 'abcdefghijklmnopqrstuvwxyz' 

! Capitalize each letter if it is lowecase 
    string = str 
    do i = 1, LEN_TRIM(str) 
     ic = INDEX(low, str(i:i)) 
     if (ic > 0) string(i:i) = cap(ic:ic) 
    end do 

End Function to_upper 

आप आसानी से पाश में कम और टोपी तार स्विच करके to_lower को यह बदल सकते हैं पर निर्भर नहीं करता है।