हास्केल कमांड लाइन आवेदन

Question

निम्नलिखित हास्केल कार्यक्रम में एक पासवर्ड के लिए संकेत टर्मिनल में पासवर्ड के लिए उपयोगकर्ता को संकेत देता और अगर वह सही में प्रवेश किया है जारी है:

main = do 
    putStrLn "Password:" 
    password <- getLine 

    case hash password `member` database of 
     False -> putStrLn "Unauthorized use!" 
     True -> do 
       ... 

दुर्भाग्य से, पासवर्ड पर दिखाई देगा स्क्रीन के रूप में उपयोगकर्ता इसे टाइप करें, जिसे मैं टालना चाहता हूं।

मैं उन वर्णों का अनुक्रम कैसे पढ़ सकता हूं जो उपयोगकर्ता स्क्रीन पर शो के बिना टाइप करते हैं? इस उद्देश्य के लिए getLine के समतुल्य क्या है?

मै मैकोज़ एक्स पर हूं, लेकिन मैं इसे विंडोज और लिनक्स पर भी काम करना चाहता हूं।

Answer 1

अगले का प्रयास करें:

module Main 
where 

import System.IO 
import Control.Exception 

main :: IO() 
main = getPassword >>= putStrLn . ("Entered: " ++) 

getPassword :: IO String 
getPassword = do 
    putStr "Password: " 
    hFlush stdout 
    pass <- withEcho False getLine 
    putChar '\n' 
    return pass 

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = do 
    old <- hGetEcho stdin 
    bracket_ (hSetEcho stdin echo) (hSetEcho stdin old) action 

Answer 2

टर्मिनल में the System.Posix.Terminal module के साथ गूंज अक्षम करना संभव है। हालांकि, इसके लिए POSIX समर्थन की आवश्यकता है, इसलिए विंडोज़ पर काम नहीं कर सकता (मैंने जांच नहीं की)।

import System.Posix.Terminal 
import System.Posix.IO (stdInput) 

getPassword :: IO String 
getPassword = do 
    tc <- getTerminalAttributes stdInput 
    setTerminalAttributes stdInput (withoutMode tc EnableEcho) Immediately 
    password <- getLine 
    setTerminalAttributes stdInput tc Immediately 
    return password 

main = do 
    putStrLn "Password:" 
    password <- getPassword 
    putStrLn "Name:" 
    name <- getLine 
    putStrLn $ "Your password is " ++ password ++ " and your name is " ++ name 

ध्यान दें कि stdin लाइन बफ़र है, इसलिए यदि आप putStr "Password:" बजाय putStrLn उपयोग करते हैं, आप अन्यथा शीघ्र भी हिचकते हो जाएगा पहले बफर फ्लश करने के लिए की जरूरत है,।

Answer 3

System.Console.Haskeline में एक getPassword नहीं है। शायद यह आपके मामले के लिए एक ओवरकिल है लेकिन किसी को यह उपयोगी लगेगा।

एक उदाहरण:

> runInputT defaultSettings $ do {p <- getPassword (Just '*') "pass:"; outputStrLn $ fromJust p} 
pass:*** 
asd 

Answer 4

जैसा कि मैंने ऊपर टिप्पणी की, मैं तुम्हें haskeline, जो एक पूर्ण शीघ्र पुस्तकालय है का उपयोग सुझाव देते हैं। मैंने बिना किसी शिकायत के LambdaCalculator के लिए खुशी से इसका इस्तेमाल किया है।

Answer 5

withEcho थोड़ा कम noice के साथ लिखा जा सकता है:

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = 
    bracket (hGetEcho stdin) 
      (hSetEcho stdin) 
      (const $ hSetEcho stdin echo >> action)