हैक हमला!
जिसके अनुसार, आप zeroaxis
विकल्प में दिख सकता है:
set term pngcairo truecolor size 300,300 font "Arial,12"
set out 'plot.png'
# x,y min/max and center
xmin = -10
xc = 0
xmax = 10
ymin = -2
yc = 0
ymax = 2
# default borders
tm = 1
bm = 1
rm = 4
lm = 4
# arrow scale factor to cover last tic
af = 1.05
set arrow from xc,yc to xmin*af,yc filled size 0.6,30
set arrow from xc,yc to xmax*af,yc filled size 0.6,30
set arrow from xc,yc to xc,ymax*af filled size 0.6,30
set arrow from xc,yc to xc,ymin*af filled size 0.6,30
set multiplot layout 2,2
## Plot 1, top left
set key top left
set xr [xmin:xc]
set yr [yc:ymax]
set tmargin tm
set bmargin 0
set rmargin 0
set lmargin lm
set border 9
unset ytics
set xtics nomirror
plot sin(x)
## Plot 2, top right
unset key
set xr [xc:xmax]
set lmargin 0
set rmargin rm
set border 3
set ytics nomirror
replot
## Plot 3, bottom left
set xr [xmin:xc]
set yr [ymin:yc]
set bmargin bm
set tmargin 0
set lmargin lm
set rmargin 0
set border 12
unset tics
replot
## Plot 4, bottom right
set xr [xc:xmax]
set lmargin 0
set rmargin rm
set border 6
set ytics nomirror
replot
unset multiplot
मैं इस उत्पादन मिलता है। एक प्रदर्शन here है। अफसोस की बात यह विकल्प धुरी को शून्य पर नहीं खींचता है, लेकिन उस स्थिति में बस एक रेखा डालता है।
मैं नहीं कहूंगा कि मेरी विधि 'कुशल' है, लेकिन शायद आपके उद्देश्यों के लिए इसे संशोधित करने के लिए बहुत अधिक प्रयास नहीं किया जा रहा है, क्योंकि अधिकांश कार्य replot
कमांड द्वारा किए गए हैं। मुझे अक्ष के अंत में gnuplot तीर डालने या बदलने के लिए विकल्प नहीं पता है जहां अक्ष को मूल रूप से खींचा जाता है।
+1। 'शून्यaxis' सेट एक अक्ष में उत्पत्ति के माध्यम से दोनों अक्ष बनाने के लिए लगता है। आप अक्ष के लिए इच्छित मोटाई और रेखा प्रकार भी निर्दिष्ट कर सकते हैं: 'शून्यaxis linewidth 2 linetype 1', आदि सेट करें – Umang
आप' x2tics 'को अनसेट करना और पहले y2tics को अनसेट करना चाहते हैं। अन्यथा आप दो बार दिखाए गए सभी चित्र प्राप्त करते हैं। – d3dave