यूनिट परीक्षण के लिए क्लोजर का उपयोग जावा

Question

एक वैकल्पिक जेवीएम भाषा स्वीकार करने के लिए संगठन प्राप्त करने के तरीकों में से एक है इसे पहले यूनिट परीक्षण जावा कोड के लिए उपयोग करना है - "बॉस, मैं बस XXX में कुछ यूनिट परीक्षण लिखने जा रहा हूं। यह कभी उत्पादन में नहीं जायेगा। "

क्या क्लोजर में ऐसा करने के लिए कोई ट्यूटोरियल है?

मैंने जावा रीस्ट सर्वर का परीक्षण करने के लिए अभी ऐसा करने के लिए स्कैला का उपयोग करना शुरू कर दिया है। स्कैला में परीक्षण लिखने से मुझे अपेक्षित एक्सएमएल आउटपुट एम्बेड करने की अनुमति मिलती है, शाब्दिक List ऑब्जेक्ट्स आदि के साथ डेटाबेस कॉल का मज़ाक उड़ाते हैं, यह उल्लेख न करें कि लक्षणों के परीक्षण के लिए सामान्य कोड को अमूर्त करना बहुत आसान हो जाता है।

Answer 1

मूल रूप से आपको जो चाहिए वह clojure.test (या कई अन्य क्लोजर परीक्षण libs में से एक है) और मानक क्लोजर Java interop है।

उदाहरण:

(ns example.test-java-util 
    (:use 
    [clojure.test]) 
    (:import [java.util HashSet])) 

(defn new-empty-set [] 
    (HashSet.)) 

(deftest test-empty-set 
    (is (= 0 (.size (new-empty-set)))) 
    (is (= true (.isEmpty (new-empty-set)))) 
    (is (= (new-empty-set) (new-empty-set)))) 

(deftest test-add-remove 
    (is (= (new-empty-set) 
     (doto (new-empty-set) 
      (.add "xyz") 
      (.remove "xyz"))))) 

और आप फिर उन्हें विभिन्न तरीकों से में चला जाएगा। मेवेन क्लोजर प्लगइन का उपयोग करके मेवेन जैसे टूल बनाएं, उन्हें स्वचालित रूप से "एमवीएन टेस्ट" के हिस्से के रूप में चलाएं।

example.test-java-util> (run-tests 'example.test-java-util) 

Testing example.test-java-util 

Ran 1 tests containing 4 assertions. 
0 failures, 0 errors. 
{:type :summary, :test 1, :pass 4, :fail 0, :error 0} 

Answer 2

यहाँ Leiningen, test.check का उपयोग कर और एक मानक Maven लेआउट संभालने के लिए एक उदाहरण है::

pom.xml 
project.clj 
src 
    main 
    java 
     quicktest 
     Discontinuities.java 
    test 
    clojure 
     quicktest 
     test_discontinuities.clj 

जावा समारोह परीक्षण करने के लिए:

package quicktest; 
public class Discontinuities { 
    public static double f5(double x) { 
     return x/(x-5); 
    } 
} 

एक repl में, आप की तरह कुछ कर सकते हैं

क्लोजर परीक्षण केस:

(ns quicktest.test-discontinuities 
    (:import [quicktest Discontinuities]) 
    (:require [clojure.test :refer :all] 
    [clojure.test.check :as tc] 
    [clojure.test.check.generators :as gen] 
    [clojure.test.check.properties :as prop] 
    [clojure.test.check.clojure-test :as ct :refer (defspec)])) 

(deftest test-single-case 
    (is (= 2.0 (Discontinuities/f5 10)))) 

(defspec test-discontinuities 1e4 
     (prop/for-all [x gen/nat ] 
         (let [y (Discontinuities/f5 x)] 
          (is (<= y x))))) 

परियोजना:

(defproject quicktest/discontinuities "0.1" 
      :dependencies [[org.clojure/clojure "1.8.0"] 
          [org.clojure/test.check "0.9.0"]] 
      :java-source-paths ["src/main/java"] 
      :test-paths ["src/test/clojure"]) 

पोम:

<?xml version="1.0" encoding="UTF-8"?> 
<project xmlns="http://maven.apache.org/POM/4.0.0" 
     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
     xsi:schemaLocation="http://maven.apache.org/POM/4.0.0 http://maven.apache.org/xsd/maven-4.0.0.xsd"> 
    <modelVersion>4.0.0</modelVersion> 
    <groupId>quicktest</groupId> 
    <artifactId>discontinuities</artifactId> 
    <version>0.1</version> 
</project> 

साथ भागो:

mvn compile 
lein deps 
lein test 

परिणाम

समारोह में दोष जल्दी से पाया जाता है:

FAIL in (test-discontinuities) (test_discontinuities.clj:13) 
expected: (<= y x) 
actual: (not (<= Infinity 5)) 
{:test-var "test-discontinuities", 
:result false, 
:seed 1431128331945, 
:failing-size 23, 
:num-tests 24, 
:fail [5], 
:shrunk {:total-nodes-visited 3, :depth 0, :result false, :smallest [5]}}