मैं स्क्रीन पर प्रिंट करने वाले पर्ल फ़ंक्शंस का परीक्षण कैसे कर सकता हूं?

Question

मैं स्क्रीन पर प्रिंट करने वाले यूनिट परीक्षण पर्ल फ़ंक्शंस में Test::More का उपयोग करने का प्रयास कर रहा हूं।

मैं समझता हूं कि यह आउटपुट prove जैसे उपकरणों में हस्तक्षेप कर सकता है।

मैं इस आउटपुट को कैप्चर कैसे कर सकता हूं ताकि मैं इसे diag() से प्रिंट कर सकूं, और आउटपुट पर परीक्षण भी चला सकता हूं?

Answer 1

अद्यतन: IMHO, इस सवाल का सही जवाब Test::Output उपयोग करने के लिए होना चाहिए:

#!/usr/bin/perl 

use strict; use warnings; 

use Test::More tests => 1; 
use Test::Output; 

sub myfunc { print "This is a test\n" } 

stdout_is(\&myfunc, "This is a test\n", 'myfunc() returns test output'); 

आउटपुट:

 
C:\Temp> tm 
1..1 
ok 1 - myfunc() returns test output 

मैं के रूप में संदर्भ के लिए मूल जवाब जा रहा हूँ, मुझे विश्वास है, यह अभी भी एक उपयोगी तकनीक दिखाता है।

आप STDOUT स्थानीय बनाना और समारोह कॉल करने से पहले एक अदिश को फिर से खोलना कर सकते हैं, बाद में बहाल:

#!/usr/bin/perl 

use strict; use warnings; 

use Test::More tests => 1; 

sub myfunc { print "This is a test\n" } 

sub invoke { 
    my $sub = shift; 
    my $stdout; 
    { 
     local *STDOUT; 
     open STDOUT, '>', \$stdout 
      or die "Cannot open STDOUT to a scalar: $!"; 
     $sub->(@_); 
     close STDOUT 
      or die "Cannot close redirected STDOUT: $!"; 
    } 
    return $stdout; 
} 

chomp(my $ret = invoke(\&myfunc)); 

ok($ret eq "This is a test", "myfunc() prints test string"); 
diag("myfunc() printed '$ret'"); 

आउटपुट:

 
C:\Temp> tm 
1..1 
ok 1 - myfunc() prints test string 
# myfunc() printed 'This is a test' 

5,8 से अधिक उम्र के perl के संस्करणों के लिए, आप शायद उपयोग करने की आवश्यकता IO::Scalar, लेकिन मुझे 5.8 से पहले काम करने के तरीके के बारे में बहुत कुछ पता नहीं है।

Answer 2

मैं एक मॉड्यूल को आपके लिए इसे संभालने की अनुमति दूंगा। Capture::Tiny देखें।

Answer 3

यदि यह कोड है जिसे आप स्वयं लिख रहे हैं, तो इसे बदलें ताकि प्रिंट स्टेटमेंट डिफ़ॉल्ट फ़ाइलहेडल का उपयोग न करें।

 
sub my_print { 
    my $self = shift; 
    my $fh = $self->_get_output_fh; 
    print { $fh } @_; 
    } 

sub _get_output_fh { $_[0]->{_output} || \*STDOUT } 
sub _set_output_fh { $_[0]->{_output} = $_[1] } # add validation yourself 

जब आप परीक्षण करने पर आपको _set_output_fh फोन यह अपने परीक्षण filehandle (शायद यह भी एक IO::Null संभाल) देने के लिए कर सकते हैं: इसके बजाय, अपने आप को आप की तरह कुछ भी करने के लिए उत्पादन filehandle स्थापित करने के लिए एक तरह से दे। जब कोई अन्य व्यक्ति आपके कोड का उपयोग करना चाहता है लेकिन आउटपुट कैप्चर करना चाहता है, तो उसे ऐसा करने के लिए पिछड़े पर मोड़ना नहीं पड़ता क्योंकि वे अपना खुद का फाइलहेडल आपूर्ति कर सकते हैं।

जब आप अपने कोड का एक हिस्सा पाते हैं जो परीक्षण करना मुश्किल है या आपको हुप्स के माध्यम से काम करने के लिए कूदना है, तो शायद आपके पास एक खराब डिज़ाइन है। मैं अभी भी आश्चर्यचकित हूं कि परीक्षण कोड इन चीजों को कैसे स्पष्ट करता है, क्योंकि मैं अक्सर उनके बारे में नहीं सोचता। यदि परीक्षण करना मुश्किल है, तो परीक्षण करना आसान बनाएं। यदि आप ऐसा करते हैं तो आप आमतौर पर जीतते हैं।