एक एसक्यूएल चर के लिए निष्पादन परिणाम कैसे असाइन करें?

Question

एसक्यूएल में एक चर के लिए एक निष्पादन कॉल का परिणाम कैसे आवंटित करते हैं? मेरे पास up_GetBusinessDay नामक संग्रहित प्रो है, जो एक ही तारीख लौटाती है।

exec @PreviousBusinessDay = dbo.up_GetBusinessDay @Date, -1 

Answer 1

मैं हमेशा त्रुटि स्थिति को वापस करने के लिए वापसी मान का उपयोग करता हूं। यदि आपको एक मान वापस करने की आवश्यकता है तो मैं आउटपुट पैरामीटर का उपयोग करूंगा।

नमूना संग्रहीत प्रक्रिया, एक आउटपुट पैरामीटर के साथ: संग्रहीत प्रक्रिया के लिए

CREATE PROCEDURE YourStoredProcedure 
(
    @Param1 int 
    ,@Param2 varchar(5) 
    ,@Param3 datetime OUTPUT 
) 
AS 
IF ISNULL(@Param1,0)>5 
BEGIN 
    SET @Param3=GETDATE() 
END 
ELSE 
BEGIN 
    SET @Param3='1/1/2010' 
END 
RETURN 0 
GO 

कॉल, एक आउटपुट पैरामीटर के साथ:

DECLARE @OutputParameter datetime 
     ,@ReturnValue  int 

EXEC @ReturnValue=YourStoredProcedure 1,null, @OutputParameter OUTPUT 
PRINT @ReturnValue 
PRINT CONVERT(char(23),@OutputParameter ,121) 

उत्पादन:

0 
2010-01-01 00:00:00.000 

Answer 2

documentation से (यह मानते हुए कि आप एसक्यूएल-सर्वर का उपयोग करें):

USE AdventureWorks; 
GO 
DECLARE @returnstatus nvarchar(15); 
SET @returnstatus = NULL; 
EXEC @returnstatus = dbo.ufnGetSalesOrderStatusText @Status = 2; 
PRINT @returnstatus; 
GO 

तो हाँ, यह उस तरह से काम करना चाहिए

आप कुछ इस तरह कर सकते हैं।

Answer 3

यह काम करेंगे यदि आप बस एक पूर्णांक वापस करना चाहते हैं:

DECLARE @ResultForPos INT 
EXEC @ResultForPos = storedprocedureName 'InputParameter' 
SELECT @ResultForPos 

Answer 4

declare @EventId int 

CREATE TABLE #EventId (EventId int) 

insert into #EventId exec rptInputEventId 

set @EventId = (select * from #EventId) 

drop table #EventId