विजुअल बेसिक

Question

का उपयोग कर आईई में वर्तमान यूआरएल प्राप्त करें मैं विजुअल बेसिक में इंटरनेट एक्सप्लोरर ऑब्जेक्ट के साथ काम कर रहा हूं। क्या मौजूदा यूआरएल की प्रतिलिपि बनाने का कोई तरीका आईई प्रदर्शित कर रहा है, इसलिए मैं इसे अपने क्लिपबोर्ड के साथ कहीं और पेस्ट कर सकता हूं?

Answer 1

मान लिया जाये कि आप पहले से ही IE विंडो की पहचान की है, जो अपने आप में एक छोटे से अधिक जटिल है - मैं कर सकते हैं इस पर विस्तार से बता अगर जरूरत:

Dim ieIEWindow As SHDocVw.InternetExplorer 
Dim sIEURL As String 

'Set your IE Window 

sIEURL = ieIEWindow.LocationURL 

IE विंडो पाने के लिए आपको संदर्भित करने के लिए की आवश्यकता होगी Microsoft Internet Controls लाइब्रेरी (ieframe.dll) वीबीए संपादक में Tools =>References... पर जाकर और सूची से इसे चुनकर। यदि वह आइटम उपलब्ध नहीं है, तो मेरे लिए .dll फ़ाइल C:\Windows\System32\ieframe.dll पर स्थित है।

एक बार संदर्भ सेट होने के बाद, आपको अपने कोड में तथाकथित SHDocVw लाइब्रेरी तक पहुंच होगी।

Public Function GrabIEWindow() As SHDocView.InternetExplorer 

Dim swShellWindows As New SHDocVw.ShellWindows 
Dim ieOpenIEWindow As SHDocVw.InternetExplorer 

    Set GrabIEWindow = Nothing 

    ' Look at the URLs of any active Explorer windows 
    ' (this includes WINDOWS windows, not just IE) 
    For Each ieOpenIEWindow In objShellWindows 

     ' Check the I.E. window to see if it's pointed 
     ' to a web location (http) 
     If Left$(ieOpenIEWindow.LocationURL, 4) = "http" Then 
      ' If so, set this window as the one to use. 
      ' This will need to be modified to create 
      ' a list if you want to select from more 
      ' than one open window 

      ' Optional grab the HWND for later reference... 
      Dim lWindowID As Long 
      lWindowID = ieOpenIEWindow.HWND 

      Set GrabIEWindow = ieOpenIEWindow 

      Exit Function 
     End If 

    Next OpenIEWindow 

End Function 

ऊपर भी संशोधित किया जा सकता एक चयन के लिए अनुमति देने के लिए:

आप IE विंडो (यह मानते हुए केवल एक ही खुला) का उपयोग कर (अपरीक्षित, संशोधित/अपने ही काम कर कोड से घटाकर) निम्नलिखित प्राप्त कर सकते हैं कई खुली आईई विंडोज़ के।

Answer 2

अरे! यह मुझे मेरे vb6 दिनों की याद दिलाता है :)

ठीक है मेरे पास यह है। यदि 1 से अधिक आईई विंडोज़ हैं तो यह अंतिम सक्रिय (वर्तमान) ले जाएगा) आईई विंडो अन्य अगर केवल एक खिड़की है तो यह ले जाएगा।

'~~> Set a reference to Microsoft Internet Controls 

'~~> The GetWindow function retrieves the handle of a window that has 
'~~> the specified relationship (Z order or owner) to the specified window. 
Private Declare Function GetWindow Lib "user32" (ByVal hwnd As Long, _ 
ByVal wCmd As Long) As Long 

'~~> The GetForegroundWindow function returns the handle of the foreground 
'~~> window (the window with which the user is currently working). 
Private Declare Function GetForegroundWindow Lib "user32"() As Long 

Sub GetURL() 
    Dim sw As SHDocVw.ShellWindows 
    Dim objIE As SHDocVw.InternetExplorer 
    Dim topHwnd As Long, nextHwnd As Long 
    Dim sURL As String, hwnds As String 

    Set sw = New SHDocVw.ShellWindows 

    '~~> Check the number of IE Windows Opened 
    '~~> If more than 1 
    hwnds = "|" 
    If sw.Count > 1 Then 
     '~~> Create a string of hwnds of all IE windows 
     For Each objIE In sw 
      hwnds = hwnds & objIE.hwnd & "|" 
     Next 

     '~~> Get handle of handle of the foreground window 
     nextHwnd = GetForegroundWindow 

     '~~> Check for the 1st IE window after foreground window 
     Do While nextHwnd > 0 
      nextHwnd = GetWindow(nextHwnd, 2&) 
      If InStr(hwnds, "|" & nextHwnd & "|") > 0 Then 
       topHwnd = nextHwnd 
       Exit Do 
      End If 
     Loop 

     '~~> Get the URL from the relevant IE window 
     For Each objIE In sw 
      If objIE.hwnd = topHwnd Then 
       sURL = objIE.LocationURL 
       Exit For 
      End If 
     Next 
    '~~> If only 1 was found 
    Else 
     For Each objIE In sw 
      sURL = objIE.LocationURL 
     Next 
    End If 

    Debug.Print sURL 

    Set sw = Nothing: Set objIE = Nothing 
End Sub 

नोट: मैं किसी भी त्रुटि हैंडलिंग नहीं किया है। मुझे यकीन है कि आप इसका ख्याल रख सकते हैं;)