एकल पंक्ति एसक्यूएल स्टेटमेंट

Question

ठीक से एकाधिक पंक्ति अद्यतन एसक्यूएल ट्रिगर। मैं एसक्यूएल ट्रिगर्स के लिए काफी नया हूं और उनके साथ कुछ समस्याएं हैं। ट्रिगर डालें बस ठीक काम करता है, और हटाएं ट्रिगर भी। सबसे पहले, कई पंक्तियों पर एक डिलीट करने से केवल एक ही हट जाएगा, लेकिन मैं इसे अपने लिए बाहर निकालने में कामयाब रहा :)

हालांकि, व्यापक खोज (यहां और Google पर) के बाद भी मैं एक संतोषजनक उत्तर नहीं ढूंढ पा रहा हूं मेरे पास अद्यतन ट्रिगर के लिए है। यदि मैं

UPDATE Customers Set CustomerUser = 0 Where CustomerStatus = 3 

पर दुर्भाग्यवश, केवल एक रिकॉर्ड अपडेट किया जाएगा, और दूसरा वैसे ही रहेगा जैसे अद्यतन। जाहिर है, यह कोई अच्छा नहीं है।

ट्रिगर मैं उपयोग कर रहा हूँ है:

ALTER TRIGGER [dbo].[TRG_TriggerName] ON [dbo].[USER_Customers] 

FOR UPDATE 

AS 
declare @customerid int; 
declare @customervenue int; 
declare @customeruser int; 
declare @customerarea int; 
declare @customerevent int; 
declare @customerproject int; 
declare @customerstatus int; 

select @customerid=i.CustomerID from inserted i; 
select @customervenue=i.CustomerVenue from inserted i; 
select @customerarea=i.CustomerArea from inserted i; 
select @customerevent=i.CustomerEvent from inserted i; 
select @customerproject=i.CustomerProject from inserted i; 
select @customeruser=i.CustomerUser from inserted i; 
select @customerstatus=i.CustomerStatus from inserted i; 

Update USER_Instances Set InstanceArea = @customerarea, InstanceVenue = @customervenue, InstanceUser = @customeruser, InstanceStatus = @customerstatus, InstanceEvent = @customerevent, InstanceLastUpdate = GetDate() Where InstanceObject = 17 AND InstanceIdentity = @customerid 
GO 

आप तुरंत एहसास होगा के रूप में, इस ट्रिगर महान है - अगर आप सिर्फ एक रिकॉर्ड को अपडेट करना चाहते हैं। अन्यथा, यह विफल रहता है। अब - यहां मुख्य प्रश्न होगा - मैं उन सभी रिकॉर्ड्स को कैसे पकड़ूं जिन्हें अद्यतन करने की आवश्यकता है, और उन्हें एक ट्रिगर कार्रवाई में अपडेट करें।

स्टैक ओवरफ़्लो पर मैंने जो उदाहरण देखे हैं, वे मुझे कुछ हद तक भ्रमित करते हैं, या अप्रभावी लगते हैं - उदाहरण के लिए, ऐसा लगता है कि उनमें से अधिकतर एक दूसरे/अन्य तालिका में केवल एक मान को अपडेट करने के साथ सौदा करते हैं, और पूरे समूह की तरह नहीं करने का प्रयत्न। वे जो कई मानों पर काम करने लगते हैं, मैं समझ नहीं पा रहा हूं :(

तो लगभग 2 घंटे की खोज के बाद, मैं हार मानता हूं, और उम्मीद करता हूं कि आप मेरी मदद कर सकते हैं :) मुझे एहसास है कि यह एक ट्रिगर-नौसिखिया मुद्दा है , और हालांकि मैं अपने एमएस-एसक्यूएल को जानता हूं, ट्रिगर कुछ ऐसा है जो मैंने कभी नहीं किया है। तो किसी भी मदद की बहुत :) का स्वागत करते हैं

डब्ल्यू

Answer 1

ऐसा लगता है कि आप इस

ALTER TRIGGER [dbo].[TRG_TriggerName] ON [dbo].[USER_Customers] 
FOR UPDATE 
AS 
UPDATE USER_Instances 
    SET InstanceArea = i.CustomerArea, 
     InstanceVenue = i.CustomerVenue, 
     InstanceUser = i.CustomerUser, 
     InstanceStatus = i.CustomerStatus, 
     InstanceEvent = i.CustomerEvent, 
     InstanceLastUpdate = GetDate() 
    FROM USER_Instances JOIN inserted i 
    ON InstanceIdentity = i.CustomerID AND InstanceObject = 17 

की तरह कुछ की जरूरत है के बाद से inserted आभासी तालिका एकाधिक पंक्तियों को शामिल कर सकते हैं इसे सही ढंग से अपने UPDATE क्या करना JOIN करने की जरूरत है।