इनो सेटअप में [रन] अनुभाग में निष्पादित होने के लिए सशर्त बयान जोड़ना संभव है?

Question

वैकल्पिक रूप से अंतर्निहित प्रगति पट्टी को मैन्युअल रूप से अपडेट करना संभव है? असल में मेरे पास 2 एमएसआई शामिल हैं और बूटस्ट्रैपर के रूप में इनो सेटअप का उपयोग कर रहे हैं, और उपयोगकर्ता इनपुट के आधार पर एक या दोनों एमएसआई स्थापित किए जाने हैं। मेरे पास CurStepChanged में Exec कथन का उपयोग करके कुछ काम कर रहा है लेकिन यह प्रगति पट्टी को अद्यतन नहीं करता है क्योंकि फ़ाइलों को निकाला जाता है और ऐसा लगता है कि इंस्टॉलर रुक गया है। मुझे लगता है कि अंतिम परिणाम यह है कि मैं कुछ प्रगति बार अपडेट चाहता हूं जबकि फ़ाइलों को अस्थायी फ़ोल्डर में निकाला जाता है।

procedure CurStepChanged(CurStep: TSetupStep); 
var 
    ResultCode: Integer; 
begin 
    if(CurStep = ssInstall) then begin 
     if(InstallServer) then begin 
      ExtractTemporaryFile('ServerSetup.msi'); 
      Exec('msiexec',ExpandConstant('/i "{tmp}\ServerSetup.msi" /qb INSTALLDIR="{code:GetInstallPath}\Server\" ALLUSERS=2'),'', SW_SHOW, ewWaitUntilTerminated, ResultCode); 
     end; 
     if(InstallClient) then begin 
      ExtractTemporaryFile('ClientSetup.msi'); 
      Exec('msiexec',ExpandConstant('/i "{tmp}\ClientSetup.msi" /qb INSTALLDIR="{code:GetInstallPath}\Client\" ALLUSERS=2'),'', SW_SHOW, ewWaitUntilTerminated, ResultCode); 
     end; 
    end; 
end; 

Answer 1

क्यों बस कुछ इस तरह की कोशिश नहीं:

[Files] 
Source: ClientSetup.msi; DestDir: {tmp}; Flags: deleteafterinstall; Components: Client 
Source: ServerSetup.msi; DestDir: {tmp}; Flags: deleteafterinstall; Components: Server 

[Run] 
Filename: msiexec.exe; Parameters: /i "{tmp}\ClientSetup.msi" /qb INSTALLDIR="{code:GetInstallPath}\Client\" ALLUSERS=2; WorkingDir: {tmp}; StatusMsg: Installing client; Components: Client 
Filename: msiexec.exe; Parameters: /i "{tmp}\ServerSetup.msi" /qb INSTALLDIR="{code:GetInstallPath}\Server\" ALLUSERS=2; WorkingDir: {tmp}; StatusMsg: Installing server; Components: Server 

[Components] 
Name: Client; Description: Client Installation 
Name: Server; Description: Server Installation 

बेशक

आप जरूरी Components उपयोग करने के लिए की जरूरत नहीं है निम्नलिखित मेरे वर्तमान कोड है। आपने यह नहीं लिखा कि आप किस इंस्टालर को चलाने के लिए तय करते हैं। आप और अधिक जटिल तर्क की जरूरत है आप भी रूप में इस्तेमाल कर सकते हैं Check functions:

[Files] 
Source: ClientSetup.msi; DestDir: {tmp}; Flags: deleteafterinstall; Check: CheckClient 
Source: ServerSetup.msi; DestDir: {tmp}; Flags: deleteafterinstall; Check: CheckServer 

[Run] 
Filename: msiexec.exe; Parameters: /i "{tmp}\ClientSetup.msi" /qb INSTALLDIR="{code:GetInstallPath}\Client\" ALLUSERS=2; WorkingDir: {tmp}; StatusMsg: Installing client; Check: CheckClient 
Filename: msiexec.exe; Parameters: /i "{tmp}\ServerSetup.msi" /qb INSTALLDIR="{code:GetInstallPath}\Server\" ALLUSERS=2; WorkingDir: {tmp}; StatusMsg: Installing server; Check: CheckServer 

[Code] 
function CheckClient: Boolean; 
begin 
    Result := WhateverCondition; 
end; 

function CheckServer: Boolean; 
begin 
    Result := WhateverOtherCondition; 
end;