सी ++ साइथन में संरचना विरासत

Question

मैं साइथन के साथ एक सी ++ लाइब्रेरी लपेट रहा हूं। हेडर फाइल में, कुछ structs कि अन्य structs से विरासत है, इसलिए की तरह हैं:

struct A { 
    int a; 
}; 
struct B : A { 
    int b; 
}; 

कैसे मेरी cdef extern... ब्लॉक में इस देखना चाहिए?

Answer 1

Using C++ in Cython कुछ भी विशेष उल्लेख नहीं है:

#file: pya.pyx 
cdef extern from "a.h": 
    cdef cppclass A: 
     int a 
    cdef cppclass B(A): 
     int b 

आवरण वर्ग:

#file: pya.pyx 
cdef class PyB: 
    cdef B* thisptr 
    def __cinit__(self): 
     self.thisptr = new B(); 
    def __dealloc__(self): 
     del self.thisptr 
    property a: 
     def __get__(self): return self.thisptr.a 
     def __set__(self, int a): self.thisptr.a = a 
    property b: 
     def __get__(self): return self.thisptr.b 
     def __set__(self, int b): self.thisptr.b = b 

उदाहरण:

import pyximport; pyximport.install(); # pip install cython 

from pya import PyB 

o = PyB() 
assert o.a == 0 and o.b == 0 
o.a = 1; o.b = 2 
assert o.a == 1 and o.b == 2 

इसे बनाने के लिए आप C++ उपयोग करने के लिए pyximport को निर्देश देने की जरूरत है:

#file: pya.pyxbld 
import os 
from distutils.extension import Extension 

dirname = os.path.dirname(__file__) 

def make_ext(modname, pyxfilename): 
    return Extension(name=modname, 
        sources=[pyxfilename, "a.cpp"], 
        language="c++", 
        include_dirs=[dirname])