बाहर निकलने की स्थिति सेट करें यदि perl -cw चेतावनी उत्सर्जित करता है

Question

मैं perl -cw ... एक संकलन चेतावनी उत्सर्जित होने पर एक गैर-शून्य निकास स्थिति वापस करने के लिए चाहता हूं।

उदा।

use warnings; 
asd; 

फिर perl -cw a.pm रिपोर्ट: लगता है a.pm फ़ाइल है

Unquoted string "asd" may clash ... 
Useless use of a constant in void context ... 
a.pm syntax OK 

और बाहर निकलने स्थिति 0 पर सेट किया जाता है मुझे लगता है कि संकलन चेतावनी पता लगाने में सक्षम उत्सर्जित कर रहे थे होना चाहते हैं - अधिमानतः हालांकि बाहर निकलने की स्थिति की सेटिंग।

Answer 1

एक BEGIN ब्लॉक में एक चेतावनी हैंडलर सेट (स्क्रिप्ट के शीर्ष के निकट है, इसलिए इस ब्लॉक कोड से पहले पार्स किया गया है कि संकलन समय ट्रिगर हो सकता है चेतावनी), और एक END में बाहर निकलें स्थिति tweak CHECK ब्लॉक।

use strict; 
use warnings; 
my $warnings; 
BEGIN { 
    $SIG{__WARN__} = sub { $warnings++; CORE::warn @_ } 
} 
$used::only::once = 42; 
CHECK { 
    if ($^C && $warnings > 0) { 
     exit $warnings; 
    } 
} 

$^C चर सच यदि और केवल यदि आप -c विकल्प के साथ perl लागू कर दिया है।

Answer 2

जहाँ तक मुझे पता है, यह संभव नहीं है। आखिरकार, वे सलाहकार नोटिस केवल सख्ती से नहीं हैं (कोई इरादा नहीं है) त्रुटियां। उलटा, हालांकि, आप रनटाइम पर घातक त्रुटियों के लिए चेतावनियों को बढ़ावा दे सकते हैं यदि इससे आपके उद्देश्य को हल करने में मदद मिलती है।

$ perl -M'warnings FATAL=>q(all)' -cw a.pm ; echo $? 
Unquoted string "asd" may clash with future reserved word at a.pm line 2. 
255 

Answer 3

इस व्यवहार को प्राप्त करने के लिए आप पहली चेतावनी के बाद मरने के लिए $SIG{__WARN__} का उपयोग कर सकते हैं। बस इस तरह:

package warncounter; 

use strict; 
use warnings; 

my $warnings; 

BEGIN { 
    $SIG{__WARN__} = sub { 
     $warnings++; 
     CORE::warn(@_); 
     exit(255); 
    }; 
} 

1; 

और फिर आप के रूप में

perl -Mwarncounter -wc test.pl 

जाँच वाक्य रचना चला सकते हैं लेकिन फिर पर्ल सही पहली चेतावनी के बाद बाहर निकल जाएगा। मेरा पहला विचार चेतावनी की संख्या गिनना था और ईएनडी ब्लॉक में निकास की स्थिति निर्धारित करना था, लेकिन वाक्यविन्यास जांच मोड -c ईएनडी ब्लॉक नहीं लगाया जा रहा था।