किसी विशिष्ट रनटाइम प्रकार की खाली सूची कैसे बनाएं

Question

नेट टाइप को देखते हुए, typeof<string> कहें, रनटाइम पर कैसे string list = [] के बराबर बनाया गया है?

मेरी प्रेरणा यह है कि FSharpValue.MakeRecord का उपयोग करते हुए मानों के आधार पर रिकॉर्ड बनाने के लिए मानों को पार्स किए गए मानों को obj[] के रूप में पारित करने की आवश्यकता है। मैं box का उपयोग करके तर्कों कास्टिंग कर रहा हूं और उसने सूचियों को छोड़कर काम किया है। मेरे सामने आने वाली समस्या यह है कि एक खाली अनियमित सूची सूची को बॉक्स नहीं किया जा सकता है और फिर अनबॉक्स किया जा सकता है। विशिष्ट लौटे त्रुटि है:

System.InvalidCastException: Unable to cast object of type 
'Microsoft.FSharp.Collections.FSharpList`1[System.Object]' 
to type 
'Microsoft.FSharp.Collections.FSharpList`1[System.String]'. 

एक खाली टाइप सूची बॉक्सिंग और अनबॉक्स्ड जा सकती है, तो मैं एक क्रम प्रकार, उदाहरण के लिए एक सूची कास्ट करने के लिए एक रास्ता खोजने के लिए कोशिश की है < टाइप करके एक प्रकार लौटाया गया है लेकिन बिना किसी किस्मत के।

type Test = {Names : string list} 
// fails 
let genericList = [] 
{Names = unbox (box genericList)} 

//works 
let typedList : string list = [] 
{Names = unbox (box typedList)} 

//works 
let genericNonEmptyList = ["Bill"] 
{Names = unbox (box genericNonEmptyList)} 

Answer 1

कैसे Seq.cast का उपयोग कर खाली सामान्य सूची कास्ट करने के लिए के बारे में?

type Test = {Names : string list} 
let genericList = [] 
let test = {Names = unbox (box genericList) |> Seq.cast<string> |> Seq.toList} 
test.Names //val it : string list = [] 

Answer 2

प्रतिबिंब का उपयोग करके आप List मॉड्यूल हो और सामान्य empty विधि कॉल कर सकते हैं: इस प्रकार

open System 
open System.Reflection 

let emptyList (t:Type) = 
    Assembly.GetAssembly(typeof<_ list>) 
     .GetType("Microsoft.FSharp.Collections.ListModule") 
     .GetMethod("Empty", BindingFlags.Static ||| BindingFlags.Public) 
     .MakeGenericMethod(t) 
     .Invoke(null, [||]) 

उपयोग:

let itemType = typeof<string> 
let emptyStringList = emptyList(itemType) :?> string list 

आपको लगता है कि कॉल कर रहे हैं अक्सर, कैशिंग पर विचार (~ 1/3 द्वारा निष्पादन समय को कम करता है):

let emptyList = 
    let empty = 
     Assembly.GetAssembly(typeof<_ list>) 
      .GetType("Microsoft.FSharp.Collections.ListModule") 
      .GetMethod("Empty", BindingFlags.Static ||| BindingFlags.Public) 
    fun (t:Type) -> empty.MakeGenericMethod(t).Invoke(null, [||]) 

Answer 3

@CaringDev के जवाब का उपयोग कर नेट प्रतिबिंब ठीक है, लेकिन आप भी एफ # विशिष्ट प्रतिबिंब मॉड्यूल का उपयोग संघ मामलों के उदाहरण बनाने के लिए कर सकते हैं:

let empty ty = 
    let uc = 
     Reflection.FSharpType.GetUnionCases(typedefof<_ list>.MakeGenericType [|ty|]) 
     |> Seq.filter (fun uc -> uc.Name = "Empty") 
     |> Seq.exactlyOne 
    Reflection.FSharpValue.MakeUnion(uc, [||]) 

Answer 4

मुझे एक और विकल्प जवाब जोड़ते हैं - हालांकि दोनों मौजूदा विधियों का काम करते हैं, वे समझते हैं कि एफ # सूचियों का प्रतिनिधित्व कैसे करता है। पहले मामले में, आपको यह जानने की जरूरत है कि Empty विधि है और दूसरे मामले में, आपको यह जानने की जरूरत है कि Empty नामक यूनियन केस है।

मैं आम तौर पर एक सहायक प्रकार को परिभाषित करने और अपने कस्टम प्रकार से अधिक प्रतिबिंब का उपयोग करके ऐसा करना पसंद करते हैं:

type ListHelper = 
    static member Empty<'T>() : list<'T> = [] 

let makeEmpty = 
    let empty = typeof<ListHelper>.GetMethod("Empty") 
    let emptyArr : obj[] = [| |] 
    fun ty -> empty.MakeGenericMethod([| ty |]).Invoke(null, emptyArr) 

यह आपको काफी सरल समारोह देता है कि कैश कर सकते MethodInfo (आप भी Expression इस्तेमाल कर सकते हैं पूर्व के लिए संकलन और नकल कैश) और चालाक चाल पर भरोसा नहीं करता है।

Answer 5

मैं पार्टी के लिए देर से हूं, लेकिन मैं वही काम करने की कोशिश कर रहा था।

let emptyListFromExample e = 
    match [e] with 
    | [] -> [] 
    | x::xs -> xs 

यह आपको किसी भी प्रकार की एक खाली सूची आप इसे बंद शुरू करने के लिए उस प्रकार के एक मूल्य के निर्माण कर सकते हैं प्रदान की दे देंगे: मैं एक तरह से पैटर्न मिलान के साथ ऐसा कर पाया।