डॉस बैच फ़ाइल

Question

में एकाधिक लाइनों पर टिप्पणी करते हुए मैंने विशाल एमएस डॉस बैच फ़ाइल लिखी है। इस बैच फ़ाइल का परीक्षण करने के लिए मुझे केवल कुछ पंक्तियों को निष्पादित करने की आवश्यकता है और शेष को छिपाना/टिप्पणी करना चाहते हैं।

मेरे पास कुछ मौजूदा टिप्पणी लाइनें हैं जो शुरू हो रही हैं :: इसलिए मैं अब :: का उपयोग नहीं कर सकता क्योंकि यह सभी टिप्पणियों को तबाह कर देगा।

इस संबंध में किसी भी मदद की सराहना की जाएगी। अग्रिम धन्यवाद, जे

Answer 1

आप कोड पर छोड़ एक goto उपयोग कर सकते हैं।

goto comment 
...skip this... 
:comment 

Answer 2

इस प्रयास करें:

@echo off 2>Nul 3>Nul 4>Nul 

    ben ali 
    mubarak 
    gadeffi 
    ..next ? 

    echo hello Tunisia 

    pause 

Answer 3

@jeb

और यह उपयोग करने के बाद, stderr दुर्गम प्रतीत हो रहा है

नहीं, इस प्रयास करें:

@echo off 2>Nul 3>Nul 4>Nul 

    ben ali 
    mubarak 2>&1 
    gadeffi 
    ..next ? 

    echo hello Tunisia 

    pause 

लेकिन यह क्यों काम करता है?

क्षमा करें, मैं frensh में सवाल का जवाब:,

(ला पुनर्निर्देशन सममूल्य 3> स्था विशेष कार एली persiste VA के ल utiliser डालना बंदी बनानेवाला le प्रवाह des va le ट्रांसफार्मर एन संयुक्त राष्ट्र पर erreurs 2> स्था पर फ्लक्स persistant à l'ade de 3> ceci va nous permettre d'avoir une gestion des erreur pour tout notre वातावरण de script..par la suite si veux recuperer le flux 'stderr' il faut faire une autre redirection du handle 2 > एयू हैंडल 1> क्यू एन'एस्ट ऑट्रे क्यू ला कंसोल ..)

Answer 4

एक और विकल्प आईएफ ब्लॉक में अनचाहे लाइनों को संलग्न करना है जो कभी भी सच नहीं हो सकता

if 1==0 (
... 
) 

निश्चित रूप से अगर ब्लॉक के भीतर कुछ भी निष्पादित नहीं किया जाएगा, लेकिन इसे पार्स किया जाएगा। तो आपके भीतर कोई अमान्य वाक्यविन्यास नहीं हो सकता है। साथ ही, टिप्पणी में ) शामिल नहीं हो सकता है जब तक कि यह बच निकला या उद्धृत न हो। उन कारणों से स्वीकृत गोटो समाधान अधिक विश्वसनीय है। (गोटो समाधान भी तेजी से किया जा सकता है)

अद्यतन 2017-09-19

यहाँ pdub's GOTO solution को एक कॉस्मेटिक वृद्धि है। मैं एक साधारण पर्यावरण चर "मैक्रो" परिभाषित करता हूं जो गोटो टिप्पणी वाक्यविन्यास को थोड़ा बेहतर स्वयं दस्तावेज़िंग बनाता है। यद्यपि यह आमतौर पर अनुशंसा की जाती है कि: बैच स्क्रिप्ट के भीतर लेबल अनूठे होते हैं, वही बैच स्क्रिप्ट के भीतर इस तरह की कई टिप्पणियां एम्बेड करना ठीक है।

@echo off 
setlocal 

set "beginComment=goto :endComment" 

%beginComment% 
Multi-line comment 1 
goes here 
:endComment 

echo This code executes 

%beginComment% 
Multi-line comment 2 
goes here 
:endComment 

echo Done 

या आप npocmaka's solution के इन प्रकार को इस्तेमाल कर सकते हैं। BREAK के बजाय आरईएम का उपयोग इरादा थोड़ा स्पष्ट बनाता है।

rem.||(
    remarks 
    go here 
) 

rem^ ||(
    The space after the caret 
    is critical 
) 

Answer 5

आप गोटो उपयोग करने के बजाय प्रत्येक पंक्ति के आरंभ में रेम जोड़ना चाहते हैं, तो आप ऐसा करने के लिए नोटपैड ++ उपयोग कर सकते हैं आसानी से इन चरणों का पालन:

1. लाइनों के ब्लॉक का चयन करें
2. uncomment के लिए Ctrl-क्यू मारा

चरणों को दोहराएँ

Answer 6

break||(
code that cannot contain non paired closing bracket 
) 

जबकि goto समाधान एक अच्छा विकल्प है, यह within brackets (FOR और IF आदेशों सहित) काम नहीं करेगा। लेकिन यह होगा। हालांकि आपको FOR और IF आदेशों के लिए बंद ब्रैकेट और अमान्य वाक्यविन्यास के बारे में सावधान रहना चाहिए क्योंकि उन्हें पार्स किया जाएगा।

अद्यतन

dbenham's जवाब में अद्यतन मुझे कुछ विचार दे दी है। पहला - दो अलग-अलग मामले हैं जहां हमें बहु रेखा टिप्पणियों की आवश्यकता हो सकती है - एक ब्रैकेट के संदर्भ में जहां गोटो का उपयोग नहीं किया जा सकता है और इसके बाहर। ब्रैकेट संदर्भ के अंदर हम एक और शर्त का उपयोग कर सकते हैं यदि कोई ऐसी स्थिति है जो कोड को निष्पादित करने से रोकती है। कोड कोड को अभी भी पर पार्स किया जाएगा और कुछ वाक्यविन्यास त्रुटियों का पता लगाया जाएगा (FOR, IF, अनुचित रूप से बंद ब्रैकेट, गलत पैरामीटर विस्तार।)। तो यदि यह संभव है तो गोटो का उपयोग करना बेहतर है।

हालांकि लेबल के रूप में उपयोग किए जाने वाले मैक्रो/वेरिएबल को बनाना संभव नहीं है - लेकिन ब्रैकेट की टिप्पणियों के लिए मैक्रोज़ का उपयोग करना संभव है। फिर भी दो चालों का उपयोग किया जा सकता है GOTO टिप्पणियां अधिक सममित और अधिक सुखदायक (कम से कम मुझे)। इसके लिए मैं दो चाल का उपयोग करूंगा - 1) आप एक लेबल के सामने एक ही प्रतीक डाल सकते हैं और गेटो अभी भी को खोजने में सक्षम होगा (मुझे नहीं पता कि यह क्यों है। मेरे संकेत यह एक ड्राइव की तलाश में है)। 2) आप एक परिवर्तनीय नाम के अंत में एक : डाल सकते हैं और एक प्रतिस्थापन/सबट्रिंग सुविधा ट्रिगर नहीं की जाएगी (यहां तक ​​कि सक्षम एक्सटेंशन के तहत भी)। ब्रैकेट टिप्पणियों के लिए मैक्रोज़ के साथ संयुक्त जो दोनों मामलों को लगभग समान दिखने के लिए बना सकता है।

तो यहाँ उदाहरण हैं (क्रम में मैं उन्हें सबसे अधिक पसंद):

@echo off 

::GOTO comment macro 
set "[:=goto :]%%" 
::brackets comment macros 
set "[=rem/||(" & set "]=)" 

::testing 
echo not commented 1 

%[:% 
    multi 
    line 
    comment outside of brackets 
%:]% 

echo not commented 2 

%[:% 
    second multi 
    line 
    comment outside of brackets 
%:]% 

::GOTO macro cannot be used inside for 
for %%a in (first second) do (
    echo first not commented line of the %%a execution 
    %[% 
     multi line 
     comment 
    %]% 
    echo second not commented line of the %%a execution 
) 

कर्ली कोष्ठक के साथ:

@echo off 

::GOTO comment macro 
set "{:=goto :}%%" 
::brackets comment macros 
set "{=rem/||(" & set "}=)" 

::testing 
echo not commented 1 

%{:% 
    multi 
    line 
    comment outside of brackets 
%:}% 

echo not commented 2 

%{:% 
    second multi 
    line 
    comment outside of brackets 
%:}% 

::GOTO macro cannot be used inside for loop 
for %%a in (first second) do (
    echo first not commented line of the %%a execution 
    %{% 
     multi line 
     comment 
    %}% 
    echo second not commented line of the %%a execution 
) 

साथ

आयताकार कोष्ठक साथ

ब्रांड्स:

@echo off 

::GOTO comment macro 
set "(:=goto :)%%" 
::brackets comment macros 
set "(=rem/||(" & set ")=)" 

::testing 
echo not commented 1 

%(:% 
    multi 
    line 
    comment outside of brackets 
%:)% 

echo not commented 2 

%(:% 
    second multi 
    line 
    comment outside of brackets 
%:)% 

::GOTO macro cannot be used inside for loop 
for %%a in (first second) do (
    echo first not commented line of the %%a execution 
    %(% 
     multi line 
     comment 
    %)% 
    echo second not commented line of the %%a execution 
) 

मिश्रण powershell के बीच और सी शैलियों (< क्योंकि पुनर्निर्देशन उच्च prio साथ है नहीं किया जा सकता।*%* की वजह से) का इस्तेमाल किया नहीं किया जा सकता:

@echo off 

::GOTO comment macro 
set "/#:=goto :#/%%" 
::brackets comment macros 
set "/#=rem/||(" & set "#/=)" 

::testing 
echo not commented 1 

%/#:% 
    multi 
    line 
    comment outside of brackets 
%:#/% 

echo not commented 2 

%/#:% 
    second multi 
    line 
    comment outside of brackets 
%:#/% 

::GOTO macro cannot be used inside for loop 
for %%a in (first second) do (
    echo first not commented line of the %%a execution 
    %/#% 
     multi line 
     comment 
    %#/% 
    echo second not commented line of the %%a execution 
) 

करने के लिए emphase एक टिप्पणी है कि (सोचा था कि यह इतना कम नहीं है):

@echo off 

::GOTO comment macro 
set "REM{:=goto :}REM%%" 
::brackets comment macros 
set "REM{=rem/||(" & set "}REM=)" 

::testing 
echo not commented 1 

%REM{:% 
    multi 
    line 
    comment outside of brackets 
%:}REM% 

echo not commented 2 

%REM{:% 
    second multi 
    line 
    comment outside of brackets 
%:}REM% 

::GOTO macro cannot be used inside for 
for %%a in (first second) do (
    echo first not commented line of the %%a execution 
    %REM{% 
     multi line 
     comment 
    %}REM% 
    echo second not commented line of the %%a execution 
)