कैसे जोड़ा डेटा के साथ एक घटना प्रेषण करने के लिए - AS3

Question

किसी भी एक मुझे, कैसे एक वस्तु इसे से जुड़े के साथ actionscript3 में एक घटना प्रेषण करने के लिए पर एक सरल उदाहरण दे सकते हैं

dispatchEvent(new Event(GOT_RESULT,result)); 

यहाँ

result की तरह एक वस्तु है कि मैं घटना के साथ पास करना चाहता हूँ।

Answer 1

यदि आप किसी ईवेंट के माध्यम से ऑब्जेक्ट पास करना चाहते हैं तो आपको एक कस्टम ईवेंट बनाना चाहिए। कोड इस तरह कुछ होना चाहिए।

public class MyEvent extends Event 
{ 
    public static const GOT_RESULT:String = "gotResult"; 

    // this is the object you want to pass through your event. 
    public var result:Object; 

    public function MyEvent(type:String, result:Object, bubbles:Boolean=false, cancelable:Boolean=false) 
    { 
     super(type, bubbles, cancelable); 
     this.result = result; 
    } 

    // always create a clone() method for events in case you want to redispatch them. 
    public override function clone():Event 
    { 
     return new MyEvent(type, result, bubbles, cancelable); 
    } 
} 

तो फिर तुम इस तरह से ऊपर कोड का उपयोग कर सकते हैं:

dispatchEvent(new MyEvent(MyEvent.GOT_RESULT, result)); 

और आप इस घटना को जहां आवश्यक के लिए सुन।

addEventListener(MyEvent.GOT_RESULT, myEventHandler); 
// more code to follow here... 
protected function myEventHandler(event:MyEvent):void 
{ 
    var myResult:Object = event.result; // this is how you use the event's property. 
} 

Answer 2

यदि सही तरीके से डिज़ाइन किया गया है तो आपको ईवेंट पर किसी ऑब्जेक्ट को पास नहीं करना चाहिए।
इसके बजाय आपको प्रेषण कक्षा पर सार्वजनिक var बनाना चाहिए।

public var myObject:Object; 

// before you dispatch the event assign the object to your class var 
myObject = ....// whatever it is your want to pass 
// When you dispatch an event you can do it with already created events or like Tomislav wrote and create a custom class. 

// in the call back just use currentTarget 
public function myCallBackFunction(event:Event):void{ 

    // typecast the event target object 
    var myClass:myClassThatDispatchedtheEvent = event.currentTarget as myClassThatDispatchedtheEvent 
    trace(myClass.myObject)// the object or var you want from the dispatching class. 

Answer 3

इस पोस्ट में एक छोटे से पुराना है लेकिन अगर यह किसी की मदद कर सकते हैं, तो आप ऐसा तरह DataEvent वर्ग का उपयोग कर सकते हैं:

dispatchEvent(new DataEvent(YOUR_EVENT_ID, true, false, data)); 

Documentation