वीबीनेट में क्रिप्टोग्राफी - डिक्रिप्ट फ़ाइल स्रोत फ़ाइल से बड़ी है?

Question

हाय एन्क्रिप्ट और एक फ़ाइल को डिक्रिप्ट करने System.Security.Cryptography उपयोग करने की कोशिश ive गया है, लेकिन इसके लिए मुझे

काम नहीं कर रहा इस कोड

Private Sub EncryptFile(ByVal sInputFilename As String, ByVal sOutputFilename As String, ByVal sKey As String) 
    Dim fsInput As New FileStream(sInputFilename, FileMode.Open, FileAccess.Read) 
    Dim fsEncrypted As New FileStream(sOutputFilename, FileMode.Create, FileAccess.Write) 
    Dim DES As New DESCryptoServiceProvider() 
    DES.Key = ASCIIEncoding.ASCII.GetBytes(sKey) 
    DES.IV = ASCIIEncoding.ASCII.GetBytes(sKey) 
    Dim desencrypt As ICryptoTransform = DES.CreateEncryptor() 
    Dim cryptostream As New CryptoStream(fsEncrypted, desencrypt, CryptoStreamMode.Write) 
    Dim bytearrayinput(fsInput.Length - 1) As Byte 
    fsInput.Read(bytearrayinput, 0, bytearrayinput.Length) 
    cryptostream.Write(bytearrayinput, 0, bytearrayinput.Length) 
    cryptostream.Close() 
End Sub 

साथ

EncryptFile(OpenFileDialog1.FileName, SaveFileDialog1.FileName, "12345678")[/CODE] 

काम करने लगता है कहा जाता है ठीक है और मुझे एक फ़ाइल को स्रोत फ़ाइल

हेरेस के समान आकार मिलता है जहां यह गलत हो जाता है हालांकि

इस कोड

Private Sub DecryptFile(ByVal sInputFilename As String, ByVal sOutputFilename As String, ByVal sKey As String) 
    Dim DES As New DESCryptoServiceProvider() 
    DES.Key() = ASCIIEncoding.ASCII.GetBytes(sKey) 
    DES.IV = ASCIIEncoding.ASCII.GetBytes(sKey) 
    Dim fsread As New FileStream(sInputFilename, FileMode.Open, FileAccess.Read) 
    Dim desdecrypt As ICryptoTransform = DES.CreateDecryptor() 
    Dim cryptostreamDecr As New CryptoStream(fsread, desdecrypt, CryptoStreamMode.Read) 
    Dim fsDecrypted As New StreamWriter(sOutputFilename) 
    fsDecrypted.Write(New StreamReader(cryptostreamDecr).ReadToEnd) 
    fsDecrypted.Flush() 
    fsDecrypted.Close() 
End Sub 

DecryptFile(OpenFileDialog1.FileName, SaveFileDialog1.FileName, "12345678")[/CODE] 

साथ नामक एक फ़ाइल है कि स्रोत फ़ाइल है कि एन्क्रिप्ट किया गया था के रूप में बड़े रूप में लगभग 2x है आउटपुट।

मुझे क्या यकीन है कि यह कुछ हफ्ते पहले ठीक काम कर रहा था और मैं इसके साथ कुछ भी गलत नहीं देख सकता।

कोई विचार कृपया?

Answer 1

मुख्य समस्या यह है कि एन्क्रिप्टेडफाइल बाइट सरणी का उपयोग कर डेटा में पढ़ता है और डिक्रिप्टफाइल स्ट्रीम का उपयोग कर डेटा में पढ़ रहा है। EncryptFile और DecryptFile विधियों के बीच एकमात्र अंतर आपके ICryptoTransform असाइनमेंट होना चाहिए। यह 1 प्रक्रिया में आम कोड के लिए आसान होगा:

Private Sub EncryptFile(ByVal sInputFilename As String, ByVal sOutputFilename As String, ByVal sKey As String) 
    Crypto(sInputFilename, sOutputFilename, sKey, True) 
End Sub 

Private Sub DecryptFile(ByVal sInputFilename As String, ByVal sOutputFilename As String, ByVal sKey As String) 
    Crypto(sInputFilename, sOutputFilename, sKey, False) 
End Sub 

Private Sub Crypto(ByVal sInputFileName As String, ByVal sOutputFileName As String, ByVal sKey As String, ByVal bEncrypt As Boolean) 
    'Define the service provider 
    Dim DES As New DESCryptoServiceProvider() 
    DES.Key() = ASCIIEncoding.ASCII.GetBytes(sKey) 
    DES.IV = ASCIIEncoding.ASCII.GetBytes(sKey) 


    'Read the input file into array 
    Dim fsInput As New FileStream(sInputFileName, FileMode.Open, FileAccess.Read) 
    Dim bytearrayinput(fsInput.Length - 1) As Byte 
    fsInput.Read(bytearrayinput, 0, bytearrayinput.Length) 


    'Define the crypto transformer 
    Dim cryptoTransform As ICryptoTransform 

    If bEncrypt Then 
     cryptoTransform = DES.CreateEncryptor() 
    Else 
     cryptoTransform = DES.CreateDecryptor 
    End If 


    'Create the encrypting streams 
    Dim fsEncrypted As New FileStream(sOutputFileName, FileMode.Create, FileAccess.Write) 
    Dim cryptostream As New CryptoStream(fsEncrypted, cryptoTransform, CryptoStreamMode.Write) 

    'Write the output file 
    cryptostream.Write(bytearrayinput, 0, bytearrayinput.Length) 
    cryptostream.Close() 
End Sub 

क्रिप्टो प्रक्रिया क्या EncryptFile हुआ करते थे करने के लिए लगभग समान है। अंतर यह है कि क्या आप ICryptoTransform असाइनमेंट को इस पर आधारित करते हैं कि आप एन्क्रिप्ट कर रहे हैं या डिक्रिप्ट कर रहे हैं या नहीं।