वीबीए जांचें कि फ़ाइल मौजूद है

Question

मेरे पास यह कोड है। यह जांचना है कि कोई फ़ाइल मौजूद है या नहीं और इसे खोलने पर इसे खोलें। यह फ़ाइल काम करता है अगर यह काम करता है, और यदि ऐसा नहीं होता है, हालांकि, जब भी मैं टेक्स्टबॉक्स को खाली छोड़ देता हूं और सबमिट बटन पर क्लिक करता हूं, तो यह विफल हो जाता है। मैं क्या चाहता हूं, यदि टेक्स्टबॉक्स खाली है तो त्रुटि संदेश प्रदर्शित करना है जैसे फ़ाइल मौजूद नहीं है।

रनटाइम त्रुटि "1004"

Dim File As String 
File = TextBox1.Value 
Dim DirFile As String 

DirFile = "C:\Documents and Settings\Administrator\Desktop\" & File 
If Dir(DirFile) = "" Then 
    MsgBox "File does not exist" 
Else 
    Workbooks.Open Filename:=DirFile 
End If 

Answer 1

कुछ इस

सबसे अच्छा की तरह (यदि आवश्यक) खोला कार्यपुस्तिका भी अधिक नियंत्रण प्रदान करने के लिए

कि फ़ाइल नाम का परीक्षण करने के लिए अद्यतन एक वास्तविक कार्यपुस्तिका था - जो भी प्रारंभिक बनाता है जांच से बेमानी, अन्य संदेश में से पाठ बॉक्स से उपयोगकर्ता फ़ाइल होने की जाँच करने के लिए खाली है

Dim strFile As String 
Dim WB As Workbook 
strFile = Trim(TextBox1.Value) 
Dim DirFile As String 
If Len(strFile) = 0 Then Exit Sub 

DirFile = "C:\Documents and Settings\Administrator\Desktop\" & strFile 
If Len(Dir(DirFile)) = 0 Then 
    MsgBox "File does not exist" 
Else 
On Error Resume Next 
Set WB = Workbooks.Open(DirFile) 
On Error GoTo 0 
If WB Is Nothing Then MsgBox DirFile & " is invalid", vbCritical 
End If 

Answer 2

शायद यह फ़ाइल नाम की वजह से चर

File = TextBox1.Value 

यह होना चाहिए

Filename = TextBox1.Value 

Answer 3

यो आपको TextBox1 मान को जांचने के लिए एक शर्त लूप सेट करना चाहिए।

If TextBox1.value = "" then 
    MsgBox "The file not exist" 
    Exit sub 'exit the macro 
End If 

आशा है कि यह आपकी मदद करे। किसी कार्यपुस्तिका चर का उपयोग करने के लिए

Answer 4

इस समारोह का उपयोग करें:

Function IsFile(ByVal fName As String) As Boolean 
'Returns TRUE if the provided name points to an existing file. 
'Returns FALSE if not existing, or if it's a folder 
    On Error Resume Next 
    IsFile = ((GetAttr(fName) And vbDirectory) <> vbDirectory) 
End Function 

Answer 5

अस्तित्व की जाँच एक भी उपयोग कर सकते हैं (दोनों, फ़ाइलों और फ़ोल्डरों के लिए काम करता है):

Not Dir(DirFile, vbDirectory) = vbNullString 

_{परिणाम True है अगर एक फ़ाइल या एक निर्देशिका मौजूद है।}

उदाहरण:

If Not Dir("C:\Temp\test.xlsx", vbDirectory) = vbNullString Then 
    MsgBox "exists" 
Else 
    MsgBox "does not exist" 
End If 

Answer 6

मैं इस वहाँ और फिर बतख बाहर फेंक देंगे। यह जांचने का सामान्य कारण है कि कोई फ़ाइल मौजूद है या नहीं, इसे खोलने का प्रयास करते समय त्रुटि से बचने के लिए। उस से निपटने के लिए त्रुटि हैंडलर का उपयोग करने के बारे में:

Function openFileTest(filePathName As String, ByRef wkBook As Workbook, _ 
         errorHandlingMethod As Long) As Boolean 
'Returns True if filePathName is successfully opened, 
'  False otherwise. 
    Dim errorNum As Long 

'*************************************************************************** 
' Open the file or determine that it doesn't exist. 
    On Error Resume Next: 
    Set wkBook = Workbooks.Open(fileName:=filePathName) 
    If Err.Number <> 0 Then 
     errorNum = Err.Number 
     'Error while attempting to open the file. Maybe it doesn't exist? 
     If Err.Number = 1004 Then 
'*************************************************************************** 
     'File doesn't exist. 
     'Better clear the error and point to the error handler before moving on. 
     Err.Clear 
     On Error GoTo OPENFILETEST_FAIL: 
     '[Clever code here to cope with non-existant file] 
     '... 
     'If the problem could not be resolved, invoke the error handler. 
     Err.Raise errorNum 
     Else 
     'No idea what the error is, but it's not due to a non-existant file 
     'Invoke the error handler. 
     Err.Clear 
     On Error GoTo OPENFILETEST_FAIL: 
     Err.Raise errorNum 
     End If 
    End If 

    'Either the file was successfully opened or the problem was resolved. 
    openFileTest = True 
    Exit Function 

OPENFILETEST_FAIL: 
    errorNum = Err.Number 
    'Presumabley the problem is not a non-existant file, so it's 
    'some other error. Not sure what this would be, so... 
    If errorHandlingMethod < 2 Then 
     'The easy out is to clear the error, reset to the default error handler, 
     'and raise the error number again. 
     'This will immediately cause the code to terminate with VBA's standard 
     'run time error Message box: 
     errorNum = Err.Number 
     Err.Clear 
     On Error GoTo 0 
     Err.Raise errorNum 
     Exit Function 

    ElseIf errorHandlingMethod = 2 Then 
     'Easier debugging, generate a more informative message box, then terminate: 
     MsgBox "" _ 
      & "Error while opening workbook." _ 
      & "PathName: " & filePathName & vbCrLf _ 
      & "Error " & errorNum & ": " & Err.Description & vbCrLf _ 
      , vbExclamation _ 
      , "Failure in function OpenFile(), IO Module" 
     End 

    Else 
     'The calling function is ok with a false result. That is the point 
     'of returning a boolean, after all. 
     openFileTest = False 
     Exit Function 
    End If 

End Function 'openFileTest()