डेल्फी आरटीटीआई: संपत्ति की कक्षा

Question

डेल्फी 2010 और आरटीटीआई का उपयोग करके, मुझे पता है कि किसी ऑब्जेक्ट के वर्ग प्रकार को कैसे प्राप्त करें और किसी वस्तु के गुणों के मूल्य और प्रकार को कैसे प्राप्त/सेट करें, लेकिन आप कैसे निर्धारित करते हैं कि कौन सी कक्षा विरासत श्रृंखला एक संपत्ति से आया था? मैं मुख्य वर्ग की तुलना में बेस क्लास के गुणों का अलग-अलग उपयोग करना चाहता हूं।

TClassBase = class(TObject) 
published 
    property A: Integer; 
end; 

TClassDescendant = class(TClassBase) 
published 
    property B: Integer; 
end; 

procedure CheckProperties(Obj: TObject); 
var 
    ctx: TRttiContext; 
    objType: TRttiType; 
    Prop: TRttiProperty; 
begin 
    ctx := TRttiContext.Create; 
    objType := ctx.GetType(Obj.ClassInfo); 
    for Prop in objType.GetProperties do begin 
    if Prop.GetClassType is TClassBase then 
     // do something special with base class properties 
    else 
     // standard functionality on all other properties 
    end; 
end; 

समस्या गुण के लिए कोई GetClassType वहाँ है:

इस कोड पर विचार करें। क्लासटाइप केवल उस वर्ग के नाम के बजाय TRttiInstancePropertyEx देता है जिस पर संपत्ति संबंधित है।

Answer 1

एक अन्य विकल्प, TRttiProperty की Parent संपत्ति का उपयोग यहाँ से आप वर्ग जो संपत्ति का हिस्सा है करने के लिए उपयोग कर सकते हैं है।

{$APPTYPE CONSOLE} 

{$R *.res} 

uses 
    Rtti, 
    SysUtils; 

type 
    TClassBase = class(TObject) 
    private 
     FA: Integer; 
    published 
    property A: Integer read FA; 
    end; 

    TClassDescendant = class(TClassBase) 
    private 
     FB: Integer; 
    published 
    property B: Integer read FB; 
    end; 

procedure CheckProperties(Obj: TObject); 
var 
    ctx: TRttiContext; 
    objType: TRttiType; 
    Prop: TRttiProperty; 
begin 
    ctx := TRttiContext.Create; 
    objType := ctx.GetType(Obj.ClassInfo); 
    for Prop in objType.GetProperties do 
    if TRttiInstanceType(Prop.Parent).MetaclassType=TClassBase then 
    Writeln(Format('The property %s is declarated in the TClassBase class',[Prop.Name])) 
    else 
    Writeln(Format('The property %s is not declarated in the TClassBase class',[Prop.Name])) 
end; 


begin 
    try 
    //CheckProperties(TClassBase.Create); 
    CheckProperties(TClassDescendant.Create); 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
    Readln; 
end. 

Answer 2

मैं अगर यह वर्ग है जो एक संपत्ति पेश किया गया था प्राप्त करना संभव है पता नहीं है, लेकिन आप नियमित रूप से RTTI साथ अपनी समस्या को हल कर सकते हैं: गुण में declarated पाने के लिए

begin 
    ... 

    for Prop in objType.GetProperties do begin 
    if Assigned(GetPropInfo(TClassBase, Prop.Name)) then 
     // do something special with base class properties 
    else 
     // standard functionality on all other properties 
    end; 
end; 

Answer 3

आप GetDeclaredProperties विधि का उपयोग कर सकते हैं वर्तमान वर्ग और फिर GetProperties विधि द्वारा लौटाए गए मानों के विरुद्ध तुलना करें।

इस नमूना को आजमाएं।

{$APPTYPE CONSOLE} 

{$R *.res} 

uses 
    Rtti, 
    SysUtils; 

type 
    TClassBase = class(TObject) 
    private 
     FA: Integer; 
    published 
    property A: Integer read FA; 
    end; 

    TClassDescendant = class(TClassBase) 
    private 
     FB: Integer; 
    published 
    property B: Integer read FB; 
    end; 

procedure CheckProperties(Obj: TObject); 

    function ExistProp(const PropName:string; List:TArray<TRttiProperty>) : Boolean; 
    var 
    Prop: TRttiProperty; 
    begin 
    result:=False; 
    for Prop in List do 
    if SameText(PropName, Prop.Name) then 
    begin 
     Result:=True; 
     break; 
    end; 
    end; 

var 
    ctx: TRttiContext; 
    objType: TRttiType; 
    Prop: TRttiProperty; 
    CurrentClassProps : TArray<TRttiProperty>; 
begin 
    ctx := TRttiContext.Create; 
    objType := ctx.GetType(Obj.ClassInfo); 
    CurrentClassProps:=objType.GetDeclaredProperties; 
    for Prop in objType.GetProperties do 
    if ExistProp(Prop.Name, CurrentClassProps) then 
    Writeln(Format('The property %s is declarated in the current %s class',[Prop.Name, obj.ClassName])) 
    else 
    Writeln(Format('The property %s is declarated in the base class',[Prop.Name])) 
end; 



begin 
    try 
    //CheckProperties(TClassBase.Create); 
    CheckProperties(TClassDescendant.Create); 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
    Readln; 
end.