डेल्फी: जेएसओएन सरणी

Question

डेल्फी में जेएसओएन को समझने की कोशिश कर रहा है। मॉड्यूल का प्रयोग "DBXJSON.pas"। कैसे इस तरह के एक सरणी बनाने के लिए इसका इस्तेमाल करने की:

Array:[ 
     {"1":1_1,"1_2_1":1_2_2}, 
     ..., 
    ] 

ऐसा करने से:

JSONObject:=TJSONObject.Create; 
JSONArray:=TJSONArray.Create(); 
... 
JSONArray.AddElement(TJSONObject.Create(TJSONPair.Create('1','1_1'))); 
JSONArray.AddElement(TJSONObject.Create(TJSONPair.Create('1_2_1','1_2_2'))); 
JSONObject.AddPair('Array',JSONArray); 

, लेकिन यह मिलती है:

{ 
"Array":[ 
{"1":"1_1"},{"1_2_1":"1_2_2"} 
] 
} 

कृपया मदद! धन्यवाद!

Answer 1

कोड, जिसे आपने ऊपर पोस्ट किया है, सही नहीं है। आपने JSON-Array बनाया है और उस सरणी में जोड़ी-तत्व जोड़ने की कोशिश कर रहा है। लेकिन, सरणी में जोड़े जोड़ने के बजाय आपको इस सरणी में JSON Objects जोड़ना होगा, और इन ऑब्जेक्ट्स में आपके जोड़े होना चाहिए।

program Project3; 

{$APPTYPE CONSOLE} 

uses 
    SysUtils, dbxjson; 

var jsobj, jso : TJsonObject; 
    jsa : TJsonArray; 
    jsp : TJsonPair; 
begin 
    try 
    //create top-level object 
    jsObj := TJsonObject.Create(); 
    //create an json-array 
    jsa := TJsonArray.Create(); 
    //add array to object 
    jsp := TJSONPair.Create('Array', jsa); 
    jsObj.AddPair(jsp); 

    //add items to the _first_ elemet of array 
    jso := TJsonObject.Create(); 
    //add object pairs 
    jso.AddPair(TJsonPair.Create('1', '1_1')); 
    jso.AddPair(TJsonPair.Create('1_2_1', '1_2_2')); 
    //put it into array 
    jsa.AddElement(jso); 

    //second element 
    jso := TJsonObject.Create(); 
    //add object pairs 
    jso.AddPair(TJsonPair.Create('x', 'x_x')); 
    jso.AddPair(TJsonPair.Create('x_y_x', 'x_y_y')); 
    //put it into array 
    jsa.AddElement(jso); 

    writeln(jsObj.ToString); 
    readln; 

    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
end. 

और आउटपुट है

{"Array":[ 
    {"1":"1_1","1_2_1":"1_2_2"}, 
    {"x":"x_x","x_y_x":"x_y_y"} 
    ] 
} 

Answer 2

@teran के रूप में एक ही जवाब:
यहाँ अपनी समस्या को हल करने के लिए एक नमूना कोड है

परिवर्तन:

JSONArray.AddElement(TJSONObject.Create(TJSONPair.Create('1','1_1'))); 
JSONArray.AddElement(TJSONObject.Create(TJSONPair.Create('1_2_1','1_2_2'))); 

रहे हैं:

JSONArray.AddElement(TJSONPair.Create('1','1_1')); 
JSONArray.AddElement(TJSONPair.Create('1_2_1','1_2_2')); 

चीयर्स।