पीएल/एसक्यूएल में एक चर के प्रकार को कैसे देखें?

Question

क्या पीएल/एसक्यूएल में एक चर का सटीक प्रकार दिखाने के लिए कोई फ़ंक्शन है, जैसे SQL में DUMP फ़ंक्शन?

मैं निम्नलिखित

DECLARE 
    l_variable INTEGER := 1; 
BEGIN 
    DBMS_OUTPUT.PUT_LINE (DUMP (l_variable)); 
END; 

की कोशिश की है लेकिन यह निम्न त्रुटि देता है:

PLS-00204: function or pseudo-column 'DUMP' may be used inside a SQL statement only

Answer 1

आप इस समारोह PL/Scope का उपयोग कर बना सकते हैं। लेकिन यह अनाम ब्लॉक के साथ काम नहीं करेगा, और आपको चर को एक स्ट्रिंग के रूप में संदर्भित करने की आवश्यकता होगी।

create or replace function get_plsql_type_name 
(
    p_object_name varchar2, 
    p_name varchar2 
) return varchar2 is 
    v_type_name varchar2(4000); 
begin 
    select reference.name into v_type_name 
    from user_identifiers declaration 
    join user_identifiers reference 
     on declaration.usage_id = reference.usage_context_id 
     and declaration.object_name = reference.object_name 
    where 
     declaration.object_name = p_object_name 
     and declaration.usage = 'DECLARATION' 
     and reference.usage = 'REFERENCE' 
     and declaration.name = p_name; 

    return v_type_name; 
end; 
/

उदाहरण:

alter session set plscope_settings = 'IDENTIFIERS:ALL'; 

create or replace type my_weird_type is object 
(
    a number 
); 

create or replace procedure test_procedure is 
    var1 number; 
    var2 integer; 
    var3 my_weird_type; 
    subtype my_subtype is pls_integer range 42 .. 43; 
    var4 my_subtype; 
begin 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR1')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR2')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR3')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR4')); 
end; 
/

begin 
    test_procedure; 
end; 
/

NUMBER 
INTEGER 
MY_WEIRD_TYPE 
MY_SUBTYPE 

Answer 2

declare 
    a number(10,3); 
    type_info varchar2(400); 
begin 
    a := 55.5; 
    select dump(a) into type_info from dual; 
    DBMS_OUTPUT.PUT_LINE(type_info); 
end; 

Answer 3

के रूप में आप नोटिस देना चाहिए, DUMP एक ओवरलोड कार्य है। इसमें 3 ओवरलोड हैं।

तो आप अपने कोड के भीतर एक ही चीज़ अनुकरण कर सकते हैं।

function myDump (x Varchar2) return varchar2 is begin return('string') ; end ; 
function myDump (x number) return varchar2 is begin return('integer') ; end ; 
function myDump (x date) return varchar2 is begin return('date') ; end ; 

उपरोक्त कोड ठीक से काम नहीं कर सकता है लेकिन आपको समस्या को हल करने का विचार देना चाहिए।

मुझे आशा है कि यह आपकी आवश्यकताओं को पूरा करेगा।

नोट; आप इन कार्यों को एक पैकेज में डाल सकते हैं और तदनुसार उनका उपयोग कर सकते हैं।