कॉम्बोबॉक्स: प्रत्येक आइटम पर एक बटन (सूची से आइटम को हटाने के लिए)

Question

मुझे कॉम्बोबॉक्स के प्रत्येक आइटम पर एक बटन (शायद TSpeedButton?) जोड़ने की आवश्यकता है। जब कोई बटन क्लिक करता है तो संबंधित आइटम सूची से हटा दिया जाता है। उदाहरण के लिए:

मैं स्ट्रिंग ग्रिड (यहाँ: TStringGrid with SpeedButtons) में SpeedButtons पर समान चर्चा देखा है, लेकिन मैं कैसे ComboBox पर उन सभी चीज़ों को लागू करने के लिए पता नहीं है। क्या आप विषय पर आगे पढ़ने के लिए कृपया मुझे कुछ सलाह या लिंक दे सकते हैं।

Answer 1

उपयोगकर्ता अनुभव टिप्पणियों को छोड़कर, जिस पर मैं सहमत हूं, प्रश्न का समाधान वास्तव में कठिन नहीं है।

आप इस प्रकार,, csOwnerDrawFixed करने के लिए Style संपत्ति की स्थापना OnDrawItem स्थिति में अपने आप को आइटम ड्राइंग, और उदाहरण के लिए OnSelect घटना में चयनित आइटम को हटा कर ऐसा कर सकते हैं:

unit Unit1; 

interface 

uses 
    Winapi.Windows, System.Classes, Vcl.Controls, Vcl.Forms, Vcl.StdCtrls, 
    Vcl.Imaging.PNGIMage; 

type 
    TForm1 = class(TForm) 
    ComboBox1: TComboBox; 
    procedure FormCreate(Sender: TObject); 
    procedure FormDestroy(Sender: TObject); 
    procedure ComboBox1DrawItem(Control: TWinControl; Index: Integer; 
     Rect: TRect; State: TOwnerDrawState); 
    procedure ComboBox1Select(Sender: TObject); 
    private 
    FDeleteGraphic: TPNGImage; 
    FDeleteRect: TRect; 
    end; 

implementation 

{$R *.dfm} 

{ TForm1 } 

procedure TForm1.ComboBox1DrawItem(Control: TWinControl; Index: Integer; 
    Rect: TRect; State: TOwnerDrawState); 
begin 
    ComboBox1.Canvas.FillRect(Rect); 
    if Index >= 0 then 
    ComboBox1.Canvas.TextOut(Rect.Left + 2, Rect.Top, ComboBox1.Items[Index]); 
    if (odSelected in State) and not (odComboBoxEdit in State) then 
    begin 
    FDeleteRect := Rect; 
    FDeleteRect.Left := FDeleteRect.Right - FDeleteGraphic.Width; 
    ComboBox1.Canvas.Draw(FDeleteRect.Left, FDeleteRect.Top, FDeleteGraphic); 
    end; 
end; 

procedure TForm1.ComboBox1Select(Sender: TObject); 
var 
    MousePos: TPoint; 
begin 
    MousePos := ComboBox1.ScreenToClient(Mouse.CursorPos); 
    MousePos.Offset(0, -ComboBox1.Height); 
    if PtInRect(FDeleteRect, MousePos) then 
    begin 
    ComboBox1.Items.Delete(ComboBox1.ItemIndex); 
    ComboBox1.Invalidate; 
    end; 
end; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    FDeleteGraphic := TPNGImage.Create; 
    FDeleteGraphic.LoadFromFile('H:\Icons\FamFam Common\Delete.png'); 
end; 

procedure TForm1.FormDestroy(Sender: TObject); 
begin 
    FDeleteGraphic.Free; 
end; 

end. 

इस परिणाम के साथ :

आप (फिर) की दुकान पिछले ItemIndex सेटिंग कर सकते हैं। अपनी इच्छाओं को अनुकूलित करें।