बैच फ़ाइल में मुफ्त डिस्क स्थान का पूर्णांक कैसे प्राप्त करें?

Question

मैं बैच फ़ाइल में मुफ्त डिस्क स्थान का पूर्णांक प्राप्त करने का प्रयास कर रहा हूं। यह मेरा (बहुत) सरल कोड है।

@echo off 
wmic logicaldisk get freespace >> freespace.log 
exit 

लेकिन freespace.log फ़ाइल में आउटपुट।

FreeSpace  
9772687360 
57401442304 
7346626560 
0    
0    

मुझे केवल पूर्णांक और सारांश चुनने की आवश्यकता है। इस तरह के सारांश आउटपुट के बाद।

74520756224 

मैं Google पर अपनी सर्वश्रेष्ठ खोज करता हूं लेकिन मुझे समाधान नहीं मिल रहा है। कृपया मेरी मदद करें :)

Answer 1

यहां हाइब्रिड बैच और पावरहेल का उपयोग करके एक सटीक समाधान है। यह वास्तव में शुद्ध शक्तिशक्ति, vbscript, या jscript के साथ किया जाना चाहिए।

टोकन और आईएफ कथन का गैर-सहज उपयोग फॉर/एफ और डब्लूएमआईसी के यूनिकोड आउटपुट के बीच अजीब बातचीत की भरपाई करना है।

@echo off 
setlocal enableDelayedExpansion 
set /a freeSpace=0 
for /f "skip=1 tokens=1,2" %%A in ('wmic logicaldisk get freespace') do (
    if "%%B" neq "" for /f %%N in ('powershell !freeSpace!+%%A') do (
    set freeSpace=%%N 
) 
) 
echo freeSpace=%freeSpace% 

Answer 2

नीचे कोड का उपयोग करें। टेक्स्ट को deviceid के साथ प्रतिस्थापित करने का प्रयास करें यदि यह ? या खाली दिखाता है।

@echo off 
setlocal 
set drive=C 
set free=? 
rem Note: WMIC will output unicode text 
wmic logicaldisk where (caption = "%drive%:") get freespace>"%temp%\free.tmp" 
for /f %%A in ('type "%temp%\free.tmp"') do (set free=%%A) 
echo Free space: %free% bytes 
rem if exist "%temp%\free.tmp" del "%temp%\free.tmp" 

Answer 3

मैं दूसरे @ dbenham की सिफारिश PowerShell (या कम से कम VBScript या JScript) स्विच करना। हालांकि, अगर आप बैच के साथ रहना चाहते हैं और सटीक संख्या की जरूरत नहीं है आप कुछ इस तरह कर सकता है यदि:

@echo off 

setlocal EnableDelayedExpansion 

for /f %%v in ('wmic logicaldisk get freespace ^| findstr /r "[0-9]"') do (
    set val=%%v 
    set val=!val:~-6! 
    set /a sum+=val 
) 

echo !sum! 

endlocal 

लाइन set val=!val:~-6! प्रत्येक मान से पिछले 6 अंक निकाल देता है। इस तरह आप बाइट्स के बजाय मेगाबाइट्स के साथ गणना कर सकते हैं, लेकिन (जाहिर है) कुछ परिशुद्धता खो देते हैं, क्योंकि मान छोटा कर दिया जाता है (और सही ढंग से गोल नहीं किया जाता है)।

Answer 4

यहाँ एक शुद्ध बैच समाधान है कि ~ 2 जी की तुलना में अधिक से अधिक संख्या को संभाल सकता है:

@echo off 
setlocal EnableDelayedExpansion 
set /A "SUMMEG=0" & set /A "SUMONE=0" 
set /A "NUM=6" & set "ZER=000000" 
for /F "tokens=2 delims==" %%F in (' 
    wmic LOGICALDISK GET FreeSpace /VALUE 
') do (
    for %%G in (%%F) do (
     set "ONE=%ZER%%%G" 
     for /F "tokens=* delims=0" %%H in ("!ONE:~,-%NUM%!") do set "MEG=%%H" 
     for /F "tokens=* delims=0" %%H in ("!ONE:~-%NUM%!") do set "ONE=%%H" 
     set /A "SUMMEG+=MEG" & set /A "SUMONE+=ONE" 
    ) 
) 
if not "!SUMONE:~,-%NUM%!"=="" (set /A "SUMMEG+=!SUMONE:~,-%NUM%!") 
set "SUMONE=%ZER%!SUMONE!" & set "SUMONE=!SUMONE:~-%NUM%!" 
for /F "tokens=* delims=0" %%H in ("%SUMMEG%%SUMONE%") do set "FRE=%%H" 
endlocal & if "%FRE%"=="" (set "FRE=0") else (set "FRE=%FRE%") 
echo %FRE%