एक्सेल में वीबीए

Question

के साथ गैर-रिक्त कक्षों का चयन करना मैं बस वीबीए में गोता लगाने लगा हूं और मैंने थोड़ा सा रोडब्लॉक मारा है।

मेरे पास 50+ कॉलम, 900+ पंक्तियों के साथ एक शीट है। मुझे उन 10 कॉलम को दोबारा सुधारने की जरूरत है और उन्हें एक नई कार्यपुस्तिका में चिपकाएं।

मैं प्रोग्राम 1 के कॉलम में प्रत्येक गैर-खाली सेल का प्रोग्रामेटिक रूप से चयन कैसे करूं, इसे कुछ कार्यों के माध्यम से चलाएं, और परिणाम 2 बुक में छोड़ दें?

Answer 1

निम्नलिखित वीबीए सह आपको शुरू करना चाहिए। यह मूल कार्यपुस्तिका में सभी डेटा को एक नई कार्यपुस्तिका में कॉपी करेगा, लेकिन यह प्रत्येक मान में 1 जोड़ देगा, और सभी रिक्त कक्षों को अनदेखा कर दिया जाएगा।

Option Explicit 

Public Sub exportDataToNewBook() 
    Dim rowIndex As Integer 
    Dim colIndex As Integer 
    Dim dataRange As Range 
    Dim thisBook As Workbook 
    Dim newBook As Workbook 
    Dim newRow As Integer 
    Dim temp 

    '// set your data range here 
    Set dataRange = Sheet1.Range("A1:B100") 

    '// create a new workbook 
    Set newBook = Excel.Workbooks.Add 

    '// loop through the data in book1, one column at a time 
    For colIndex = 1 To dataRange.Columns.Count 
     newRow = 0 
     For rowIndex = 1 To dataRange.Rows.Count 
      With dataRange.Cells(rowIndex, colIndex) 

      '// ignore empty cells 
      If .value <> "" Then 
       newRow = newRow + 1 
       temp = doSomethingWith(.value) 
       newBook.ActiveSheet.Cells(newRow, colIndex).value = temp 
       End If 

      End With 
     Next rowIndex 
    Next colIndex 
End Sub 

Private Function doSomethingWith(aValue) 

    '// This is where you would compute a different value 
    '// for use in the new workbook 
    '// In this example, I simply add one to it. 
    aValue = aValue + 1 

    doSomethingWith = aValue 
End Function 

Answer 2

आप देख रहे हैं एक कॉलम के अंतिम पंक्ति के लिए उपयोग करें:

Sub SelectFirstColumn() 
    SelectEntireColumn (1) 
End Sub 

Sub SelectSecondColumn() 
    SelectEntireColumn (2) 
End Sub 

Sub SelectEntireColumn(columnNumber) 
    Dim LastRow 
    Sheets("sheet1").Select 
    LastRow = ActiveSheet.Columns(columnNumber).SpecialCells(xlLastCell).Row 

    ActiveSheet.Range(Cells(1, columnNumber), Cells(LastRow, columnNumber)).Select 
End Sub 

अन्य आदेशों आप कर रहे हैं कॉपी और पेस्ट आदेशों से परिचित हो की आवश्यकता होगी:

Sub CopyOneToTwo() 
    SelectEntireColumn (1) 
    Selection.Copy 

    Sheets("sheet1").Select 
    ActiveSheet.Range("B1").PasteSpecial Paste:=xlPasteValues 
End Sub 

अंत में, आप निम्नलिखित वाक्यविन्यास का उपयोग करके अन्य कार्यपुस्तिकाओं में वर्कशीट का संदर्भ दे सकते हैं:

Dim book2 
Set book2 = Workbooks.Open("C:\book2.xls") 
book2.Worksheets("sheet1") 

Answer 3

यह पूरी तरह से बंद आधार हो सकता है, लेकिन आप केवल एक नई स्प्रैडशीट में पूरे स्तंभ कॉपी नहीं कर सकते और फिर स्तंभ को क्रमबद्ध? मुझे लगता है कि आपको आदेश अखंडता को बनाए रखने की आवश्यकता नहीं है।

Answer 4

मैं जानता हूँ कि मैं कर रहा हूँ बहुत देर से कर रहा हूँ इस पर, लेकिन यहाँ कुछ उपयोगी नमूने:

'select the used cells in column 3 of worksheet wks 
wks.columns(3).SpecialCells(xlCellTypeConstants).Select 

या

'change all formulas in col 3 to values 
with sheet1.columns(3).SpecialCells(xlCellTypeFormulas) 
    .value = .value 
end with 

स्तंभ में अंतिम बार उपयोग पंक्ति ढूंढने के लिए, कभी नहीं LastCell पर भरोसा करते हैं, जो अविश्वसनीय है (डेटा को हटाने के बाद इसे रीसेट नहीं किया जाता है)। इसके बजाय, मैं

lngLast = cells(rows.count,3).end(xlUp).row