सेट सीएमडी फॉरवर्ड स्लैश और एक प्रश्न चिह्न (बैच)

Question

अगर यह संभव है /?

के अध्यक्ष एवं प्रबंध निदेशक के विंडो शीर्षक बदलने के लिए मैं ^/?, ^/^?, और "/?" का उपयोग कर की कोशिश की है मैं सोच रहा हूँ के लिए शीर्षक लेकिन उनमें से कोई काम करने लगते हैं।

किसी को भी कोई सुझाव मिला है?

धन्यवाद

Answer 1

कुछ अदृश्य वर्ण जोड़ने के साथ यह संभव है।
विचार @npocmaka SO: How can I set set a title that start with coma,semicolon or equal sign?
से शुरू किया गया विचार प्रारंभिक अल्पविराम के साथ एक शीर्षक की समस्या को एलएफ चरित्र के साथ भी हल किया जा सकता है, लेकिन आपके मामले में एलएफ स्ट्रिंग में कहीं भी मदद नहीं करता है।

@echo off 

(set LF=^ 
%=empty=% 
) 

::Create a FS variable 
call :hexprint "0x1C" FS 

title /%FS%? 
exit /b 

:hexPrint string [rtnVar] 
    for /f eol^=^%LF%%LF%^ delims^= %%A in (
    'forfiles /p "%~dp0." /m "%~nx0" /c "cmd /c echo(%~1"' 
) do if "%~2" neq "" (set %~2=%%A) else echo(%%A 
exit /b 

Answer 2

@ECHO OFF 
if "%~1"=="_SO42546112_" (
    shift 
) else (
    start "/?" cmd /D /K ""%~f0" "_SO42546112_"" 
    exit 
) 

/? विंडो शीर्षक, .bat स्क्रिप्ट ऊपर डबल क्लिक के साथ एक नईCMD कमांड प्रॉम्प्ट लॉन्च करने के लिए।

---

/? विंडो शीर्षक के साथ एक .bat स्क्रिप्ट चलाने के लिए, उदाहरण के लिए अवधारणा से ऊपर का उपयोग निम्नानुसार:

@ECHO OFF 
SETLOCAL EnableExtensions 

rem self wrapper - start 
if "%~1"=="_SO42546112_" (
    shift 
) else (
    start "/?" cmd /D /C ""%~f0" "_SO42546112_" %*" 
    exit /B 
    rem ↑↑ omit the `/B` switch to close calling `cmd` window 
) 
rem self wrapper - end 

rem check whether the self wrapper works - start 
echo 1st "%~1" 
echo 2nd "%~2" 
echo 3rd "%~3" 
echo all %* 
pause 
rem check whether the self wrapper works - end 

rem original script continues here: