रैकेट: एक फ्रेम% खिड़की

Question

में उपयोग करते हुए घटनाओं मैं रैकेट सीख रहा हूँ (पूर्व PLT योजना, एक लिस्प बोली) और कैसे घटनाओं paint-callback की तुलना में अलग संभाल करने की खोज करने की कोशिश (शायद यह भी एक नहीं है)।

मुझे आशा है कि this part of the doc से बहुत कुछ है लेकिन on-char और on-event ऐसा कुछ भी नहीं है जो मुझे रूचि दे (या कुछ भी नहीं)।

प्लस, मैं घटनाओं, कतार-कॉलबैक और उनके उपयोगों को समझ नहीं पा रहा हूं। एक उदाहरण एक अच्छी बात होगी! मैं उस अच्छे आदमी का आभारी रहूंगा जो मुझे एक लिख देगा :)।

यहाँ मेरी कोड है:

(define game (new frame%)) 

(define gameLay (class canvas% (super-new))) 

(new gameLay 
    [parent game] 
    [paint-callback (λ (canvas dc) #|draw things|#)]) 

मैं की तरह "पर माउस क्लिक में बाईं ओर" कुछ (जो मौजूद नहीं है) जिस तरह से मैं का उपयोग "रंग-कॉलबैक" उपयोग करना चाहते हैं, लेकिन मैं मुझे लगता है कि कदम जोड़ने की जरूरत है (मैंने ईवेंटस्पेस इत्यादि के बारे में पढ़ा है)। मैं यह काम नहीं करता है, लेकिन यहां काल्पनिक कोड मैं के लिए खोज कर रहा हूँ है:

(new gameLay 
    [parent game] 
    [paint-callback (λ (canvas dc) #|draw things|#)] 
    [on-mouse-click-left (λ (canvas dc) #|do other things|#)]) 

Answer 1

यहाँ एक छोटे से कैनवस और कीबोर्ड की घटनाओं का उपयोग कर कार्यक्रम है। एक बार जब आप तीर कुंजी दबाएंगे, तो कैनवास आपके द्वारा दबाए गए अंतिम दिखाएगा।

#lang racket/gui 

(define game-canvas% 
    (class canvas% 
    (inherit get-width get-height refresh) 

    ;; direction : one of #f, 'left, 'right, 'up, 'down 
    (define direction #f) 

    (define/override (on-char ke) 
     (case (send ke get-key-code) 
     [(left right up down) 
     (set! direction (send ke get-key-code)) 
     (refresh)] 
     [else (void)])) 

    (define/private (my-paint-callback self dc) 
     (let ([w (get-width)] 
      [h (get-height)]) 
     (when direction 
      (let ([dir-text (format "going ~a" direction)]) 
      (let-values ([(tw th _ta _td) 
          (send dc get-text-extent dir-text)]) 
       (send dc draw-text 
        dir-text 
        (max 0 (/ (- w tw) 2)) 
        (max 0 (/ (- h th) 2)))))))) 

    (super-new (paint-callback (lambda (c dc) (my-paint-callback c dc)))))) 

(define game-frame (new frame% (label "game") (width 600) (height 400))) 
(define game-canvas (new game-canvas% (parent game-frame))) 
(send game-frame show #t) 

प्रत्येक फ्रेम में एक ईवेंट स्पेस होता है जो ईवेंट प्रेषण का प्रबंधन करता है। on-char विधि एक ईवेंट हैंडलर है; यह इवेंटस्पेस हैंडलर थ्रेड में चलाया जाता है। आपकी on-char विधि समाप्त होने तक कोई और ईवेंट संसाधित नहीं किया जाएगा। तो यदि आप कुछ जटिल करना चाहते हैं, तो आप एक अलग थ्रेड बनाना और वहां पर गणना करना चाहते हैं। ऐसा करने का एक आसान तरीका एक और इवेंटस्पेस बनाना है, जो कि किसी भी फ्रेम के लिए ईवेंट को संभाल नहीं करता है, लेकिन यह queue-callback का उपयोग करके इसे "ईवेंट" को संभालता है। उदाहरण के लिए, इस के साथ ऊपर on-char की परिभाषा बदल देते हैं:

(define aux-eventspace (make-eventspace)) 

(define/override (on-char ke) 
    (parameterize ((current-eventspace aux-eventspace)) 
    (queue-callback 
    (lambda() 
     (case (send ke get-key-code) 
     ((left right up down) 
      (set! direction (send ke get-key-code)) 
      (refresh)) 
     (else (void))))))) 

समारोह queue-callback करने के लिए दिया एक अलग थ्रेड में चलाया जाता है। आप कुछ प्रिंटआउट, देरी, या जो कुछ भी खुद को मनाने के लिए सम्मिलित कर सकते हैं कि मुख्य ईवेंट स्पेस अभी भी ईवेंट को संसाधित कर सकता है जबकि दूसरा आपका कॉलबैक संभालता है।