प्रतिबिंब

Question

का उपयोग करके किसी प्रकार के स्थैतिक फ़ील्ड मान प्राप्त करना मुझे स्थिर "गणना" कक्षाओं का एक सेट मिला है जिसका उपयोग मैं अर्थपूर्ण चर नामों को रखने के लिए कर रहा हूं ताकि इनपुट फ़ाइल पर प्राप्त किए गए अर्थहीन कोड मानों का प्रतिनिधित्व किया जा सके। यहां एक उदाहरण दिया गया है।

Public Class ReasonCodeValue 
    Private Sub New() 
    End Sub 
    Public Shared ReadOnly ServiceNotCovered As String = "SNCV" 
    Public Shared ReadOnly MemberNotEligible As String = "MNEL" 
End Class 

मैं एक विधि है कि इन स्थिर वर्गों में से एक के प्रकार के और एक स्ट्रिंग मान स्वीकार करते हैं और यह निर्धारित मूल्य स्थिर फ़ील्ड मान में से एक है होगा लिखना चाहते हैं। मुझे पता है कि किसी विशिष्ट ऑब्जेक्ट के लिए इंस्टेंस फ़ील्ड कैसे प्राप्त करें, और मुझे पता है कि विशिष्ट फ़ील्ड के लिए स्थिर फ़ील्ड की सूची कैसे प्राप्त करें; जो मैं समझ नहीं पा रहा हूं वह एक उदाहरण के बिना स्थैतिक फ़ील्ड मान कैसे प्राप्त करें। यहां तक ​​कि मुझे अब तक क्या मिला है।

Public Function IsValidValue(ByVal type As Type, ByVal value As String) As Boolean 
    Dim fields = type.GetFields(BindingFlags.Public Or BindingFlags.Static) 
    For Each field As FieldInfo In fields 
     DoSomething() 
    Next 
End Function 

मैं मैं गणन कक्षाएं गैर स्थिर सिर्फ इसलिए मैं अपने सत्यापन विधि के अंदर FieldInfo.GetValue को पारित करने के लिए एक उदाहरण बना सकते हैं बना सकता है चाहिए। मैं अपनी कक्षा को वैसे ही रखूंगा जैसा मैं कर सकता हूं।

मुझे GetRawConstantValue नामक एक विधि दिखाई देती है। यह खतरनाक लग रहा है। क्या वह मुझे वह दे देगा जो मैं ढूंढ रहा हूं? कोई अन्य विचार?

Answer 1

कॉल

field.GetValue(Nothing) 

और यह ठीक हो जाओगे। आपको स्थिर सदस्यों के लिए एक उदाहरण की आवश्यकता नहीं है।

मुझे नहीं लगताGetRawConstantValue वह है जो आप चाहते हैं - मैं उपरोक्त कोड पर चिपके रहूंगा।

Answer 2

आप बड़े मायने में ऐसा करने की कोशिश कर रहे हैं क्या को देखते हुए, शायद यह एक बेहतर फिट होगा:

Public Interface ICustomEnum(Of T) 
    Function FromT(ByVal value As T) As ICustomEnum(Of T) 
    ReadOnly Property Value() As T 

    ''// Implement using a private constructor that accepts and sets the Value property, 
    ''// one shared readonly property for each desired value in the enum, 
    ''// and widening conversions to and from T. 
    ''// Then see this link to get intellisense support 
    ''// that exactly matches a normal enum: 
    ''// https://stackoverflow.com/questions/102084/hidden-features-of-vb-net/102217#102217 
End Interface 

' 
''' <completionlist cref="ReasonCodeValue"/> 
Public NotInheritable Class ReasonCodeValue 
    Implements ICustomEnum(Of String) 

    Private _value As String 
    Public ReadOnly Property Value() As String Implements ICustomEnum(Of String).Value 
     Get 
      Return _value 
     End Get 
    End Property 

    Private Sub New(ByVal value As String) 
     _value = value 
    End Sub 

    Private Shared _ServiceNotCovered As New ReasonCodeValue("SNCV") 
    Public Shared ReadOnly Property ServiceNotCovered() As ReasonCodeValue 
     Get 
      Return _ServiceNotCovered 
     End Get 
    End Property 

    Private Shared _MemberNotEligible As New ReasonCodeValue("MNEL") 
    Public Shared ReadOnly Property MemberNotEligible() As ReasonCodeValue 
     Get 
      Return _MemberNotEligible 
     End Get 
    End Property 

    Public Shared Function FromString(ByVal value As String) As ICustomEnum(Of String) 
     ''// use reflection or a dictionary here if you have a lot of values 
     Select Case value 
      Case "SNCV" 
       Return _ServiceNotCovered 
      Case "MNEL" 
       Return _MemberNotEligible 
      Case Else 
       Return Nothing ''//or throw an exception 
     End Select 
    End Function 

    Public Function FromT(ByVal value As String) As ICustomEnum(Of String) Implements ICustomEnum(Of String).FromT 
     Return FromString(value) 
    End Function 

    Public Shared Widening Operator CType(ByVal item As ReasonCodeValue) As String 
     Return item.Value 
    End Operator 

    Public Shared Widening Operator CType(ByVal value As String) As ReasonCodeValue 
     Return FromString(value) 
    End Operator 
End Class 

और फिर IntelliSense समर्थन जो सटीक मेल खाता है कि प्राप्त करने के लिए इस लिंक पर आप सक्षम हो सकता है का उपयोग करते हुए एक सामान्य enum:
Hidden Features of VB.NET?