गणित में, अभिव्यक्ति को सरल बनाने के लिए कैसे करें == +/- b^^ == b^2 में?

Question

गणित में, मैं a == b || a == -b जैसे a^2 = b^2 में अभिव्यक्तियों को कैसे सरल बना सकता हूं? मैंने जो भी कार्य किया है (जिसमें कमी, सरलीकृत, और पूर्ण अनुकरण शामिल है) ऐसा नहीं करता है।

ध्यान दें कि मैं इसे मनमाना (बहुपद) अभिव्यक्ति a और b के लिए काम करना चाहता हूं। एक और उदाहरण के रूप में,

a == b || a == -b || a == i b || a == -i b 

(काल्पनिक i के लिए)

और

a^2 == b^2 || a^2 == -b^2 

दोनों a^4 == b^4 को सरल बनाया जाना चाहिए।

नोट: समाधान को तार्किक स्तर पर काम करना चाहिए ताकि अन्य असंबंधित तार्किक मामलों को नुकसान न पहुंचाए। उदाहरण के लिए,

a == b || a == -b || c == d 

बन

a^2 == b^2 || c == d. 

Answer 1

बूलियन अभिव्यक्ति बीजीय रूप में बदला जा सकता इस प्रकार है:

In[18]:= (a == b || a == -b || a == I b || a == -I b) /. {Or -> Times, 
    Equal -> Subtract} // Expand 

Out[18]= a^4 - b^4 

---

संपादित

परिवर्तन बाहर छोड़ भागों बनाने के उत्तर में अन्य चरों में, कोई Or परिवर्तन फ़ंक्शन लिख सकता है n, और Simplify में उपयोग करें:

In[41]:= Clear[OrCombine]; 
OrCombine[Verbatim[Or][e__Equal]] := Module[{g}, 
    g = GatherBy[{e}, Variables[Subtract @@ #] &]; 
    Apply[Or, 
    Function[ 
    h, ((Times @@ (h /. {Equal -> Subtract})) // Expand) == 0] /@ g] 
    ] 

In[43]:= OrCombine[(a == b || a == -b || a == I b || a == -I b || 
    c == d)] 

Out[43]= a^4 - b^4 == 0 || c - d == 0 

वैकल्पिक रूप से:

In[40]:= Simplify[(a == b || a == -b || a == I b || a == -I b || 
    c == d), TransformationFunctions -> {Automatic, OrCombine}] 

Out[40]= a^4 == b^4 || c == d 

Answer 2

एक उत्पाद है कि शून्य के बराबर होना चाहिए करने के लिए संभावनाओं के सेट परिवर्तित किया जा सका चाहिए।

expr = a == b || a == -b || a == I*b || a == -I*b; 
eqn = Apply[Times, Apply[Subtract, expr, 1]] == 0 

Out[30]= (a - b)*(a - I*b)*(a + I*b)*(a + b) == 0 

अब इसे सरल बनाएं।

Simplify[eqn] 

Out[32]= a^4 == b^4 

डैनियल Lichtblau