प्रोग्रामिंग के रूप में अपना आईपी पता कैसे सेट करें?

Question

मैं अपना आईपी पता प्रोग्रामेटिक रूप से कैसे सेट कर सकता हूं?

मेरा आवेदन यह जाँच कर रहा है, (हालांकि मुझे यकीन है कि अगर About.com से कोड बेहतर नहीं हो सकता है नहीं कर रहा हूँ) DelphiTricks से कोड का उपयोग कर

मैं परीक्षण प्रयोजनों के लिए प्रोग्राम के रूप में पता सेट करने में सक्षम होना चाहता हूँ। और (मुझे नहीं पता कि यह महत्वपूर्ण है), मैं ऐसा करने में सक्षम होना चाहता हूं, यहां तक ​​कि मैं किसी भी नेटवर्क (लैपटॉप पर, एक ट्रेन पर) से जुड़ा नहीं हूं।

Answer 1

अपने नेटवर्क एडाप्टर के आईपी पते को बदलने के लिए आप Win32_NetworkAdapterConfiguration WMI कक्षा या AddIPAddress WinApi विधि का उपयोग कर सकते हैं।

डब्ल्यूएमआई का उपयोग करने वाले इस नमूने को आजमाएं।

{$APPTYPE CONSOLE} 

{$R *.res} 

uses 
    SysUtils, 
    ActiveX, 
    Variants, 
    ComObj; 

procedure SetStaticIpAddress(const NetworkCard, IPAddress, Mask :string); 
const 
    WbemUser =''; 
    WbemPassword=''; 
    WbemComputer='localhost'; 
    wbemFlagForwardOnly = $00000020; 
var 
    FSWbemLocator : OLEVariant; 
    FWMIService  : OLEVariant; 
    FWbemObjectSet : OLEVariant; 
    FWbemObject  : OLEVariant; 
    FOutParams  : OLEVariant; 
    vIpAddress  : OLEVariant; 
    vMask   : OLEVariant; 
    oEnum   : IEnumvariant; 
    iValue   : LongWord; 
begin 
    FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator'); 
    FWMIService := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword); 

    FWbemObjectSet:= FWMIService.ExecQuery(Format('SELECT * FROM Win32_NetworkAdapterConfiguration Where Description="%s"',[NetworkCard]),'WQL',wbemFlagForwardOnly); 
    oEnum   := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant; 
    if oEnum.Next(1, FWbemObject, iValue) = 0 then 
    begin 
    vIpAddress := VarArrayCreate([0, 0], varVariant); 
    vIpAddress[0]:= IPAddress; 
    vMask := VarArrayCreate([0, 0], varVariant); 
    vMask[0]:= Mask; 
    FOutParams:=FWbemObject.EnableStatic(vIpAddress, vMask); 
    // 0 - Successful completion, no reboot required 
    // 1 - Successful completion, reboot required 
    Writeln(Format('ReturnValue %s',[FOutParams])); 
    end 
    else 
    Writeln('Network card not found'); 
end; 


begin 
try 
    CoInitialize(nil); 
    try 
     SetStaticIpAddress('Network card name','192.168.1.1','255.255.255.0'); 
    finally 
     CoUninitialize; 
    end; 
except 
    on E:EOleException do 
     Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode])); 
    on E:Exception do 
     Writeln(E.Classname, ':', E.Message); 
end; 
Writeln('Press Enter to exit'); 
Readln; 
end.