एक्सएसएलटी: क्या मैं वैश्विक स्तर पर एक चर घोषित कर सकता हूं और बाद में इसे मान सकता हूं

Question

इस कोड को काम करने के लिए मैं क्या कर सकता हूं?

<xsl:choose> 
    <xsl:when test='type = 6'> 
    <xsl:variable name='title' select='root/info/title' /> 
    </xsl:when> 
    <xsl:when test='type = 7'> 
    <xsl:variable name='title' select='root/name' /> 
    </xsl:when> 
    <xsl:otherwise> 
    <xsl:variable name='title'>unknown</xsl:variable> 
    </xsl:otherwise> 
</xsl:choose> 

<div class='title'> 
    <xsl:value-of select='$title'/> 
</div> 

इसका कारण यह है काम नहीं करता है जब मैं करना <xsl:value-of select='$title'/>, $title दायरे से बाहर है। मैंने दायरे के बाहर <xsl:variable name='title'/> लाइन जोड़ने की कोशिश की, लेकिन यह या तो काम नहीं करेगा, क्योंकि जब मैं <xsl:variable name='title' select='root/info/title' /> को उदाहरण के लिए कॉल करता हूं, तो मैंने पहले ही इस चर को सेट कर दिया है। मुझे इसे कैसे हल करना चाहिए?

Answer 1

आप स्थानांतरित कर सकते हैं इस तरह चर की अंदर चुनते हैं, तो:

<xsl:variable name="title"> 
    <xsl:choose> 
    <xsl:when test='type=6'> 
     <xsl:value-of select="root/info/title" /> 
    </xsl:when> 
    ... 
    </xsl:choose> 
</xsl:variable> 

<div class='title'> 
    <xsl:value-of select="$title" /> 
</div> 

Answer 2

आप एक्सएसएलटी (1.0) में चर को फिर से असाइन नहीं कर सकते हैं। नाम शायद सौभाग्य से नहीं चुना गया है; एक xsl:variable एक चर से अधिक प्रतीक है।

अपने नमूना में आप निम्न का उपयोग कर सकते हैं:

<xsl:variable name='title'> 
    <xsl:choose> 
    <xsl:when test='type = 6'> 
     <xsl:value-of select='root/info/title' /> 
    </xsl:when> 
    <xsl:when test='type = 7'> 
     <xsl:value-of select='root/name' /> 
    </xsl:when> 
    <xsl:otherwise> 
     <xsl:text>unknown</xsl:text> 
    </xsl:otherwise> 
    </xsl:choose> 
</xsl:variable> 

Answer 3

<xsl:choose> 
    <xsl:when test='type = 6'> 
    <xsl:variable name='title' select='root/info/title' /> 
    </xsl:when> 
    <xsl:when test='type = 7'> 
    <xsl:variable name='title' select='root/name' /> 
    </xsl:when> 
    <xsl:otherwise> 
    <xsl:variable name='title'>unknown</xsl:variable> 
    </xsl:otherwise> 
</xsl:choose> 

<div class='title'> 
    <xsl:value-of select='$title'/> 
</div> 

यह नहीं करता है ' टी काम

यह एक एफएक्यू:

आप कई चर परिभाषित कर रहे हैं, प्रत्येक नाम $title और प्रत्येक बेकार है, क्योंकि यह तुरंत दायरे से बाहर हो जाता है।

शर्तों के आधार पर एक चर को परिभाषित करने के XSLT 1.0 में उचित तरीके से है:

<xsl:variable name="vTitle"> 
    <xsl:choose> 
     <xsl:when test='type = 6'> 
     <xsl:value-of select='root/info/title' /> 
     </xsl:when> 
     <xsl:when test='type = 7'> 
     <xsl:value-of select='root/name' /> 
     </xsl:when> 
     <xsl:otherwise> 
     <xsl:value-of select="'unknown'"/> 
     </xsl:otherwise> 
    </xsl:choose> 
</xsl:variable> 

को परिभाषित करने का एक और तरीका एक ही चर: इस विशेष मामले में आप चर एक स्ट्रिंग करना चाहते हैं मूल्य। यह एक अधिक कॉम्पैक्ट रूप में व्यक्त किया जा सकता है:

<xsl:variable name="vTitle2" select= 
"concat(root/info/title[current()/type=6], 
     root/name[current()/type=7], 
     substring('unknown', 1 div (type > 7 or not(type > 5))) 
     ) 
"/> 

अंत में, XSLT 2.0 एक में ऐसा वैरिएबल भी अधिक आसानी से परिभाषित कर सकते हैं: @ carolclarinet के standar जवाब और अधिक कॉम्पैक्ट इसके अलावा

<xsl:variable name="vTitle3" as="xs:string" select= 
"if(type eq 6) 
    then root/info/title 
    else if(type eq 7) 
      then root/name 
      else 'unknown' 
"/> 

Answer 4

@ डिमिट्रे का जवाब, जब परिणाम कुछ नोड पर निर्भर करता है और आप पुन: उपयोग और विस्तारशीलता के बारे में चिंता करते हैं, तो आप टेम्पलेट्स लागू कर सकते हैं और पैटर्न मिलान का उपयोग कर सकते हैं, यानी:

<xsl:variable name="title"> 
    <xsl:apply-templates select="type" mode="title"/> 
</xsl:variable> 

<xsl:template match="type[.=6]" mode="title"> 
    <xsl:value-of select='../root/info/title"/> 
</xsl:template> 
<xsl:template match="type[.=7]" mode="title"> 
    <xsl:value-of select='../root/name"/> 
</xsl:template> 
<xsl:template match="type" mode="title"> 
    <xsl:text>unknown</xsl:text> 
</xsl:template> 

Answer 5

मैं स्थानीय मान को xml xsl:desult _document फ़ोल्डर /temp_variables_loop/loop-data-id_(position()).xml पर सहेजने के लिए कर रहा हूं।

और अगले लूप में मैंने/temp_variables_loop.alias/loop-data-id_(position()-1).xml से फ़ाइलें पढ़ीं।

आपको /temp_variables_loop से temp_variables_loop.alias के उपनाम बनाकर xsl इंजन को धोखा देने की आवश्यकता है क्योंकि आप एक ही फ़ाइल को एक xsl में पढ़ और लिख नहीं सकते हैं।