डेल्फी

Question

में विंडोज़ पर पूरी तरह से योग्य डोमेन नाम कैसे प्राप्त करें मुझे डोमेन पर विंडोज मशीन के लिए डेल्फी में पूरी तरह योग्य डोमेन नाम प्राप्त करने की आवश्यकता है।

मैं LookupAccountSid का उपयोग करने की कोशिश की है, लेकिन यह मेरे मामले में यह "इंट्रानेट" है में मुझे केवल NetBIOS डोमेन नाम, देता है, लेकिन मैं पूरी की जरूरत है "intranet.companyname.com"

किसी भी विचार?

Answer 1

GetUserNameEx Windows API समारोह की कोशिश करो।

const 
    NameUnknown   = 0; 
    NameFullyQualifiedDN = 1; 
    NameSamCompatible  = 2; 
    NameDisplay   = 3; 
    NameUniqueId   = 6; 
    NameCanonical   = 7; 
    NameUserPrincipal  = 8; 
    NameCanonicalEx  = 9; 
    NameServicePrincipal = 10; 
    NameDnsDomain   = 12; 

function GetUserNameExString(ANameFormat: DWORD): string; 
var 
    Buf: array[0..256] of Char; 
    BufSize: DWORD; 
    GetUserNameEx: function (NameFormat: DWORD; lpNameBuffer: LPSTR; 
    var nSize: ULONG): BOOL; stdcall; 
begin 
    Result := ''; 
    BufSize := SizeOf(Buf) div SizeOf(Buf[0]); 
    GetUserNameEx := GetProcAddress(GetModuleHandle('secur32.dll'), 'GetUserNameExA'); 
    if Assigned(GetUserNameEx) then 
    if GetUserNameEx(ANameFormat, Buf, BufSize) then 
     Result := Buf; 
end; 

उदाहरण के लिए NameDnsDomain प्रारूप का उपयोग कर, www.mydomain.com\user_name परिणाम यदि आप "www.mydomain.com" डोमेन में लॉग इन किया जाएगा।

---

चूंकि अब मैंने इसे अपने आवेदन में अपनी जरूरतों के लिए लागू किया है, इसलिए @ आईपैथ की टिप्पणी सही छोड़ दी गई थी। GetComputerNameEx का बेहतर उपयोग करें, और अपनी खुद की जरूरतों के लिए COMPUTER_NAME_FORMAT में से एक निर्दिष्ट करें।

एक डेल्फी कार्यान्वयन इस (यूनिकोड संस्करण) दिखाई देगा:

interface 
... 
type 
    COMPUTER_NAME_FORMAT = (
    ComputerNameNetBIOS, 
    ComputerNameDnsHostname, 
    ComputerNameDnsDomain, 
    ComputerNameDnsFullyQualified, 
    ComputerNamePhysicalNetBIOS, 
    ComputerNamePhysicalDnsHostname, 
    ComputerNamePhysicalDnsDomain, 
    ComputerNamePhysicalDnsFullyQualified, 
    ComputerNameMax); 

function GetComputerNameExString(ANameFormat: COMPUTER_NAME_FORMAT): WideString; 

implementation 
... 
function GetComputerNameExW(NameType: COMPUTER_NAME_FORMAT; lpBuffer: LPWSTR; 
    var nSize: DWORD): BOOL; stdcall; external kernel32 name 'GetComputerNameExW'; 

function GetComputerNameExString(ANameFormat: COMPUTER_NAME_FORMAT): WideString; 
var 
    nSize: DWORD; 
begin 
    nSize := 1024; 
    SetLength(Result, nSize); 
    if GetComputerNameExW(ANameFormat, PWideChar(Result), nSize) then 
    SetLength(Result, nSize) 
    else 
    Result := ''; 
end; 

Answer 2

NetGetJoinInformation ठीक काम करना चाहिए।

MSDN:

http://msdn.microsoft.com/en-us/library/windows/desktop/aa370423(v=vs.85).aspx

उदाहरण:

type 
    PWKSTA_INFO_100 = ^WKSTA_INFO_100; 

    WKSTA_INFO_100 = packed record 
    wki100_platform_id: DWord; 
    wki100_computername: PWChar; 
    wki100_langroup: PWChar; 
    wki100_ver_major: DWord; 
    wki100_ver_minor: DWord; 
    end; 

    TNetSetupJoinStatus = 
    (
    NetSetupUnknownStatus, 
    NetSetupUnjoined, 
    NetSetupWorkgroupName, 
    NetSetupDomainName 
); 

    TNetApiBufferFreeFunction = function(ABuffer: Pointer): DWORD; stdcall; 
    TNetWkstaGetInfoFunction = function(const AServername: PWChar; const ALevel: DWord; const ABufptr: Pointer): DWORD; stdcall; 
    TNetGetJoinInformationFunction = function(const AServerName: PWChar; out ANameBuffer: PWChar; out ABufferType: TNetSetupJoinStatus): DWORD; stdcall; 

const 
    NERR_SUCCESS = 0; 

function GetLocalComputerDomainName: string; 
var 
    NetApiBuffer: Pointer; 
    NetApi: THandle; 
    NetApiBufferFree: TNetApiBufferFreeFunction; 
    NetWkstaGetInfo: TNetWkstaGetInfoFunction; 
    NetGetJoinInformation: TNetGetJoinInformationFunction; 
    NetSetupJoinStatus: TNetSetupJoinStatus; 
    NameBuffer: PWideChar; 
begin 
    Result := ''; 
    NetApi := LoadLibrary('netapi32.dll'); 
    if NetApi <> 0 then 
    begin 
    NetApiBufferFree  := TNetApiBufferFreeFunction( GetProcAddress(NetApi, 'NetApiBufferFree')); 
    NetGetJoinInformation := TNetGetJoinInformationFunction(GetProcAddress(NetApi, 'NetGetJoinInformation')); 
    NetWkstaGetInfo  := TNetWkstaGetInfoFunction(  GetProcAddress(NetApi, 'NetWkstaGetInfo')); 
    if @NetApiBufferFree <> nil then 
    begin 
     if @NetSetupJoinStatus <> nil then 
     begin 
     if NetGetJoinInformation(nil, NameBuffer, NetSetupJoinStatus) = NERR_SUCCESS then 
     begin 
      if NetSetupJoinStatus = NetSetupDomainName then 
      begin 
      Result := NameBuffer; 
      end; 
      NetApiBufferFree(NameBuffer); 
     end; 
     end; 
    end; 
    FreeLibrary(NetApi); 
    end; 
end; 

Answer 3

मैं ऊपर के सभी कोशिश की, लेकिन सफलता नहीं मिली। अंत में, मैं बस पर्यावरण चर पकड़ने के लिए बस गया।

uses jclSysInfo; 

function GetDomain:string; 
begin 
    result:=GetEnvironmentVariable('USERDNSDOMAIN'); 
end; 

सर्वर 2008 आर 2 पर परीक्षण - ठीक काम करता है। "Server.home.lan" देता है। विंडोज 7 गैर-डोमेन कनेक्टेड पीसी पर एक खाली स्ट्रिंग में परिणाम।