डेल्फी - एक रेक्ट

Question

के केंद्र में टेक्स्ट मल्टीलाइन ड्रा करें डेल्फी में मैं एक ट्रैक्ट के अंदर टेक्स्ट खींचना चाहता हूं। मैं निम्नलिखित कार्यक्षमता के लिए उम्मीद कर रहा हूँ:

1. ड्रा पाठ TRect
2. भीतर लंबवत रूप से केंद्रित पाठ TRect
3. भीतर क्षैतिज रूप से केंद्रित ड्रा वहाँ है, तो पाठ (का उपयोग कर के 1 से अधिक लाइन के लिए जगह TRect के ऊंचाई), टेक्स्ट मल्टीलाइन
4. ड्रा करें यदि टेक्स्ट TRect में फिट नहीं है (या तो एकल या बहु लाइन पर) तो टेक्स्ट में इलिप्सिस संलग्न करें।

मैं Windows.DrawText() फ़ंक्शन लगभग देख सकते हैं इस कार्यशीलता को शामिल किया गया है, लेकिन जब पाठ, बहु लेखन और ऊर्ध्व रूप से केंद्रित परस्पर अनन्य हैं।

मैं सोच रहा था कि यह कार्यक्षमता विंडोज़ (2000+) में बनाई गई है या नहीं? यदि नहीं, तो अपना खुद का कार्य लिखने के बिना ऐसा करने का कोई तरीका नहीं है?

Answer 1

क्षमा करें, यह सभी पिछले उत्तरों और टिप्पणियों का एक संयोजन है। लेकिन ऐसा लगता है कि ओपी को और सहायता चाहिए।

function DrawTextCentered(Canvas: TCanvas; const R: TRect; S: String): Integer; 
var 
    DrawRect: TRect; 
    DrawFlags: Cardinal; 
    DrawParams: TDrawTextParams; 
begin 
    DrawRect := R; 
    DrawFlags := DT_END_ELLIPSIS or DT_NOPREFIX or DT_WORDBREAK or 
    DT_EDITCONTROL or DT_CENTER; 
    DrawText(Canvas.Handle, PChar(S), -1, DrawRect, DrawFlags or DT_CALCRECT); 
    DrawRect.Right := R.Right; 
    if DrawRect.Bottom < R.Bottom then 
    OffsetRect(DrawRect, 0, (R.Bottom - DrawRect.Bottom) div 2) 
    else 
    DrawRect.Bottom := R.Bottom; 
    ZeroMemory(@DrawParams, SizeOf(DrawParams)); 
    DrawParams.cbSize := SizeOf(DrawParams); 
    DrawTextEx(Canvas.Handle, PChar(S), -1, DrawRect, DrawFlags, @DrawParams); 
    Result := DrawParams.uiLengthDrawn; 
end; 

procedure TForm1.FormPaint(Sender: TObject); 
const 
    S = 'This is a very long text as test case for my paint routine.'; 
var 
    R: TRect; 
begin 
    SetRect(R, 100, 100, 200, 140); 
    Canvas.Rectangle(R); 
    InflateRect(R, -1, -1); 
    Caption := Format('%d characters drawn', [DrawTextCentered(Canvas, R, S)]); 
end; 

Answer 2

DT_CALCRECT का उपयोग कर पहले टेक्स्ट को मापें। शब्द रैपिंग सक्षम करने के लिए DT_WORDBREAK पास करें। यह आपको अपने पाठ के लिए आवश्यक ऊंचाई खोजने की अनुमति देगा। फिर आप अपने कोड में, ऊर्ध्वाधर ऑफ़सेट की गणना कर सकते हैं जो आपको लंबवत केंद्रित पाठ देता है, और उस ऑफसेट पर आकर्षित करता है।