मैं इनो सेटअप में GetVolumeInformation का उपयोग कैसे कर सकता हूं?

Question

मुझे इनो सेटअप के साथ बनाई गई स्थापना के दौरान ड्राइव अक्षर के लिए वॉल्यूम सीरियल नंबर प्राप्त करने की आवश्यकता है। मुझे पता है कि डीएलएल कार्यों को इनो में आयात किया जा सकता है, लेकिन मैं इसके लिए काफी नया हूं और इसे काम करने में कुछ समस्याएं हैं। मुझे पता है कि kernel32 में GetVolumeInformation फ़ंक्शन जो मुझे चाहिए वह कर सकता है। क्या कोई मुझे दिखा सकता है कि वॉल्यूम सीरियल नंबर पुनर्प्राप्त करने के लिए इनो स्क्रिप्ट में उस कार्यक्षमता को आयात और उपयोग कैसे करें?

धन्यवाद!

Answer 1

InnoSetup कोड ::

[Code] 
function GetVolumeInformation(
    lpRootPathName: PChar; 
    lpVolumeNameBuffer: PChar; 
    nVolumeNameSize: DWORD; 
    var lpVolumeSerialNumber: DWORD; 
    var lpMaximumComponentLength: DWORD; 
    var lpFileSystemFlags: DWORD; 
    lpFileSystemNameBuffer: PChar; 
    nFileSystemNameSize: DWORD 
): BOOL; 
    external 'GetVolumeInformationA@kernel32.dll stdcall'; 


function LoWord(dw: DWORD): WORD; 
begin 
    Result := WORD(dw); 
end; 

function HiWord(dw: DWORD): WORD; 
begin 
    Result := WORD((dw shr 16) and $FFFF); 
end; 

function WordToHex(w: WORD): string; 
begin 
    Result := Format('%.4x', [w]); 
end; 

function FindVolumeSerial(const Drive: string): string; 
var 
    FileSystemFlags: DWORD; 
    VolumeSerialNumber: DWORD; 
    MaximumComponentLength: DWORD; 
begin 
    Result := ''; 
    // Note on passing PChars using RemObjects Pascal Script: 
    // '' pass a nil PChar 
    // #0 pass an empty PChar  
    if GetVolumeInformation(
    PChar(Drive), 
    '', // nil 
    0, 
    VolumeSerialNumber, 
    MaximumComponentLength, 
    FileSystemFlags, 
    '', // nil 
    0) 
    then 
    Result := WordToHex(HiWord(VolumeSerialNumber)) + '-' + WordToHex(LoWord(VolumeSerialNumber)); 
end; 

function InitializeSetup(): Boolean; 
begin 
    MsgBox(FindVolumeSerial('c:\'), mbInformation, mb_Ok); 
end; 

---

Inno- साथ परीक्षण किया गया सेटअप संस्करण 5.2.3
Inno-सेटअप के यूनिकोड संस्करणों में PCharPAnsiChar साथ

Answer 2

चूंकि InnoSetup पॉइंटर्स का समर्थन नहीं करता है तो आपको GetVolumeInformation फ़ंक्शन के कॉल के लिए बाहरी लाइब्रेरी बनाना होगा। निम्नलिखित कोड नमूने डेल्फी और इनोसेटअप के सभी संयोजनों के लिए काम करना चाहिए (यूनिकोड समर्थन बिंदु से)।

यहाँ डेल्फी पुस्तकालय कोड है:

library VolumeInformation; 

uses 
    Types, Classes, SysUtils, Windows; 

var 
    SerialNumber: AnsiString; 

function GetVolumeSerial(Drive: PAnsiChar): PAnsiChar; stdcall; 
var 
    FileSystemFlags: DWORD; 
    VolumeSerialNumber: DWORD; 
    MaximumComponentLength: DWORD; 
begin 
    SerialNumber := ''; 
    GetVolumeInformationA(Drive, nil, 0, @VolumeSerialNumber, 
    MaximumComponentLength, FileSystemFlags, nil, 0); 
    SerialNumber := IntToHex(HiWord(VolumeSerialNumber), 4) + ' - ' + 
    IntToHex(LoWord(VolumeSerialNumber), 4); 
    Result := PAnsiChar(SerialNumber); 
end; 

exports 
    GetVolumeSerial; 

end. 

और यहाँ InnoSetup कोड है:

[Files] 
Source: "VolumeInformation.dll"; Flags: dontcopy 

[Code] 

function GetVolumeSerial(Drive: PAnsiChar): PAnsiChar; 
    external 'GetVolumeSerial@files:VolumeInformation.dll stdcall setuponly'; 

procedure ButtonOnClick(Sender: TObject); 
var 
    S: string; 
begin 
    S := GetVolumeSerial('c:\'); 
    MsgBox(S, mbInformation, mb_Ok); 
end;